; ;*********
;        *
; BASIC0 *
;        *
;*********
	.TITLE BASIC0
	.SBTTL	TRAP MACRO DEFINITIONS
;
; DOS VERSION FROM WHICH THE RSX VERSION EVOLVED WAS ORIGIANLLY A DECUS
; LIBRARY PROGRAM MODIFIED BY FRANK KORZENIEWSKI OF RPSLMC.
;
; BASIC TRAP HANDLER OBJECT MODULE 31 MAY 72
; PROVIDES ONE WORD TRAP SUBROUTINE CALLS AND
; ERROR HANDLING
;
; MODIFIED BY LARRY SIMPSON 12-SEP-75 FOR ERROR TRAPS ONLY
; AND USE OF WORD ON STACK RETURNED BY RSX EXECUTIVE.
;
; MODIFIED FOR "MO" ERROR HANDLING
; BY LARRY SIMPSON 15-OCT-75
;
; MODIFIED FOR "ON ERROR GOTO" USER ERROR HANDLING
; BY LARRY SIMPSON 13-DEC-76
;
; MODIFIED FOR FLOATING POINT EXCEPTION ERROR HANDLING
; BY LARRY SIMPSON 17-DEC-76
;
; MODIFIED FOR FLOATING POINT EMULATION (CONDITIONAL ON  'FPPEMU')              ;DSS1
; FPPEMU IS DEFINED (OR NOT) IN PREFIX ASSEMBLY FILE                            ;DSS1
; BY DANIEL STEINBERG 18-JAN-79                                                 ;DSS1
;                                                                               ;DSS1
; MODIFIED TO INCLUDE 'VARIABLE TYPE MISMATCH ERROR' (VTMERR - 52)              ;DSS1
; WHEN STRING AND NUMERIC VARIABLES ARE MIXED TOGETHER  (PREVIOUSLY, THE        ;DSS1
; PROGRAM TRAPPED OUT ON ODD ADDRESS OR ILLEGAL INSTRUCTION OR MEMORY FAULT)    ;DSS1
; *** THIS IS NOT THE ONLY ERROR THAT CAN BE GENERATED WHEN THERE IS            ;DSS1
;     A MISMATCHED EXPRESSION....THE WHOLE ERROR CODE STRUCTURE WILL            ;DSS1
;     EVENTUALLY BE MODIFIED ***                                                ;DSS1
; BY DANIEL STEINBERG 14-FEB-79                                                 ;DSS1
;                                                                               ;DSS1
; FIXED MINOR BUG IN ERROR ROUTINE UNDER RSX11M                                 ;DSS1
; D.S.                                                                          ;DSS1
;                                                                               ;DSS1
;                                                                               ;DSS1
;-355,,/;DSS1/                                                                  ;DSS1
;	TV	VTMERR	;VARIABLE TYPE MISMATCH CHANGED TO #54, (FB)
; DEFINE FOR RSX11D IF RSX11M IS NOT DEFINED BY HEADER FILE TO MACRO
;
	.IF	NDF	RSX11M
RSX11D=1	;DEFINE FOR RSX11D MO ERROR HANDLING
	.ENDC
; GLOBAL PROGRAM EXTERNALS
;
	.GLOBL	ENDSTK	STOP02	TINPT	TOTPT	INPT	OTPT
	.GLOBL	STUDAT	ENUDAT	DETACH	GOTO03	FPEXFL	LINEFL
;
; GLOBALS DEFINED HERE
	.GLOBL	FPERMS	CTCENT
	.IF	DF	RSX11D
	.GLOBL	STRD
	.ENDC
;
; MO PARAMETER LIST GLOBALS
	.GLOBL	PARLST	P.ERCD	P.LINE	P.FCS	P.FLNM	P.FNAM
;
; MACRO CALLS
	.MCALL	DIR$	ASTX$S
	.IF DF	RSX11D
	.MCALL	MOUT$	MODF$	MOWA$S
	.ENDC
;TRAP ENTRY POINT GLOBALS - FOR SVTK$ AND SFPA$ IN BASIC3
;
	.GLOBL	TRAP00	FPEXTR
;
;
	.MACRO	TV	.SYM
.SYM	=	TRAP
TRAP=TRAP+1
	.GLOBL	.SYM
	.ENDM

.PAGE
	.SBTTL	JSR MACRO DEFINITIONS
;
; MODIFICATION BY FRANK BORGER 5-SEP-75
;
	;CODE TO CONVERT TRAP SUBROUTINE CALLS TO NORMAL JSR'S
	;FOR OPERATION UNDER RSX.
	;
	;DEFINE A GENERAL MACRO TO GENERATE A SECOND MACRO WHICH
	;CONVERTS A TRAP NAME OF XXXXXX TO A
	;	JSR	PC,XXXXXX
	;
	.MACRO TRPSUB	A,B
	.MACRO	A
	JSR	PC,B
	.ENDM
	.ENDM
