.MACRO	ACCDF$,L,B

;
; ACCOUNTING SYSTEM VERSION 7 CONTROL BLOCK OFFSET DEFINITIONS
;
; STEVE THOMPSON, 1979.
; VERSION 7:		JANUARY 1981
;
;	SMT718	20-JUL-81	ADDED QMG PAGE COUNT INTERFACE
;	SMT735	 5-AUG-81	ADDED EXIT STATUS DISPLAY
;	SMT752	29-SEP-81	ADDED NAME OF DESPOOLER TASK FOR AC.PAG
;	SMT753	 7-OCT-81	CHANGED NAMES OF CONDITIONAL ASSEMBLY
;				PARAMETERS.
;	SMT757	 7-OCT-81	ADDED OFFSETS FOR MEMORY USAGE ACCOUNTING.
;	SMT762	 9-OCT-81	ADDED BATCH V3 SUPPORT FOR "USE" COMMAND,
;				PLUS BATCH/INTERACTIVE LOAD FEATURE.
;	SMT767	12-OCT-81	REJECT LOGON IF UAB ALLOCATION ERROR
;	SMT788	13-NOV-81	ADDED AC.GAC REQUEST
;	SMT815	12-APR-82	MADE PRIORITY LINK A STANDARD FEATURE
;
	.ASECT
;
; TASK ACCOUNTING CONTROL BLOCK
;
.=0
B.LNK:'L' .BLKW	1		; LINK WORD
B.PRI:'L' .BLKB	1		; LINKING PRIORITY FIELD (*DO NOT MOVE*)
B.CKP:'L' .BLKB	1		; CHECKPOINTABILITY FIELD (*DO NOT MOVE*)
B.MASK:'L'			; MASK WORD OFFSET FOR COMMANDS
B.TCB:'L' .BLKW	1		; TCB ADDRESS OF TASK BEING ACCOUNTED
B.UCB:'L' .BLKW	1		; UCB ADDRESS OF OWNER TASK
B.UIC:'L' .BLKW	1		; LOGON UIC OF OWNER TASK'S TI:
	.IF DF	AA$MEM
B.ELPT:'L' .BLKW 2		; ELAPSED TIME OF TASK EXECUTION
B.CORE:'L' .BLKW 1		; CORE SIZE OF TASK
	.ENDC	; DF AA$MEM
B.TNAM:'L'			; EXITING TASK'S NAME IN RADIX-50
B.STRT:'L' .BLKW 2		; SAVE START TIME HERE
B.CPU:'L' .BLKW	2		; CPU TIME
	.IF DF	AA$QIO & AA$TCQ
B.QIO:'L' .BLKW	2		; QIO REQUEST COUNT
	.ENDC	; DF AA$QIO & AA$TCQ
	.IF DF	AA$FPR
	.IF DF	A$$PRI
B.NREQ:'L' .BLKW 2		; NUMBER OF REQUESTS
B.SPRI:'L' .BLKW 2		; PRIORITY SUM
	.IFF
B.SPRI:'L' .BLKW 1		; TASK PRIORITY
	.ENDC	; DF A$$PRI
	.ENDC	; DF AA$FPR
	.IF DF	AA$CPU
B.EXST:'L' .BLKW 1		; TASK'S EXIT STATUS
	.ENDC	; DF AA$CPU
B.LGTH='B'.			; CONTROL BLOCK LENGTH

;
; NODE PARAMETERS COMMAND PACKET OFFSETS
;

.=B.MASK+2
B.NADD:'L' .BLKW 1		; NODE ADDRESS
B.NSIZ:'L' .BLKW 1		; NODE SIZE
B.NAHD:'L' .BLKW 1		; ACCOUNTING LISTHEAD ADDRESS
B.NTCB:'L' .BLKW 1		; TCB OF SENDER TASK (AC.GAC REQUEST)
B.NLEN='B'.			; PACKET SIZE FOR SEND NODE PARAMETERS

;
; CPU COMMAND OFFSETS (NOT CONDITIONALISED BECAUSE ALSO
; USED BY CHG COMMAND)
;

.=B.UCB+2
B.FLAG:'L' .BLKW 1		; CPU REPORTING FLAG
B.LCPU='B'.			; LENGTH OF CPU COMMAND PACKET

;
; UPD COMMAND OFFSETS
;

	.IF DF	AA$USE ! AA$BAT
B.LUPD='B'B.MASK+2

;
; USE COMMAND OFFSETS
;

