.TITLE	DBKCF
	.IDENT	/VS01.0/
;
;  CALL DBKCF(LUN, MODE, IER)
;
;  INPUTS
;	LUN - LUN TO CLOSE
;	MODE - "D" TO DELETE THE FILE, OTHERWISE JUST CLOSE
;
;  OUTPUTS
;	IER - 0 IF SUCCESSFUL, OTHERWISE FCS ERROR CODE
;
;  DELETE OPTION AND ERROR OUTPUT ADDED ON MARCH 11,1982 BY:
;	BILL WOOD
;	INSTITUTE FOR CANCER RESEARCH
;	7701 BURHOLME AVE.
;	PHILA., PA. 19111
;
;
FDBOF	=	14
;
	.GLOBL	.DLFNB
	.GLOBL	S.FDB
	.MCALL	CLOSE$
;
DBKCFN:	.RAD50	/DBKCF /
;
;
DBKCF::
	CALL	$SAVAL
	MOV	#DBKCFN,R0
	MOV	(R0)+,R4
	MOV	(R0)+,-(SP)
	JSR	R4,NAM$			; TRACE-BACK CHAIN
;
	MOV	@2(R5),R2
	MOV	@#$OTSV,R3
	CALL	$FCHNL			; GET FFDB ADDR
	ADD	#FDBOF,R0		; POINT TO FDB
;
	CMPB	@4(R5),#'D		; DELETE THE FILE?
	BEQ	10$			; EQ - YES
	CLOSE$	R0			; CLOSE THE FILE
	BR	20$
10$:
	CALL	.DLFNB			; CLOSE AND DELETE THE FILE
20$:
	MOVB	F.ERR(R0),R1		; GET ERROR STATUS
	BMI	25$			; ERROR
	CLR	R1			; STATUS 0 = SUCCESS
25$:
	MOV	R1,@6(R5)		; RETURN STATUS
;
;	ZERO FDB
;
	SUB	#FDBOF,R0		; START OF FDB
	MOV	#<FDBOF+S.FDB>/2,R1	; # WORDS TO CLEAR
;
30$:
	CLR	(R0)+
	SOB	R1,30$
;
	RETURN
	.END