;
;	NOW ALL THE ONE-TIME TRAPS THAT BASIC USES
;
	TRPSUB	ATOF,ATOF00	;ASCII TO FLOATING
	TRPSUB	ATOI,ATOI00	;ASCII TO INTEGER
	TRPSUB	CLOSEF,CLOS00	;CLOSE ANY OPEN FILES
	TRPSUB	CLRUSR,CLRU00	;CLOSE TEMP USER SPACE (IF ANY)
	TRPSUB	CRLF,CRLF00	;DO [CR,LF]
	TRPSUB	DIMCHK,DIMC00	;CHECK LEGALITY OF DIMENSIONS
	TRPSUB	EVAL,EVAL00	;EVALUATE ARITHMETIC EXPRESSION
	TRPSUB	EVALS,EVLS00	;EVALUATE STRING EXPRESSION
	TRPSUB	FINDLN,FIND00	;FIND LINE NUMBER (IN R0)
	TRPSUB	GETVAR,GETV00	;GET TRUNCATED VARIABLE
	TRPSUB	ITOA,ITOA00	;CONVERT INTEGER TO ASCII
	TRPSUB	JUNKIT,JUNK00	;SKIP OVER TRASH TO END OF LINE
	TRPSUB	PACK,PCK00	;PACK LINE INTO WORKING STORAGE
	TRPSUB	PRINTC,PRNT00	;PRINT CHARACTER
	TRPSUB	PRINTL,PRN00	;PRINT LINE, R0=FBA,R1=LBA
	TRPSUB	PRNTLN,PRLN00	;PRINT LINE NUMBER
	TRPSUB	PUSH,PUSH00	;PUSH ONE WORD INTO USER LIST
	TRPSUB	SCRNCH,SCR00	;DELETE N BYTES FROM USER SPACE
	TRPSUB	SKIP,SKIP00	;SKIP OVER SPACES IN INPUT TEXT
	TRPSUB	SQUISH,SQU00	;DELETE TEXT TO TERMINATOR AND PACK
	TRPSUB	SRCHLF,SRCH00	;SEARCH FOR LINE FEED USING R1 AS POINTER
	TRPSUB	SRLST,SRL00	;SEARCH FOR ITEM IN USER STORAGE
	TRPSUB	STRLEN,STRL00	;COMPUTE STRING LENGTH
	TRPSUB	TSTCH,TST00	;TEST CHAR (IN R2) ALPHA VS NUMERIC
	TRPSUB	TSTOK,TSTU00	;CHECK, IS THERE ENOUGH USER SPACE
	TRPSUB	FNMBR,FNMB00	;GET FILE NUMBER AND SET UP FILE