.=B.MASK+2
B.STCB:'L'			; SENDER TASK NAME
B.ELAP:'L' .BLKW 2		; TOTAL ELAPSED TIME
B.EXEC:'L' .BLKW 2		; TOTAL EXECUTIVE TIME
B.NULL:'L' .BLKW 2		; TOTAL NULL TIME
	.IF DF	AA$LDR
B.LOAD:'L' .BLKW 2		; TOTAL LOADER REQUESTS
	.ENDC	; DF AA$LDR
	.IF DF	AA$QIO
B.TQIO:'L' .BLKW 2		; TOTAL QIOS
	.ENDC	; DF AA$QIO
	.IF DF	AA$CSW
B.CSWT:'L' .BLKW 2		; TOTAL CONTEXT SWITCHES
	.ENDC	; DF AA$CSW
	.IF DF	AA$BAT
B.BATU:'L' .BLKW 2		; TOTAL BATCH CPU TIME
	.ENDC	; DF AA$BAT
B.USER:'L' .BLKW 2		; TOTAL USER TIME
B.STAT:'L' .BLKW 2		; STATISTICS UPDATE NUMBER
B.LUSE='B'.

	.ENDC	; DF AA$USE ! AA$BAT

;
; HELLO COMMAND OFFSETS
;

.=B.UIC+2
B.HTCB:'L' .BLKW 1		; HELLO'S TCB ADDRESS
B.HACN:'L' .BLKW 1		; ACCOUNT NUMBER
B.HCHW:'L' .BLKW 1		; CHAIN WORD
B.HSCN:'L' .BLKW 1		; NON-STANDARD CONNECT RATE WORD
B.HSCP:'L' .BLKW 1		; NON-STANDARD CPU RATE WORD
B.LHEL='B'.

;
; BYE COMMAND OFFSETS
;

.=B.UIC+2
B.BTCB:'L' .BLKW 1		; BYE TCB ADDRESS
B.BACN:'L' .BLKW 1		; ACCOUNT NUMBER
B.BCHW:'L' .BLKW 1		; CHAIN WORD
B.BSCN:'L' .BLKW 1		; NON-STANDARD CONNECT RATE WORD
B.BSCP:'L' .BLKW 1		; NON-STANDARD CPU RATE WORD
B.CONN:'L' .BLKW 2		; CONNECT TIME (TICKS)
B.SCPU:'L' .BLKW 2		; TOTAL SESSION CPU TIME
B.ECPU:'L' .BLKW 2		; PRIO. ADJ. CPU TIME
	.IF DF	AA$QIO & AA$TCQ
B.SQIO:'L' .BLKW 2		; TOTAL SESSION I/O REQUESTS
	.ENDC	; DF AA$QIO & AA$TCQ
B.ACFL:'L' .BLKW 1		; ACCOUNTING ENABLE FLAG
B.BPAG:'L' .BLKW 1		; TOTAL PRINTED PAGES
	.IF DF	AA$MEM
B.BCOR:'L' .BLKW 2		; MEMORY USAGE FIELD
	.ENDC	; DF AA$MEM
B.LBYE='B'.

;
; TSF COMMAND OFFSETS
;

	.IF DF	AA$TSF ! AA$BAT
.=B.UCB+2
B.TTCB:'L' .BLKW 1		; TSF TCB ADDRESS
B.TTYP:'L' .BLKW 1		; TSF COMMAND TYPE
B.CSF:'L'  .BLKW 2		; CPU TIME SO FAR
	.IF DF	AA$QIO & AA$TCQ
B.ISF:'L'  .BLKW 2		; I/O REQUESTS SO FAR
	.ENDC	; DF AA$QIO & AA$TCQ
B.TCON:'L' .BLKW 2		; CONNECT TIME
B.PSF:'L'  .BLKW 1		; PAGES PRINTED SO FAR
B.LTSF='B'.
	.ENDC	; DF AA$TSF ! AA$BAT

;
; PAGE COUNT COMMAND (REQUIRES LPP0 MODIFICATIONS)
;

.=B.MASK+2
B.PAGE:'L' .BLKW 1		; PAGE COUNT
	   .BLKW 1		; (UIC FROM LPP0, OFFSET B.UIC)
B.SPNM:'L' .BLKW 2		; NAME OF DESPOOLER TASK (RAD-50)
B.LPAG='B'.

	.PSECT
	.MACRO	ACCDF$,X,Y
	.ENDM
	.ENDM