.ENABLE SUBSTITUTION
.ENABLE GLOBAL
.;
.;	TIMGEN Y01.03
.;
.;	DECnet time sender and setter task generation
.;
.;	To chain into this file, define the following symbols:
.;	$TSET - Logical TRUE - To build the time setter task
.;	$TSND - Logical TRUE - To build the time sender task
.;	$LIST - Logical TRUE - To generate spooled listings and maps
.;	$NUIC - Numeric octal UIC - Network UIC
.;
;
;	TIMGEN Y01.03
.IFDF $TSET	.GOTO 10
;
		.ASK $TSET Build the time setter task
.10:
.IFDF $TSND	.GOTO 20
;
		.ASK $TSND Build the time sender task
.20:
		.SETS LIST ""
.IFDF $LIST	.GOTO 30
;
		.ASK $LIST Generate unspooled listings and maps
.30:
.IFDF $NUIC	.GOTO 40
;
		.ASKN $NUIC What UFD group is the network kept in
.40:
.IFF $TSET	.GOTO 50
;
;	Build the network time setter task
;
.IFT $LIST	.SETS LIST ", TIMREC/-SP"
		.OPEN CAMCER.CMD
		.DATA TIMREC'LIST' = LB:[1,1]NETLIB.MLB/ML, -
		.DATA LB:['$NUIC',10]RSXMC.MAC/PA:1, -
		.DATA SY:'<UIC>'TIMREC.MAC
		.CLOSE CAMCER.CMD
.;
		.OPEN DLBCER.CMD
		.DATA TIMREC/PR:0/-FP/-CP'LIST' = SY:'<UIC>'TIMREC
		.DATA /
		.DATA UNITS=4
		.DATA ACTFIL=0
		.DATA UIC=['$NUIC',54]
		.DATA PRI=100
		.DATA TASK=TIMREC
		.DATA //
		.CLOSE DLBCER.CMD
.;
		MAC @CAMCER
		TKB @DLBCER.CMD
		PIP CAMCER.CMD;*, DLBCER.CMD;*/NM/DE, TIMREC.OBJ;*

.50:
.IFF $TSND	.GOTO 60
;
;	Build the network time sender task
;
.IFT $LIST	.SETS LIST ", TIMSND/-SP"
	MAC TIMSND'LIST' = LB:[1,1]NETLIB.MLB/ML, SY:'<UIC>'TIMSND.MAC
		.OPEN DLBDNS.CMD
		.DATA TIMSND/PR:0/-FP/-CP'LIST' = SY:'<UIC>'TIMSND
		.DATA /
		.DATA UNITS=3
		.DATA ACTFIL=0
		.DATA UIC=['$NUIC',54]
		.DATA PRI=100
		.DATA TASK=TIMSND
		.DATA //
		.CLOSE DLBDNS.CMD
.;
		TKB @DLBDNS.CMD
		PIP DLBDNS.CMD;*/NM/DE, TIMSND.OBJ;*
.60:
;
;	All done.
;