.TITLE	SRDSUB---SORT DIRECTORY SUBROUTINES
	.IDENT	-6.0-
	.MCALL	DIR$
;+
; ATTDET---ATTACH/DETACH LISTING DEVICE
;
; THIS ROTINE IS CALLED TO ATTACH OR DETACH THE LISTING DEVICE
; IF THE DEVICE IS RECORD ORIENTED
;-
ATTDET::MOV	(R0)+,LSTQIO+2	; SET FUNCTION
10$:	DIR$	#LSTQIO		; ISSUE REQUEST
	BCC	20$		; BR IF A-OK
	CALL	ALERR		; DIAGNOS ERR
	BR	10$		; RETRY IF RETRYABLE
20$:	RTS	R0		; RETURN
;+
; SRDCOM --- COMPRESS DIRECTORY BUFFER.
;
;	R1 -> END OF DIRECTORY BUFFER
;	R2 -> BEGINNING OF DIRECTORY BUFFER
;	R3, R4, R5 ARE DESTROYED
;
;	DUKE001 -- 19-NOV-79,-5.0-, HENRY R. TUMBLIN
;		ADDED AS A SUBROUTINE
;	Modified by PASP to compress 'in order' so as not to screw
;	up a /-SR listing.
;-
SRDCOM::
	MOV	R2,R3		; COPY THAT FOR SORT
	MOV	R2,R4		; Twice
;
10$:
	CMP	R3,R1		; Finished?
	BHIS	40$		; If HIS yes - exit
	TST	(R3)		; SEE IF OCCUPIED
	BNE	20$		; BR IF YES
	ADD	#D.SIZ,R3	; No - set to next
	BR	10$		; And try again
;
20$:
	MOV	#<D.SIZ/2>,R5	; SET DIRECTORY SIZE IN WORDS
;
30$:
	MOV	(R3)+,(R4)+	; FILL IN HOLE WITH NEXT PROPER ENTRY
	SOB	R5,30$		; DO ENTIRE ENTRY
	BR	10$		; Check the next one
;
40$:
	MOV	R4,R3		; Get furthest we've used so far
;
50$:
	CMP	R3,R1		; Used the lot?
	BHIS	60$		; If HIS yes
	CLR	(R3)		; No - clear this one
	ADD	#D.SIZ,R3	; Set to next entry
	BR	50$		; And try next one
;
60$:
	MOV	R4,R1		; Update end of directory pointer
	CLR	(R1)		; Ensure it is empty
	RETURN			; AND RETURN TO THE CALLER.
;+
; CNVDAT---CONVERT DATE FROM STRING TO MONOTONICALLY INCREASING
; 	BINARY INTEGER.
;-
; 
	.NLIST	BEX
MONTHS:	.ASCII	\JAN\<-1>\FEB\<-1>\MAR\<-1>\APR\<-1>\MAY\<-1>\JUN\<-1>
	.ASCII	\JUL\<-1>\AUG\<-1>\SEP\<-1>\OCT\<-1>\NOV\<-1>\DEC\<-1>
	.LIST	BEX
	.BYTE	0
BLKPOS:	.BYTE				; POSITION OF FIRST SPACE
COLPOS:	.BYTE				; POSITION OF FIRST COLON
	.EVEN
CNVDAT::
	MOV	R0,-(SP)	; SAVE R0
	MOV	R1,-(SP)	; SAVE R1
	MOV	#16.,R0		; GET LENGTH OF STRING TO CHECK
	ADD	R0,R1		; SET R1 PAST END OF STRING
	MOVB	#17.,BLKPOS	; INITIALISE OFFSETS
	CLRB	COLPOS		;
;
10$:
	CMPB	-(R1),#''	; FOUND A QUOTE?
	BNE	20$		; IF NE NO - LOOK FOR HASH
	MOVB	R0,BLKPOS	; YES - STORE THE OFFSET
;
20$:
	CMPB	(R1),#'#	; FOUND A HASH?
	BNE	30$		; IF NE NO - FINISH LOOP
	MOVB	R0,COLPOS	; YES - STORE OFFSET
;
30$:
	SOB	R0,10$		; CHECK NEXT CHAR
	TSTB	COLPOS		; ANY TIME SPECIFIED?
	BNE	40$		; IF NE YES - CARRY ON
	CALL	CVDATE		; NO - CONVERT THE DATE
	CLR	R3		; AND SHOW NO TIME
	BR	80$		; AND EXIT
