;
;
;	TABLE ACCESS MACROS.
;
;	AUTHOR	:-	J.S.Clifton.
;	DATE	:-	24th May 1982
;
;
.MACRO	TLOOKUP	TKEY,TBLE,RSAVE
	TSEEKF	= 0	; IF SET DENOTES 'CALL T$SEEK' GENERATED.
	.IF B TKEY
	    .ERROR	; -KEY NOT DEFINED.
	    .MEXIT
	.ENDC
	.IF B TBLE
	    .ERROR	; -TABLE NOT DEFINED.
	    .MEXIT
	.ENDC
	.IIF DIF RGSTR'RSAVE,RGSTRS	 .EMIT	<CALL	R$SAVE>
	.IF DIF TBLE,-
	    .IF DIF TBLE,R0
		.NTYPE	TLAB,TBLE
		.IF EQ TLAB&70
		    .EMIT	<MOV	TBLE,R0>
		.IFF
		    .EMIT	<MOV	#TBLE,R0>
		.ENDC
	    .ENDC
	    .EMIT	<CALL	T$INIT>
	.ENDC
	.IF DIF TKEY,-
	 .IF	DIF	TKEY,FIRST
	  .IF	DIF	TKEY,PREVIOUS
	   .IF	DIF	TKEY,PRESENT
	    .IF	DIF	TKEY,NEXT
	     .IF DIF	TKEY,LAST
	     	.IIF DIF TKEY,R1	.EMIT	<MOV	TKEY,R1>
		.EMIT	<CALL	T$SEEK>
		TSEEKF	= 1	;SET THE SEEK FLAG.
	     .IFF
		.EMIT	<CALL	T$LAST>
	     .ENDC
	    .IFF
		.EMIT	<CALL	T$NEXT>
	    .ENDC
	   .IFF
		.EMIT	<CALL	T$PRESENT>
	   .ENDC
	  .IFF
		.EMIT	<CALL	T$PREVIOUS>
	  .ENDC
	 .IFF
		.EMIT	<CALL	T$FIRST>
	 .ENDC
	.IFF
	    .IIF EQ LST$$ .LIST
		MOV	CD.KEY,R1
		CALL	T$SEEK
	    .IIF EQ LST$$ .NLIST
	    TSEEKF	= 1
	.ENDC
	.IIF DIF RGSTR'RSAVE,RGSTRS	.EMIT	<CALL R$UNSAVE>
.ENDM	TLOOKUP
;
;
.MACRO	TREAD	DST,TKEY,TBLE
	TLOOKUP	TKEY,TBLE
	ON.NOERROR
	    MOVSTRING	-,DST
	END
.ENDM	TREAD
;
;
.MACRO	TWRITE	SRC,TKEY,TBLE
	.IF B SRC
	    .ERROR	; -SOURCE NOT DEFINED.
	    .MEXIT
	.ENDC
	.IIF IDN SRC,-	.EMIT	<MOV	CD.SRC,-(SP)>
	TLOOKUP	TKEY,TBLE
	.IF IDN SRC,-
		ON.NOERROR
			.EMIT	<MOV	CD.SRC,CD.DST>
			.EMIT	<MOV	(SP)+,CD.SRC>
			MOVSTRING	-,-
		END
	.IFF
		ON.NOERROR
			.EMIT	<MOV	CD.SRC,CD.DST>
			MOVSTRING	SRC,-
		END
	.ENDC
.ENDM	TWRITE
;
;
.MACRO	TKILL	TKEY,TBLE
	.IF	IDN	TKEY,ALL
	    TCLOSE	TBLE
	.IFF
	    .EMIT	<CALL	R$SAVE>
	    TLOOKUP	TKEY,TBLE,S
	    ON.NOERROR
		.EMIT	<CALL	T$2DEL>
	    END
	    .EMIT	<CALL	R$UNSAVE>
	.ENDC
.ENDM	TKILL
;
;
.MACRO	TCREATE	LNGTH,TKEY,TBLE,RSAVE
	.IF B LNGTH
	    .ERROR	; -LENGTH NOT DEFINED.
	    .MEXIT
	.IFF
	    .IIF DIF LNGTH,-	.EMIT	<MOV	LNGTH,CD.CNT>
	.ENDC
	.IF B TKEY
	    .ERROR	; -KEY NOT DEFINED.
	    .MEXIT
	.ENDC
	.IIF DIF RGSTR'RSAVE,RGSTRS	.EMIT	<CALL	R$SAVE>
	TLOOKUP	TKEY,TBLE,S
	ON.ERROR
		.IF	EQ	TSEEKF
		    .ERROR	;INCORRECT MACRO KEY USAGE.
		    .MEXIT
		.ENDC
		.EMIT	<MOV	CD.CNT,R0>
		.EMIT	<CALL	T$CREATE>
		ON.NOERROR
			.EMIT	<MOV	R0,CD.SRC>
		END
	ELSE
		SETERROR
	END
	.IIF DIF RGSTR'RSAVE,RGSTRS	.EMIT	<CALL	R$UNSAVE>