;+1
; .SKIP
; .X ^INTRODUCTION
; ^THIS ^^BASIC\\ FOLLOWS ^^DEC\\'S ^^BASIC-11\\ IN ITS BASIC ORIENTATION.
; ^ADVANCED FEATURES TEND TO FOLLOW <RSTS <BASIC-PLUS (E.G. VIRTUAL ARRAYS).
; ^PRIMARY DIFFERENCES ARE IN THE FILE ^I/^O.
; ^THE ^^OPEN, PRINT\\ AND ^^INPUT\\ STATEMENTS HAVE BEEN MODIFIED
; TO PROVIDE FULL ^^FILES-11\\ CAPABILITY FOR ^^ASCII\\ FILES BOTH
; FIXED AND VARIABLE LENGTH AND SEQUENTIAL AND RANDOM ACCESS.
; ^THE STATEMENT CONCATENATION CHARACTER IS THE COLON (:).
; .S
; .X <IMMEDIATE MODE
; <BASIC CAN BE USED IN AN <IMMEDIATE MODE. ^ANY LEGAL COMMAND ENTERED
; WITHOUT A LINE NUMBER (OR LEADING "TAB") WILL BE PERFORMED IMMEDIATELY.
; ^NEARLY ALL THE <BASIC CODES PRESENTED IN THIS DOCUMENT CAN BE USED IN
; THE <IMMEDIATE MODE AND A FEW CAN BE USED
; ONLY IN THE <IMMEDIATE MODE.
; .FG 1
; ^THE OTHER <BASIC MODE IS THE <PROGRAM MODE.
; ^ANY LEGAL COMMAND FOLLOWING A LINE NUMBER OR WITH A LEADING "TAB",
; (EFFECTIVELY A CONTINUATION LINE,) WILL BE STORED WITH THE CURRENT
; PROGRAM AND EXECUTED IN NORMAL PROGRAM FLOW.
; .S
; <BASIC COMES IN SEVERAL 'SIZES'. ^WHEN A USER
; INVOKES <BASIC BY CALLING FOR <BAS, THE
; SPACE RESERVED FOR THE PROGRAM AND DATA IN MAIN MEMORY
; CONTAINS 2570 BYTES. ^THE NEXT
; 'SIZE' IS <BA2, 4618 BYTES. ^THE LARGEST IS <B11, 23050 BYTES.
; .S
; ^IF A USER'S  PROGRAM CALLS FOR MORE THAN THE
; SPACE ALLOTED TO IT, THE COMPUTER STOPS EXECUTION
; AND PRINTS OUT A ^^USERS OVERFLOW\\ ERROR MESSAGE.
; ^EXIT AND RE-ENTER THE <BASIC MODE AT A HIGHER
; VERSION.
; .FG 1
; ^ALL NUMERIC CALCULATION IS DONE IN FLOATING POINT (^^REAL*4\\ FOR YOU
; ^^FORTRAN\\ BUFFS) REGARDLESS OF THE VARIABLE TYPES IN THE EXPRESSION.
; .S
; .HEADERLEVEL 1 ^STATEMENT AND LINE FORMAT
; .X ^STATEMENT AND LINE FORMAT
; .BR
; ^MULTIPLE STATEMENTS MAY BE CONCATENATED ON A SINGLE LINE BY USE OF
; THE COLON (:) CHARACTER.
; ^A BACKSLASH (_\) IS ALSO ALLOWED FOR <BASIC-<PLUS COMPATIBILITY.
; ^A LINE MAY BE CONTINUED ON THE NEXT LINE WITHOUT USING A NEW LINE
; NUMBER BY STARTING THE CONTINUED LINE WITH A TAB OR TWO SPACES.
; ^CONTINUED LINES ARE TREATED THE SAME WAY AS IN <BASIC-PLUS: THE
; END OF A PHYSICAL LINE IS IGNORED DURING EXECUTION SO LONG AS AN
; INDIVIDUAL <BASIC ELEMENT IS NOT BROKEN ACROSS LINE BOUNDARIES.
; ^THE END OF LINE DOES NOT SERVE TO END A STATEMENT EXCEPT WHEN
; THERE IS NO CONTINUED LINE FOLLOWING IT. ^THUS A STATEMENT WHICH
; BEGINS ON A CONTINUED LINE MUST EITHER HAVE A CONCATENATION
; CHARACTER AT THE START OF ITS LINE OR THE END OF THE PREVIOUS
; LINE. ^THERE IS AN EXCEPTION IN THE CASE OF A COMMENT (! ONLY)
; TERMINATING THE PREVIOUS LINE, IN WHICH CASE NO CONCATENATION
; CHARACTER IS USED.
; ^CARE SHOULD BE TAKEN NOT TO START AN IMMEDIATE MODE
; COMMAND WITH A TAB OR DOUBLE SPACE AS IT WILL NOT BE EXECUTED BUT
; ADDED TO THE EXISTING PROGRAM AS A CONTINUATION OF THE LAST ENTERED
; PROGRAM LINE.
; .S
; ^NOTE THAT CHECKING OF PROGRAM STATEMENTS FOR VERB LEGALITY AS THEY
; ARE READ IN BY THE INTERPRETER IS NO LONGER DONE AS IT WAS IN
; EARLIER VERSIONS. ^ALL CHECKING IS NOW DONE AT RUN TIME.
; .S
; .HEADERLEVEL 1 ^VARIABLE NAMES
; .X ^VARIABLES
; .BR
; ^VARIABLE NAMES MAY BE ONE OR TWO CHARACTERS OF WHICH THE FIRST IS ALPHA
; AND THE SECOND (IF USED) IS ALPHANUMERIC, FOLLOWED BY AN OPTIONAL TYPE
; CHARACTER. ^IF NO TYPE CHARACTER IS USED, THE TYPE IS <REAL*4. ^A $ DENOTES
; A STRING VARIABLE, % IS AN INTEGER VARIABLE (16 BITS) AND _& IS A BYTE
; VARIABLE (8 BITS). ^NOTE THAT UNLIKE STANDARD <BASIC, THE SECOND CHARACTER
; OF THE VARIABLE NAME IS ALLOWED TO BE ALPHABETIC. ^IN ORDER TO GAIN THIS
; FLEXIBILITY IN NAMING VARIABLES, SOME RESTRICTIONS HAD TO BE MADE IN THE
; ALLOWED FORMAT OF THE PROGRAM TEXT: SPACES ARE NOT ALLOWED WITHIN A
; VARIABLE NAME; VARIABLE NAMES MUST NOT BE THE SAME AS <BASIC KEY WORDS
; (E.G. <TO AND <IF).
; ^ALSO, AMBIGUITIES MAY SOMETIMES ARISE WHEN A VARIABLE  IS NEXT TO A
; KEYWORD IN THE PROGRAM TEXT. ^THIS CAN USUALLY BE RESOLVED BY RE-WRITING
; THE TEXT. ^ALTHOUGH IT IS THEORETICALLY POSSIBLE TO RESOLVE THESE CASES IN
; THE INTERPRETER, THE EXPENSE IN TERMS OF INTERPRETER CODE LENGTH AND
; EXECUTION TIME DOES NOT SEEM TO WARRANT IT. ^CONSIDER THE FOLLOWING EXAMPLE:
; .NF
; ^^
;	100 IF A _< MT OR B=5. THEN 500
; \\
; .F
; ^THE ^T OF <MT AND THE ^O OF <OR ARE MISINTERPRETED BY <BASIC TO FORM
; THE KEYWORD <TO.
; ^THE STATEMENT CAN BE REWRITTEN UNAMBIGUOUSLY AS FOLLOWS:
; .NF
; ^^
; 	100 IF (A _< MT) OR (B=5.) THEN 500
; \\
; .F
; .S
; .HEADERLEVEL 1 ^VIRTUAL ARRAYS
; .BR
; .X ^VIRTUAL ARRAYS
; ^VIRTAUL ARRAYS ARE USED TO STORE EXTENSIVE NUMBERS OF VARIABLE VALUES,
; USUALLY MORE THAN IS PRACTICAL TO STORE IN AN IN-MEMORY ARRAY.
; ^THE USE OF VIRTUAL ARRAYS INVOLVES A SPECIAL FORM OF THE <DIM STATEMENT
; AND THE FILE <OPEN STATEMENT WITH THE BLOCK MODE SWITCH </BL.
; ^SEE THE <DIM STATEMENT DOCUMENTATION FOR DETAILS OF VARIABLE MAPPING
; INTO VIRTUAL ARRAY FILES.
; .S
; ^MECHANICS OF VIRTUAL ARRAY FILES: ^VIRTUAL ARRAY FILES ARE OPENED IN BLOCK
; MODE USING THE </BL SWITCH.
; ^THERE IS NO RECORD STRUCTURE SUPERIMPOSED OVER THE BASIC BLOCK STRUCTURE.
; ^THEREFORE ONLY THE FILE ACCESS MODE SWITCHES CAN BE USED IN CONJUNCTION
; WITH </BL. ^THIS ALSO IMPLIES THAT A VIRTUAL ARRAY FILE DOES NOT SUBTRACT
; FROM THE TOTAL NUMBER OF FILES (RECORD TYPE) WHICH MAY BE OPEN SIMULTANEOUSLY
; (CURRENTLY 6).
; .S
; ^VIRTUAL ARRAYS ARE MAINTAINED IN MEMORY ONE BLOCK AT A TIME (512 BYTES).
; ^WHEN A VARIABLE IS ACCESSED, THE APPROPRIATE BLOCK IS CALCULATED AND,
; IF NECESSARY, READ INTO MEMORY. ^IF ANY WRITING TO THAT BLOCK IS DONE,
; A FLAG IS SET AND WHEN A DIFFERENT BLOCK NEEDS TO BE READ IN, THAT ONE
; IS WRITTEN OUT. ^THIS HAS SEVERAL IMPLICATIONS: ^FIRST, ON A VIRTUAL FILE
; OPENED FOR READ ONLY ACCESS, AN ILLEGAL WRITE WILL NOT BE DETECTED UNTIL
; THE BLOCK AS A WHOLE ATTEMPTS TO BE WRITTEN OUT. ^ALSO, IN THE CASE THAT
; THE INTERPRETER ABORTS OR THE SYSTEM CRASHES, NEW OR CHANGED DATA MAY BE
; LOST FOR THAT BLOCK WHICH IS THEN IN MEMORY.
; .SKIP
; .HEADERLEVEL 1 ^STRING CONSTANTS
; .BR
; .X ^STRINGS
; ^STRING CONSTANTS ARE SPECIFIED WITH DOUBLE QUOTES.
; ^AT THIS POINT IT IS NOT POSSIBLE TO REPRESENT A DOUBLE QUOTE
; IN A STRING CONSTANT, I.E. A STRING DELIMITED BY DOUBLE QUOTES.
; ^HOWEVER, THIS LIMITATION MAY BE GOTTEN AROUND BY USING ^^INPUT\\
; OR ^^READ\\ OR THE ^^CHR$\\ FUNCTION.
; .SKIP
; .HEADERLEVEL 1 ^DATA AND FILE PRESERVATION
; .BR
; .X ^^CLEAR\\
; .X ^^RUN\\
; .X ^FILE CLOSE
; ^USER DATA IS NOW KEPT INTACT EXCEPT FOR ^^CLEAR\\ AND ^^RUN\\ COMMANDS.
; ^USER FILES ARE AUTOMATICALLY CLOSED ON EXECUTION OF THE ^^RUN\\
; OR ^^CLEAR\\ COMMANDS AND ON EXIT FROM ^^BASIC\\.
; ^THEY REMAIN OPEN (UNLESS EXPLICITLY CLOSED BY A ^^CLOSE\\ COMMAND)
; ON PROGRAM STOP FOR DEBUGGING PURPOSES.
; .SL
; .HEADERLEVEL 1 ^STRING VARIABLES
; .BR
; ^STRING VARIABLES ARE DECLARED IN A ^^DIM\\ STATEMENT AND CAN BE EITHER
; FIXED OR VARIABLE LENGTH.
; ^SEE ^^DIM\\ STATEMENT FOR THE SPECIFICS.
; .SL
; .HEADERLEVEL 1 ^EXPONENTIATION
; .X ^EXPONENTIATION
; .X ^POWERS OF NUMBERS
; .BREAK
; ^EXPONENTIATION (_^) IS DONE IN TWO WAYS.
; ^IF THE EXPONENT IS AN INTEGER, THE BASE IS MULTIPLIED (OR DIVIDED)
; BY ITSELF THE APPROPRIATE NUMBER OF TIMES.
; ^IF THE EXPONENT CONTAINS A FRACTIONAL PART, A LOG - ANTILOG CALCULATION
; SEQUENCE IS USED.
; .SL
; .HEADERLEVEL 1 ^^MCR COMMAND LINE\\
; .X ^^MCR COMMAND LINE\\
; .BREAK
; ^^BASIC\\ IS CALLED FROM THE ^^MCR\\ BY TYPING ^^BASIC\\ (OR ^^BAS\\)
; IN RESPONSE TO THE ^^MCR\\ PROMPT.
; ^A _<^C^R> MAY FOLLOW FOR NORMAL INTERACTIVE USE OR ONE OF TWO OTHER
; OPTIONS MAY FOLLOW BEFORE _<^C^R> FOR SPECIAL USES.
; .FG 1
; ^IF A SPACE AND A ? FOLLOWED BY AN ARITHMETIC EXPRESSION FOLLOWS ^^BAS\\,
; THE VALUE OF THE EXPRESSION WILL BE PRINTED ON THE NEXT LINE FOLLOWED
; BY A RETURN TO THE ^^MCR\\.
; ^THIS IS USEFUL FOR QUICK DESK CALCULATOR TYPE CALCULATIONS.
; .FG 1
; ^IF A SPACE (OR TAB) AND A FILE NAME WITH AN OPTIONAL SWITCH FOLLOW,
; THEN THAT FILE WILL BE READ IN AS A USER PROGRAM JUST AS IN THE ^^OLD\\
; COMMAND.
; .FG 1
; ^IF THE SWITCH (/^R^N) IS SPECIFIED, THE PROGRAM WILL ALSO BE RUN AS
; THOUGH THE ^^RUN\\ COMMAND HAD BEEN TYPED.
; ^A SWITCH OF THE FORM "</RN:NNN" WILL CAUSE THE PROGRAM TO START
; EXECUTION AT LINE _# <NNN.
; .FG 1
; ^IF THE SWITCH (/^C^O) IS ADDED, THEN THE FILE RETRIEVED WILL BE
; ASSUMED TO BE PREVIOUSLY COMPILED AND A DEFAULT EXTENSION OF <BAC
; WILL BE USED.
; .NOTE
; ^NOTE THAT NO QUOTES ARE USED HERE AS OPPOSED TO THE ^^OLD\\ AND
; ^^RUN\\ COMMANDS.
; .ENDNOTE
; ^EXAMPLES:
; .NOFILL
; ^^
;	MCR>{BAS}
;	MCR>{BASIC PROG.BAS/RN}
; 	MCR>{BAS PROG/RN:150}
;	MCR>{BAS ? 4*3+2}
; \\
; .FILL
;-
;+2
; ^THE SUBSET OF COMMANDS LISTED IN THIS CHAPTER IS PRIMARILY USED TO CONTROL
; EXECUTION OF <BASIC PROGRAMS. ^THEIR PURPOSE IS TO LET ONE LOAD
; SAVED PROGRAMS, INTERACTIVELY MODIFY/DEBUG THEM WHILE RUNNING, AND
; POSSIBLY SAVE MODIFIED VERSIONS FOR LATER USE.
; ^AS SUCH, THE EQUIVALENT COMMANDS NORMALLY DO NOT EXIST FOR COMPILED
; LANGUAGES SUCH AS <FORTRAN.
;-
;+3
; ^THE SUBSET OF COMMANDS LISTED IN THIS CHAPTER IS PRIMARILY USED TO
; CONTROL THE FLOW OF PROGRAM EXECUTION, RESERVE
; STORAGE AREA FOR VARIABLES, PERFORM ARITHMETIC CALCULATIONS, ETC.
;-
;+4
; ^THE FUNCTIONS LISTED IN THIS CHAPTER ARE PRIMARILY ARITHMETIC IN NATURE.
; ^THEY RETURN ARITHMETIC VALUES OR CERTAIN SYSTEM VALUES SUCH AS THE
; ^DATE OR THE ^TIME.
;-
;+5
; ^THE FUNCTIONS LISTED IN THIS CHAPTER ARE PRIMARILY CHARACTER STRING
; ORIENTED. ^THEY PROVIDE WIDE CAPABILITY FOR EXAMINING AND ALTERING
; VARIABLES WHICH CONTAIN CHARACTER STRINGS, AND FOR CONVERSION FROM/TO
; OTHER DATA FORMATS.
;-
;+6
; ^THE COMMANDS LISTED IN THIS CHAPTER ARE PRIMARILY CONCERNED WITH
; ^INPUT AND ^OUTPUT. ^THEY PROVIDE THE CAPABILITY OF OPENING FILES,
; READING/WRITING DATA IN VARIOUS FORMATS, AND CLOSING THE FILES WHEN DONE.
;-
;+7
; ^THIS CHAPTER IS PRIMARILY CONCERNED WITH THE OPERATION OF USER WRITTEN
; <MACRO SUBROUTINES. ^THE CAPABILITY OF CALLING A MACHINE LANGUAGE
; SUBROUTINE TO PERFORM SOME COMPLEX CALCULATION CAN PROVIDE MUCH SIMPLER
; PROGRAM OPERATION, AND/OR SIGNIFICANTLY INCREASE THE SPEED OF OPERATION.
; .FG 1
; ^SEVERAL SPECIAL <MACRO SUBROUTINES PROVED SO USEFUL THAT THEY WERE MADE
; A PERMANENT PART OF <BASIC AND AS SUCH DO NOT HAVE TO BE LOADED.
; ^THOSE ROUTINES ARE LISTED IN THIS CHAPTER.
; .FG 1
; ^A SAMPLE OF A <MACRO SUBROUTINE WHICH WILL REVERSE A CHARACTER STRING
; ALONG WITH A DESCRIPTION OF THE INTERNAL <BASIC SUBROUTINES IT USES
; IS INCLUDED IN ^APPENDICES ^B _& ^C OF THIS MANUAL.
;-