;
40$:
	CMPB	BLKPOS,COLPOS	; DATE OR TIME FIRST?
	BLT	60$		; IF LT THE DATE
	CALL	CVTIME		; ELSE CONVERT THE TIME
	MOVB	BLKPOS,R1	; GET THE BLANKS OFFSET
	ADD	(SP),R1		; INITIALISE THE ADDRESS OF THE DATE
	CMPB	BLKPOS,#17.	; NO DATE?
	BNE	50$		; OK WE HAVE ONE
	MOV	#TDBUF$,R1	; RESET TO TODAY
;
50$:
	CALL	CVDATE		; CONVERT THE DATE
	BR	80$		; RETURN
;
60$:
	CALL	CVDATE		; CONVERT THE DATE FIRST
	MOVB	BLKPOS,R1	; GET ADDRESS OF TIME
	ADD	(SP),R1		;
	CALL	CVTIME		; AND CONVERT THAT
;
80$:
	MOV	(SP)+,R1	; RESTORE R1
	MOV	(SP)+,R0	; RESTORE R0
	RETURN			; AND EXIT
;
CVDATE::
	JSR	R5,$SAVRG	; SAVE REGS 3,4,5
	CALL	CNV2		; CONVERT TO BINARY
	MOV	R2,-(SP)	; SAVE THAT MUCH
	BEQ	50$		; MUST BE SOMETING
	CMPB	#'-,(R1)+	; SKIP SEPARATOR
	BEQ	10$		; BR IF SEPARATOR
	DEC	R1		; BACK UP
10$:	MOV	#MONTHS,R4	; LIST OF ALL MONTHS
20$:	MOV	R1,R3		; COPY ADDRESS OF MONTH NAME
30$:	CMPB	(R3)+,(R4)+	; SAME?
	BEQ	30$		; BR AS LONG AS YES
	TSTB	-1(R4)		; END OF MONTH
	BMI	60$		; YES-FOUND IT
	ADD	#31.,(SP)	; NO ADD IN A MONTH'S WORTH OF DAYS
40$:	TSTB	(R4)+		; LOOK FOR NEXT MONTH
	BGT	40$		; BR IF NOT END
	TSTB	(R4)		; END OF LIST?
	BNE	20$		; BR IF NO
50$:	FERR	BADD		; BAD DATE FORMAT
60$:
	MOV	R3,R1		; COPY PLACE IN INPUT STRING
	CMPB	-(R1),#'-	; SEPARATOR?
	BNE	70$		; 
	INC	R1		; BACK UP
70$:	CALL	CNV2		; GET YEAR
	SUB	#70.,R2		; ADJ TO REL 1970
	BMI	50$		; BR IF BAD
	SWAB	R2		; MULT X 256
	ASL	R2		; 2 MORE = 512
	ADD	(SP)+,R2	; FIND TOTAL DATE
	RETURN
CVTIME::
	MOV	R2,-(SP)	; SAVE R2
	MOV	R5,-(SP)	; SAVE R5
	CALL	CNV2		; CONVERT FIRST TWO
	MOV	R2,R3		; SAVE THEM
	ASH	#6,R3		; MULTIPLY BY 64.
	CMPB	(R1)+,#'#	; DIVIDER?
	BEQ	10$		; IF EQ YES
	DEC	R1		; NO - DISCOUNT IT
;
10$:
	CALL	CNV2		; GET THE NEXT TWO
	ADD	R2,R3		; ADD THEM IN
	MOV	(SP)+,R5	; RESTORE REGISTERS
	MOV	(SP)+,R2	;
	RETURN
CNV2:	CLR	R2		; INIT ACCUMULATOR
	MOV	#2,R5		; SET MAX CHARS TO CONVERT
10$:	CMPB	(R1),#'0	; CHECK FOR RANGE
	BLO	20$		; BR IF OUT
	CMPB	(R1),#'9	; CHECK OTHER END
	BHI	20$		; BR IF OUT
	CLR	-(SP)		; GET A ZERO
	MOVB	(R1)+,(SP)	; GET THE VALUE
	SUB	#'0,(SP)	; REMOVE ASCII BIAS
	ASL	R2		; MULT PREVIOUS
	ADD	R2,(SP)		; SAVE TIME 2 RESULT
	ASL	R2		; X 4
	ASL	R2		; X 8
	ADD	(SP)+,R2	; FINAL RESULT OLD X 10 + NEW
	SOB	R5,10$		; LOOP?
20$:	RETURN
;
ALERR::
$ALERR::
	MOV	(SP),R0		;
	MOV	$DSW,R1		;
	HALT			;
	RETURN			;
	.END