'CORAL' P2 MOV MODULE
 
 
   'LIBRARY' ('PROCEDURE' PLOT ('LOCATION''FLOATING','LOCATION''FLOATING','LOCATION''INTEGER');
   'PROCEDURE' WHERE ('LOCATION''FLOATING','LOCATION''FLOATING','LOCATION''FLOATING');
   'PROCEDURE' RTH ('LOCATION''FLOATING','LOCATION''FLOATING'));
   'COMMON' ('PROCEDURE' MOV ('VALUE''FLOATING','VALUE''FLOATING'));
   'COMMON' DATPLT ('FLOATING' XSPAC,YSPAC,XOR,YOR,XI,YI,FACR);
   'SEGMENT' RJSSUB
   'BEGIN'
 
 
       'PROCEDURE' MOV ('VALUE''FLOATING' X,Y);
       'BEGIN'
           'INTEGER' ACTION:=3;  (LIFT PEN CODE)
           'FLOATING' XX,YY,FF;
 
           'COMMENT' GET X AND Y POSITION AND SCALING FACTOR
                     NOTE ONLY THE SCALING FACTOR IS REQUIRED;
           WHERE(XX,YY,FF);
           XX:=X;        (HOLD X AND Y COORDINATES)
           YY:=Y;
           RTH(XX,YY);  (CHECK AND CONVERT R THETA IF REQD)
 
           'COMMENT' ENSURE PEN DOES NOT LEAVE PAPER LIMITS;
           'IF' XX < XOR/FF
           'THEN' XX:=XOR;
           'IF' XX > XSPAC/FF
           'THEN' XX:=XSPAC;
           'IF' YY < YOR/FF
           'THEN' YY:=YOR;
           'IF' YY > YSPAC/FF 
           'THEN' YY:=YSPAC;
           PLOT(XX,YY,ACTION);
       'END'OF PROCEDURE MOV;
   'END';
   'FINISH'