; BASIC TRAP AND ERROR HANDLER -
;	ERROR CALLS IN BASIC ARE MADE BY TRAP CALLS; NORMAL SUBROUTINE
;	TRANSFERS ARE MADE BY JSR PC'S UNDER RSX
;
;	SUBROUTINE CALLS ARE MADE BY MACRO'S WHICH ARE EXPANDED INTO JSR'S.
;

	.SBTTL	TRAP ERROR CALLS - MACRO DEFINITIONS
;
; THE FOLLOWING IS A LIST OF IMPLEMENTED ERROR CALLS.  ALL ERRORS LESS
;	THAN "FENCE" ARE FATAL, ALL GREATER ARE NON-FATAL.
;
; FATAL ERROR CALLS
;
TRAP=104400		;PROTOTYPE TRAP INSTR. FOR MACRO
	TV	OVFERR	;USER STORAGE OVERFLOW - 0
	TV	UNRERR	;UNRECOGNIZED STATEMENT - 1
	TV	GOERR	;ILLEGAL GOTO OR GOSUB - 2
	TV	ILCERR	;ILLEGAL CHARACTER TERMINATING STMT - 3
	TV	RETERR	;RETURN WITHOUT GOSUB - 4
	TV	SBSERR	;BADLY FORMED SUBSCRIPT - 5
	TV	SUBERR	;SUBSCRIPT OUT OF RANGE - 6
	TV	PARERR	;MISMATCHED PARENTHESES - 7
	TV	LETERR	;ILLEGAL LET - 8
	TV	OPRERR	;ILLEGAL RELATIONAL OPERATOR IN IF - 9
	TV	IFERR	;ILLEGAL IF - 10
	TV	PRNERR	;ILLEGAL PRINT - 11
	TV	LINERR	;INPUT LINE TOO LONG - 12
	TV	DIMERR	;BAD DIMENSION - 13
	TV	DMVERR	;NOT ENOUGH ROOM IN STORAGE FOR THE ARRAY - 14
	TV	DEFERR	;BADLY FORMED DEFINE - 15
	TV	LNNERR	;ILLEGAL LINE NUMBER OR DIMENSION VALUE - 16
	TV	DMDERR	;DIM OF PREVIOUSLY DECLARED OR USED ITEM - 17
	TV	INPERR	;BAD VARIABLE IN INPUT LIST - 18
	TV	REAERR	;BAD VARIABLE IN READ LIST - 19
	TV	RE1ERR	;OUT OF DATA - 20
	TV	RE2ERR	;BAD FORMAT IN A DATA STATEMENT - 21
	TV	FORERR	;ILLEGAL FOR STATEMENT - 22
	TV	NXTERR	;NO NEXT MATCHING FOR - 23
	TV	NXMERR	;NEXT WITHOUT FOR - 24
	TV	UNMERR	;UNMATCHED QUOTES IN STATEMENT - 25
	TV	EXFERR	;EXTERNAL FUNCTION NOT PROPERLY SET UP - 26
	TV	ILFERR	;ILL FORMED EXPRESSION - 27
	TV	CSIERR	;COMMAND STRING ERROR - 28
	TV	STRERR	;SBS FUNCTION ERROR - 29
	TV	STXERR	;SYNTAX ERROR IN FUNCTION - 30
	TV	OPNERR	;SYNTAX ERROR IN OPEN - 31
	TV	CLSERR	;SYNTAX ERROR IN CLOSE - 32
	TV	FNMERR	;INVALID FILE NUMBER - 33
	TV	EOFERR	;END OF FILE ERROR - 34
	TV	CLOSER	;FCS ERROR DURING CLOSE - 35
	TV	OPENER	;FCS ERROR DURING OPEN - 36
	TV	CALERR	;ERROR IN PROCESSING CALL STATEMENT - 37
	TV	ARGERR	;ERROR IN PROCESSING CALL ARGUMENTS - 38
	TV	STOERR	;ERROR IN STORE DURING CALLED ROUTINE - 39
	TV	OPLBER	;ERROR IN SYNTAX OR LUN IN USE IN LIB OPEN - 40
	TV	OPLFER	;FCS ERROR IN LIBRARY OPEN OR FIRST READ - 41
	TV	SLPERR	;ERROR IN SLEEP COMMAND - 42
	TV	WATERR	;ERROR IN WAIT COMMAND - 43
	TV	TMOERR	;TIMEOUT ERROR ON INPUT - 44
	TV	PRIERR	;PRIORITY ERROR - 45
	TV	PRFERR	;PROGRAM FILE ERROR - 46
	TV	FACERR	;FILE ACCESS MODE ERROR - 47
	TV	LODERR	;ERROR IN LOADED USER SUBROUTINE - 48
	TV	VFIERR	;VIRTUAL FILE ACCESS ERROR - 49
	TV	VOPERR	;VIRTUAL FILE OPEN ERROR - 50
	TV	SETERR	;ERROR IN SET COMMAND - 51
	TV	COMERR	;USE OF /CO SWITCH ON NORMAL BASIC SOURCE -52
	TV	IMMERR	;IMMEDIATE MODE COMMAND IN SOURCE PROGRAM -53
	TV	VTMERR	;VARIABLE TYPE MIS-MATCH -54