.ENDM	TCREATE
;
;
.MACRO	TPROTECT	TKEY,TBLE
	.IF IDN TKEY,ALL
	    T..ALL	PROTECT,TBLE
	.IFF
	    .EMIT	<CALL	R$SAVE>
	    TLOOKUP	TKEY,TBLE,S
	    ON.NOERROR
		.EMIT	<BIS	#100000,-2(R0)>
	    END
	    .EMIT	<CALL	R$UNSAVE>
	.ENDC
.ENDM	TPROTECT
;
;
.MACRO	TUNPROTECT	TKEY,TBLE
	.IF IDN TKEY,ALL
	    T..ALL	UNPROTECT,TBLE
	.IFF
	    .EMIT	<CALL	R$SAVE>
	    TLOOKUP	TKEY,TBLE,S
	    ON.NOERROR
		.EMIT	<BIC	#100000,-2(R0)>
	    END
	    .EMIT	<CALL	R$UNSAVE>
	.ENDC
.ENDM	TUNPROTECT
;
;
.MACRO	TCLOSE	TBLE
	TLOOKUP	FIRST,TBLE
	.EMIT	<CALL	T$CLOSE>
.ENDM	TCLOSE
;
;
.MACRO	TINSERT	SRC,LGTH,TKEY,TBLE
	.EMIT	<CALL	R$SAVE>
	.IF B SRC
		.ERROR	; -SOURCE NOT DEFINED.
		.MEXIT
	.ENDC
	.IF B LGTH
		.ERROR	; -LENGTH NOT DEFINED.
		.MEXIT
	.ENDC
	TLOOKUP	TKEY,TBLE,S
	ON.NOERROR
		.IF	IDN	TKEY,LAST
			.IIF	EQ	LST$$	.LIST
			INC	CD.KEY
			MOV	CD.KEY,R1
			.IIF	EQ	LST$$	.NLIST
		.IFF
			.IIF	EQ	LST$$	.LIST
			CALL	T$RSEQ
			MOV	CD.KEY,R1
			.IIF	EQ	LST$$	.NLIST
		.ENDC
	ELSE
		.IF	IDN	TKEY,NEXT
			.IIF	EQ	LST$$	.LIST
			CALL	T$LAST
			INC	CD.KEY
			MOV	CD.KEY,R1
			.IIF	EQ	LST$$	.NLIST
		.IFF
			.IIF	EQ	TSEEKF	.EMIT	<CLR	R1>
		.ENDC
	END
	.IIF DIF LGTH,-	.EMIT	<MOV	LGTH,CD.CNT>
	.IIF	EQ	LST$$	.LIST
		MOV	CD.CNT,R0
		CALL	T$CREATE
	.IIF	EQ	LST$$	.NLIST
	ON.NOERROR
		.IIF	EQ	LST$$	.LIST
		CALL	R$CLEAR
		MOV	R0,CD.DST
		.IIF	EQ	LST$$	.NLIST
		.IF DIF SRC,NULSTG
		    .IF DIF SRC,-
			.NTYPE	TSRC,SRC
			.IF	EQ	TSRC&70
				.EMIT	<MOV	SRC,CD.SRC>
			.IFF
				.EMIT	<MOV	#SRC,CD.SRC>
			.ENDC
		    .ENDC
		    .EMIT	<CALL	L$ADDTO>
		.ENDC
	END
	.EMIT	<CLR	R0		;COMPLETE RESEQUENCE.>
	ON.NOERROR
		.EMIT	<CALL	T$RSEQ>
	ELSE
		.IIF	EQ	LST$$	.LIST
		CALL	T$RSEQ
		SEC
		.IIF	EQ	LST$$	.NLIST
	END
		.EMIT	<CALL	R$UNSAVE>
.ENDM	TINSERT
;
;
.MACRO	TREMOVE	TKEY,TBLE
	.EMIT	<CALL	R$SAVE>
	TLOOKUP	TKEY,TBLE,S
	ON.NOERROR
		.EMIT	<CALL	T$2DEL>
	END
	.IIF	EQ	LST$$	.LIST
	CLR	R0		;Complete resequence.
	CALL	T$RSEQ
	CALL	R$UNSAVE
	.IIF	EQ	LST$$	.NLIST
.ENDM	TREMOVE
;
;
.MACRO	T..ALL	ACTION,TBLE,?LAB1,?LAB2
	.EMIT	<CALL	R$SAVE>
	TLOOKUP	-,TBLE,S
	ON.NOERROR
	    .IIF	EQ	LST$$	.LIST
	    MOV TADDRESS,R0
	    MOV	(R0)+,R2
	    ADD	R0,R2
LAB1:	    CMP	R0,R2
	    BGE	LAB2
	    TST	(R0)+
	    .IIF	EQ	LST$$	.NLIST
	    .IIF	IDN	ACTION,PROTECT	.EMIT	<BIS	#100000,-2(R0)>
	    .IIF	IDN	ACTION,UNPROTECT .EMIT	<BIC	#100000,-2(R0)>
	    .IIF	EQ	LST$$	.LIST
	    TST	(R0)+	
	    BR	LAB1
LAB2:
	    .IIF	EQ	LST$$	.NLIST
	    .IIF IDN ACTION,DELETE .EMIT <CALL T$SQUEEZE>
	END
	.EMIT	<CALL	R$UNSAVE>
.ENDM	T..ALL
;
;
;
	.END