;+
;********************************************************************************
;										*
;	***********								*
;	*         *								*
;	*   ***   *	SIMMONDS PRECISION PRODUCTS, INC.			*
;	*  *   *  *	INSTRUMENT SYSTEMS DIVISION				*
;	*  *      *	PANTON ROAD						*
;	*   ***   *	VERGENNES, VERMONT  05491 U.S.A.			*
;	*  *   *  *	(802) 877-2911						*
;	*  *   *  *								*
;	*  ****   *	PROGRAMMER:	JAMES E DUNN				*
;	*  *      *								*
;	*  *      *								*
;	**  *******								*
;										*
;********************************************************************************
;										*
; VT1XX.MAC									*
;		VT1XX INITIALIZATION SUBROUTINE					*
;										*
;	CALLING:	CALL VT100(LUN,ISTATUS)					*
;										*
;	WHERE:		LUN ------ INTEGER*2, LOGICAL UNIT NUMBER		*
;			ISTATUS -- INTEGER*2, TERMINAL STATUS			*
;					0 = VT52				*
;					1 = VT100				*
;										*
;********************************************************************************
;										*
;	REV	DATE		PROGRAMMER	DESCRIPTION			*
;	---	------		----------	------------------------	*
;	1.0	07-MAY-82	J.E.DUNN	DECUS RELEASE VERSION		*
;										*
;********************************************************************************
;-
	.TITLE	VT1XX	SET VT100
	.IDENT	/V01.00/
	.MCALL	QIOW$S
	.ENABL	LC

EFLG	= 5
 
VT1XX::
	CLR	@4(R5)			;ISTATUS = 0
	QIOW$S	#IO.RPR,@2(R5),#EFLG,,,,<#ANSR,#ANSRX,,#QERY,#QERYX,#0>
	MOV	#ANSR,R1		;*
	MOV	#ESC1,R2		;*
	CMPB	(R1)+,(R2)+		;* ESC
	BNE	1$			;*
	CMPB	(R1)+,(R2)+		;* [
	BNE	1$			;*
	CMPB	(R1)+,(R2)+		;* ?
	BNE	1$			;*
	CMPB	(R1)+,(R2)+		;* 1
	BNE	1$			;*
	CMPB	(R1)+,(R2)+		;* ;
	BNE	1$			;*
	CMPB	(R1)+,(R2)+		;* (SKIP)
	CMPB	(R1)+,(R2)+		;* c	IS IT A VT100
	BEQ	2$			;*	YES, BRANCH
1$:	MOV	#ANSR,R1		;**
	MOV	#ESC2,R2		;**
	CMPB	(R1)+,(R2)+		;** ESC
	BNE	EXIT			;**
	CMPB	(R1)+,(R2)+		;** /
	BNE	EXIT			;**
	CMPB	(R1)+,(R2)+		;** Z	IS IT A VT100
	BNE	EXIT			;**	NO, BRANCH
2$:	INC	@4(R5)			;ISTATUS = 1
	QIOW$S	#SF.SMC,@2(R5),#EFLG,,,,<#TBLE,#TBLEX> ;MAKE IT A VT100
EXIT:	RETURN

ESC	= 033
 
QERY:	.BYTE	ESC,'Z			;TERMINAL IDENTIFY
QERYX	= .-QERY
 
ANSR:	.BLKB	32.			;ANSWER BUFFER
ANSRX	= .-ANSR

TBLE:	.BYTE	TC.TTP,15		;SET /TERM=TI:VT100
TBLEX	= .-ANSR
 
ESC1:	.BYTE	ESC
	.ASCII	\[?1;0c\
 
ESC2:	.BYTE	ESC
	.ASCII	\/Z\
 
	.END