TRAP=104500-2		;SET ADDRESS FOR START OF DEBUGGING CODES
	TV	TM1ERR	;DEBUGGING ERROR #1 - 62
	TV	TM2ERR	;DEBUGGING ERROR #2 - 63

;
; NON-FATAL ERROR CALLS
;
TRAP=104500		;SET ADDRESS FOR NON-FATAL ERRORS
FENCE=TRAP-104400
;
	TV	LOGERR	;LOG OF NEGATIVE OR ZERO NUMBER - 64
	TV	SQRERR	;SQUARE ROOT OF NEGATIVE NUMBER - 65
	TV	DVFERR	;DIV.-MUL. OVERFLOW OR UNDERFLOW - 66
	TV	FIXERR	;NUMBER TOO LARGE TO FIX - 67
	TV	FOFERR	;FLOATING POINT OVERFLOW - 68
	TV	FUFERR	;FLOATING POINT UNDERFLOW - 69
	TV	NXVERR	;NON-EXISTENT VARIABLE - 70
	TV	IN1ERR	;TOO MUCH DATA TYPED - 71
	TV	IN2ERR	;NOT ENOUGH DATA TYPED - 72
	TV	IN3ERR	;ILLEGAL CHARACTERS ON INPUT - 73
	TV	VALERR	;ERROR IN VAL FUNCTION - 74
