;+
;********************************************************************************
;										*
;	***********								*
;	*         *								*
;	*   ***   *	SIMMONDS PRECISION PRODUCTS, INC.			*
;	*  *   *  *	INSTRUMENT SYSTEMS DIVISION				*
;	*  *      *	PANTON ROAD						*
;	*   ***   *	VERGENNES, VERMONT  05491 U.S.A.			*
;	*  *   *  *	(802) 877-2911						*
;	*  *   *  *								*
;	*  ****   *	PROGRAMMER:	JAMES E DUNN				*
;	*  *      *								*
;	*  *      *								*
;	**  *******								*
;										*
;********************************************************************************
;										*
; TRMTYP.MAC									*
;										*
; 	TRMTYP IS A FORTRAN CALLABLE SUBROUTINE TO DETERMINE THE		*
; 	TYPE OF TERMINAL BEING USED ON A SPECIFIED LUN.  THE LUN		*
;	IS ATTACHED WITH ESCAPE SEQUENCE PROCESSING AND IS SET TO		*
;	THE NOWRAP MODE.							*
; 										*
; 	CALLING:	CALL TRMTYP(LUN,TYPE)					*
;										*
; 	WHERE:	LUN --- INTEGER*2 VALUE SPECIFYING THE LOGICAL UNIT NUMBER	*
;		TYPE -- INTEGER*2 TERMINAL TYPE # (SEE THE I/O DRIVER MANUAL	*
;			FOR THE TYPE #'S. LOOK IN THE FDX TERMINAL DRIVER.)	*
;										*
;********************************************************************************
;										*
;	REV	DATE		PROGRAMMER	DESCRIPTION			*
;	---	------		----------	------------------------	*
;	1.0	07-MAY-82	J.E.DUNN	DECUS RELEASE VERSION		*
;										*
;********************************************************************************
;-
	.TITLE	TRMTYP	TERMINAL TYPE
	.IDENT	/V01.00/
	.MCALL	QIOW$S
 
LUN	= 2
TYPE	= 4
 
VT100	= 15
 
	.PSECT	CURSOR
 
TRMTYP::
	MOV	#1,R1					;EVENT FLAG #
	MOV	@LUN(R5),R2				;LUN #
	QIOW$S	#IO.ATT!TF.ESQ,R2,R1			;ATTACH W/ESC SEQ PROCESSING
	QIOW$S	#SF.SMC,R2,R1,,,,<#WRAP,#WRAPX>		;SET /NOWRAP
	QIOW$S	#SF.GMC,R2,R1,,,,<#TBLE,#TBLEX>		;*
	MOVB	TBLE+1,R0				;*GET TERMINAL TYPE #
	CMP	#VT100,R0				;IS IT A VT100
	BNE	EXIT					;NO, BRANCH
	QIOW$S	#IO.WLB,R2,R1,,,,<#ANSI,#ANSIX,#0> 	;FORCE INTO ANSI MODE
EXIT:	MOV	R0,@TYPE(R5)				;RETURN TYPE NUMBER
	RETURN
 
TBLE:	.BYTE	TC.TTP,0
TBLEX	= .-TBLE
ANSI:	.BYTE	033,'<
ANSIX	= .-ANSI
WRAP:	.BYTE	TC.ACR,0
WRAPX	= .-WRAP
 
	.END