.TITLE	HLINIT
	.IDENT	/V01.1R/
	.PSECT	INIT,OVR,I,LCL
;
; COPYRIGHT (C) 1978
; DIGITAL EQUIPMENT CORPORATION, MAYNARD, MASS.
;
;         
; VERSION:	1
; AUTHOR:	ALAN GROUPE
; DATE:		8-DEC-78

; THIS SEGMENT FILLS IN A HELP PAGE THAT DEFINES WHAT KEYS ARE ACTIVE
; UNIVERSALLY FROM RMDEMO
; Add RM, LL, AT, TH from network contribution
; Add DA myself


	.WORD	INIT		; ENTRY ADDRESS (FIRST WORD)


	.MACRO	FLAG,DD
	BISB	#200,DD
	.ENDM


	.MACRO	FILL,FROM,END,TO,?A,?B,?C
	MOV	TO,R4		; ADDRESS TO OUTPUT TO
	BEQ	C		; SKIP IT
	MOV	#FROM,R1
A:	MOV	R4,R2
B:	MOVB	(R1)+,(R2)+
	TSTB	(R1)
	BNE	B
	INC	R1		; PAST ZERO BYTE
	ADD	$WIDTH,R4
	CMP	R1,#END
	BLO	A
C:
	.ENDM
	.PAGE
	.SBTTL	HELP PAGE TEXT STRINGS


; TOP LINE

TOP:	.ASCIZ	/THE FOLLOWING KEYS ARE ACTIVE UNIVERSALLY:/



; STINGS FOR COLUMN 1

COL1:	.ASCIZ	/H -(HL)- THIS PAGE/
	.ASCIZ	/M -(MD)- DYNAMIC MEMORY DISPLAY/
	.ASCIZ	/A -(AT)- ACTIVE TASK LIST DISPLAY/
	.ASCIZ	/T -(TH)- TASK HEADER DISPLAY/
	.ASCIZ	/R -(RM)- REMOTE NODE DISPLAY/
	.ASCIZ	/L -(LL)- LOGICAL LINK DISPLAY/
	.ASCIZ	/D -(DA)- DEVICE ACTIVITY DISPLAY/


; STRINGS FOR COLUMN 2

COL2:


; STRINGS FOR COLUMN 3

COL3:


; STRINGS FOR BOTTOM LINES

BOTTOM:	.ASCIZ	/<ESC> LETS YOU ENTER A COMMAND IF ANY COMMANDS ARE AVAILABLE FOR THAT PAGE/
	.ASCIZ	/<SPACE> REPLOTS THE CURRENT PAGE/
	.ASCIZ	/<CTRL-C> OR <CTRL-Z> EXIT/

END:				; END Of TEXT STRINGS
	.EVEN
	.PAGE
	.SBTTL	PAGE FILL


INIT:
	CALL	$CLEAR
	FILL	TOP,COL1,$HLTOP
	FILL	COL1,COL2,$HLCL1
	FILL	BOTTOM,END,$HLBOT


; NOW FLAG ALL AS NEW CHARS

FLAG:	MOV	#$SCRN,R1	; BEGINNING OF SCREEN BUFFER
	MOV	#$ESCRN,R2	; END OF SCREEN BUFFER
FLGLP:	CMP	R1,R2		; AT END
	BHIS	RETURN
	CMPB	#40,(R1)+	; SCREEN WAS ALL BLANKS
	BEQ	FLGLP
	FLAG	-1(R1)		; FLAG AS CHANGED
	BR	FLGLP

RETURN:	RETURN
	.END