;
; END OF DIAGNOSTIC CALLS
;

	.SBTTL	ERROR TRAP HANDLER
;
;
; TRAP AND ERROR HANDLER
;	FATAL ERRORS WIPE OUT THE SYSTEM STACK AND RETURN TO THE
;	COMMAND INTERPRETER AFTER GIVING THE DIAGNOSTIC.  NON-FATAL
;	ERRORS RETURN TO THE CALLING ROUTINE.
; REGISTER ASSIGNMENTS
;
R0	=	%0		;TEMPORARY AND PARAMETER TRANSFER
R1	=	%1		;TEMPORARY AND PARAMETER TRANSFER
R2	=	%2		;SCRATCH
R3	=	%3		;SCRATCH
R4	=	%4		;SCRATCH
R5	=	%5		;USER LIST POINTER
SP	=	%6		;BASIC STACK POINTER
PC	=	%7		;PROGRAM COUNTER
;
TRAP=104400		;FOR USE BY TRAP HANDLER
;
	.PSECT	BASIC0,RW,I,LCL,REL,CON	;MAIN OF TRPHDL
TRAP00:	MOV	(SP)+,R2	;2*LOWER BYTE IN R2
	MOV	(SP)+,(SP)	;SET STACK FOR POSSIBLE RTS,PC
	ASR	R2		;LOWER BYTE OF TRAP IN R2
	CMP	R2,#FENCE	;IS IT FATAL?
	.IF	DF	RSX11M
	BGE	ERRR01		;FOR 11M
	.IFF
	BGT	ERRR01		;FOR 11D
	.ENDC
	MOV	#TINPT,INPT	;RESET FILE CONTROL BLOCK ADDRESSES
	MOV	#TOTPT,OTPT
	CLR	LINEFL		;IN CASE BINARY OR INPUT LINE FAILED
	MOV	ENUSAV,ENUDAT	;RESTORE OLD END OF DATA IN CASE CORRUPTED
	CLOSEF			;IN CASE FROM OLD
	MOV	ENDSTK,SP	;ZAP THE STACK
	MOV	#STOP02,-(SP)	;GET NEW RETURN ADDRESS
