$! CALENDAR TICKLER FILE
$SET NOON
$ TODAY=F$TIME()
$ DDAT=F$EXTRACT(0,11,TODAY)
$! GET DEFAULT DATE = TODAY'S FOR START.
$INQUIRE LODATE "What is the start date for this reminder?"
$IF LODATE .EQS. "" THEN LODATE = DDAT
$!NOW SEE IF THE DATE IS OF FORM WITH YEAR AS "1983" OR SO, OR
$! IF JUST "83" WAS USED FOR YEAR (OR LATER YEARS, OF COURSE...)
$YR=F$EXTRACT(7,4,LODATE)
$YN=F$INTEGER(YR)
$IF YN .LT. 1900 THEN YN=YN+1900
$YS=F$STRING(YN)
$LDT=F$EXTRACT(0,7,LODATE)
$LDT=LDT+YS
$! NOW LOW DATE IS VALID FOR SAVING...
$DDAT=LDT
$LDT=LDT+" 00:01:00.01"
$LODATE=F$CVTIME(LDT)
$INQUIRE HIDATE "What is the end date for this reminder?"
$IF HIDATE .EQS. "" THEN HIDATE = DDAT
$YR=F$EXTRACT(7,4,HIDATE)
$YN=F$INTEGER(YR)
$IF YN .LT. 1900 THEN YN=YN+1900
$YS=F$STRING(YN)
$HDT=F$EXTRACT(0,7,HIDATE)
$HDT=HDT+YS+" 23:59:59.00"
$HIDATE=F$CVTIME(HDT)
$! NOW HAVE LOW AND HIGH DATES IN COMPARE-ABLE FORMAT
$!STORE IN LOGIN CALTIK.DAT IF PRESENT,OR CREATE THAT FILE.
$TIKL=F$SEARCH("SYS$LOGIN:CALTIK.DAT")
$IF TIKL .NES. "" THEN GOTO OPNOLD
$! NEW FILE... CREATE HERE
$MCR PIP SYS$LOGIN:CALTIK.DAT=NL:
$! USE THIS TRICK TO MAKE AN EMPTY FILE
$ OPNOLD:
$OPEN/APPEND OUTFIL SYS$LOGIN:CALTIK.DAT
$DLN=">>>>"+LODATE+"-->"+HIDATE
$WRITE OUTFIL DLN
$WRITE SYS$OUTPUT "Enter your message, return only on line when done"
$CPYLP:
$INQUIRE CMDLIN "Command:"
$CLN="-"+CMDLIN
$IF CMDLIN .EQS. "" THEN GOTO DUNLP
$WRITE OUTFIL CLN
$GOTO CPYLP
$ DUNLP:
$ CLOSE OUTFIL