ERRR01:	MOV	R2,PARLST+P.ERCD ;PUT ERROR CODE IN PARAMETER LIST
	.IF DF	RSX11D
	INC	R2		;INCREMENT TO USE FOR REC NO
	MOV	R2,MODPB+M.ONUM	;PUT IN DPB FOR MO
	MOV	MOLUN,MODPB+M.OLUN ;SET UP LUN PROPERLY
	.ENDC
	MOV	LINENO,PARLST+P.LINE ;PUT CURRENT LINE NO IN PAR LIST
	TST	ERRBRN		;ERROR HANDLING ROUTINE DEFINED?
	BGT	ERBR		;IF SO, BRANCH
	CLR	WTMAG		;SET FOR NO TIME OUT
	.IF DF	RSX11D                                                          ;DSS1
	CMP	R2,#FENCE+1	;SEE IF MODIFIED ERROR CODE PAST FATAL
	.IFF
	CMP	R2,#FENCE	;SEE IF ERROR CODE PAST FATAL
	.ENDC
	BGE	2$		;IF SO, SKIP DETACH
	JSR	PC,DETACH	;NULLIFY ^O
2$:
	.IF DF	RSX11D
	DIR$	#MODPB		;PERFORM MO QIO
	BCS	ERRR06		;IF MO DIDN'T GO, DO REGULAR MESSAGE
	MOWA$S			;WAIT FOR MO TO FINISH
1$:	BR	ERRR07		;IF OK EXIT ROUTINE
	.ENDC
ERRR06:	MOV	R1,-(SP)	;SAVE TEXT POINTER
	.IF DF	RSX11D
	DEC	R2		;GET CODE BACK TO ORIGINAL VALUE
	.ENDC
	MOV	R2,R1
	MOV	#ERRR02,R0	;ASCII DESTINATION
	ITOA
	MOV	OTPT,-(SP)	;SAVE CURR FILE CONTROL BLOCK ADDR
	MOV	#TOTPT,OTPT	;FORCE OUTPUT TO TERMINAL
	CRLF
	MOV	#ERRR03,R0	;START OF MESSAGE
	PRINTL			;PRINT THE LINE
	MOV	#ERRR05,R0
	PRINTL
	PRNTLN			;AND THE LINE NUMBER
	CRLF
	MOV	(SP)+,OTPT	;RESTORE FILE CONTROL BLOCK POINTER
ERRR04:	MOV	(SP)+,R1	;RESTORE R1
ERRR07:                                                                         ;DSS1
	.IF	DF,FPPEMU	;IF FPP EMULATION                               ;DSS1
	.IFF			;IF NOT                                         ;DSS1
	TST	FPEXFL		;ANY FLOATING POINT EXCEPTIONS?                 ;DSS1
	BEQ	1$		;IF NOT, SKIP PROCESSING                        ;DSS1
	.IFTF			;WHETHER OR NOT                                 ;DSS1
	JSR	PC,FPERMS	;IF SO, REPORT THEM
	.ENDC
1$:	RTS	PC		;AND RETURN
ERBR:	MOV	ERRBRN,R0	;ERROR ROUTINE LINE NUMBER IN R0
	MOV	ENDSTK,SP	;ZAP THE STACK
	CLR	-(SP)		;INDICATE EXACT LINE NUMBER WANTED
	CLR	ERRBRN		;JUST IN CASE ERROR IN ERROR ROUTINE
	MOV	USR,R1		;START SEARCH FROM START OF CODE
	JMP	GOTO03		;GO TO IT
;+1
; .SL
; .HEADERLEVEL 1 ^CONTROL ^C
; .BR
; .X _^^C
; .X ^CONTROL ^C
; ^THE BREAK KEY FOR ^^BASIC\\ IS THE ^CONTROL-^C (_^^C).
; ^A _^^C TYPED AT THE KEYBOARD WHEN RUNNING WILL CAUSE THE PROGRAM
; TO STOP AT THE NEXT SEQUENTIAL LINE (NOT AT A LINE ENTERED VIA
; <GOTO, <GOSUB, <IF ETC.).
; ^WHEN IN IMMEDIATE MODE, _^^C WILL BRING UP <MCR IF THE TERMINAL HAS
; NOT BEEN SET HOSTILE.
; _^^C TYPED DURING A LIST COMMAND WILL TERMINATE THE LISTING PROCESS
; AFTER THE CURRENT LINE IS FINISHED PRINTING OUT.
; ^IT CAUSES AN IMMEDIATE RETURN TO THE INTERPRETER AS OPPOSED TO
; _^^O WHICH ONLY SUPPRESSES PRINTING WHILE THE <BASIC INTERPRETER
; STILL GOES THROUGH THE MOTIONS OF COMPLETING THE LISTING.
;-
;
; AST ENTRY FOR ^C BREAK ROUTINE
;
CTCENT:
	.IF	NDF RSX11D	;CONDITIONAL CODE FOR RSX-11M
				;^C COMES ON STACK JUST LIKE
				;ANY OTHER UNSOLICITED CHAR.
	CMP	(SP)+,#3	;WAS CHAR ^C?
	BNE	1$		;IF NOT, IGNORE IT
	.ENDC
	INC	BRFLAG
1$:	ASTX$S			;AST SERVICE EXIT
;
; CODE TO HANDLE FLOATING POINT EXCEPTION TRAPS
; NO REGISTERS ARE DESTROYED
;
	.IF	DF,FPPEMU	;IF FPP EMULATION                               ;DSS1
	.IFF			;IF NOT                                         ;DSS1
FPEXTR:	MOV	2(SP),(SP)	;MOVE FEC STATUS (OVERWRITE ADDRESS)
	MOV	R0,2(SP)	;SAVE R0
	MOV	(SP)+,R0	;FEC -> R0
	MOV	R2,-(SP)	;SAVE R2
	CLR	R2		;PREPARE FOR FUTURE USE
	ASR	R0		;DIVIDE ERROR NUMBER BY 2
	DEC	R0		;AND DECREMENT
	BLE	2$		;IF ZERO OR NEG, NO ERROR
	CMP	R0,#4		;IF > 4, ALSO
	BGT	2$		;NO ERROR TO REPORT
	SEC			;GET BIT READY TO SHIFT IN
1$:	ROL	R2		;SHIFT OVER ONE
	SOB	R0,1$
	BIS	R2,FPEXFL	;SET APPROPRITE FLAG BIT
2$:	MOV	(SP)+,R2	;RESTORE OLD R2
	MOV	(SP)+,R0	;RESTORE OLD R0
	ASTX$S			;EXIT FROM AST ROUTINE
;
; THIS SUBROUTINE SHOULD BE CALLED FOR ERROR MESSAGE PROCESSING
; AFTER POSSIBLE FLOATING EXCEPTION ERRORS.
; IT CHECKS THE FLOATING POINT EXCEPTION FLAGS WORD AND PRINTS
; TRAPS TO THE APPROPRIATE ERROR ROUTINE (USER OR SYSTEM)
; NOTE THAT IN THE CASE OF A USER ERROR ROUTINE BRANCH, ONLY
; THE FIRST OF THE FOUR FLOATING POINT ERRORS WHICH OCCURS
; WILL BE ACTED UPON AND RECORDED.
;
; REGISTERS USED - R0,R2
;
FPERMS:	MOV	FPEXFL,R0	;GET ERROR BIT CODES IN R0
	MOV	#2$-4,R2	;JUMP LIST ADDRESS TO R2
	CLR	FPEXFL		;CLEAR THE FLAGS, SO WE DON'T LOOP
3$:	ADD	#4,R2		;STEP THROUGH THE LIST
	ASR	R0		;AND NOW GET ERROR BIT IN 'C'
	BCC	1$		;IF NOT SET, NO ACTION
	MOV	R0,-(SP)	;SAVE REGISTERS IN CASE
	MOV	R2,-(SP)	;WE COME BACK HERE
	JMP	(R2)		;GO DO ERROR TRAP
1$:	BNE	3$		;IF STILL BITS LEFT, KEEP CHECKING
	RTS	PC
2$:	DVFERR			;FLOATING DIVIDE BY ZERO
	BR	5$
	FIXERR			;FLOATING -> INTEGER CONVERSION OVFLOW
	BR	5$
	FOFERR			;FLOATING OVERFLOW ERROR
	BR	5$
	FUFERR			;FLOATING UNDERFLOW ERROR
5$:	MOV	(SP)+,R2	;RESTORE SAVED REGISTERS
	MOV	(SP)+,R0
	BR	3$
;
	.IFT			;IF FPP EMULATION, DO IT DIFFERENTLY            ;DSS1
                                                                                ;DSS1
FPEXTR=0		;DEFINE FPEXTR (SO THERE WON'T BE AN UNDEFINED GLOBAL)  ;DSS1
FPERMS:	MOV	R0,-(SP)	;SAVE REGS                                      ;DSS1
	MOV	R1,-(SP)                                                        ;DSS1
	STST	R1		;GET FLOATING EXCEPTION CODE, IF ANY            ;DSS1
	SUB	#ERRDIV,R1		;4=DIVIDE BY ZERO                       ;DSS1
	BLT	1$			;6=CONVERSION TO INTEGER ERROR          ;DSS1
	CMP	R1,#ERRUNR-ERRDIV	;8=OVERFLOW                             ;DSS1
	BGT	1$			;10=UNDERFLOW                           ;DSS1
	ASL	R1                                                              ;DSS1
	ADD	#5$,R1                                                          ;DSS1
	JSR	PC,(R1)                                                         ;DSS1
1$:	MOV	(SP)+,R1	;RESTORE REGS                                   ;DSS1
	MOV	(SP)+,R0                                                        ;DSS1
	RTS	PC                                                              ;DSS1
5$:	DVFERR			; 4                                             ;DSS1
	RTS	PC                                                              ;DSS1
	FIXERR			; 6                                             ;DSS1
	RTS	PC                                                              ;DSS1
	FOFERR			; 8                                             ;DSS1
	RTS	PC                                                              ;DSS1
	FUFERR			; 10                                            ;DSS1
	RTS	PC                                                              ;DSS1
                                                                                ;DSS1
	.ENDC                                                                   ;DSS1
                                                                                ;DSS1
;-554,595,/;DSS1/                                                               ;DSS1
	.IF DF	RSX11D
STRD:	.WORD	STR1E-STR1	;DEFINE STRING(FILENAME) LENGTH
	.WORD	STR1		;ADDRESS OF FILENAME STRING
STR1:	.ASCIZ	/LB:[1,2]BASIC/
STR1E:
	.ENDC
	.END