$	VF_SW = 'F$VERIFY(0)
$	NO := "NO"
$	IF "''P1'" .EQS. "VERIFY" THEN  NO := ""
$	SET 'NO'VERIFY
$!
$!	RUNOFF COMMAND EXECUTION FILE
$!
$	INQUIRE FILE "File name"
$	INQUIRE LA36 "Hard copy terminal [y/n]"
$	INQUIRE CSN  "Number for Greek Processing (/CS:n)"
$	INQUIRE ADDSW "Enter additional switches (/WA and/or /PA:low:high)"
$!
$	IF CSN .EQS. "" THEN CSN := "-1"
$!
$!	Check for existence of PROLOGUE.RNO
$!
$	OPEN/READ/ERROR=100 PRO PROLOGUE.RNO
$	CLOSE PRO
$	OPEN/WRITE ONE TEMPORARY.TMP
$	WRITE ONE ".IN PROLOGUE.RNO"
$	WRITE ONE ".IN ''FILE'.RNO"
$	CLOSE ONE
$	FILE := "TEMPORARY.TMP"
$	PURGE TEMPORARY.TMP
$ 100:
$	IF .NOT. LA36 THEN GOTO 300
$	TYPE SYS$INPUT
!
!	Allign paper to top of form
!
$	INQUIRE OK "Paper Alligned OK [y/n]
"
$	IF .NOT. OK THEN GOTO 100
$	IF "''CSN'" .NES. "1" THEN GOTO 300
$!
$	COUNT = 1
$ 150:
$	WRITE SYS$OUTPUT "! Check Line # ''COUNT' -----"
$	WRITE SYS$OUTPUT "!"
$	COUNT = COUNT + 1
$	IF COUNT .LE. 8 THEN GOTO 150
$ 300:
$!
$!	RUNOFF the first or only pass
$!
$	DEAS SYS$INPUT
$	IF .NOT. LA36 THEN RNO TI:'ADDSW'='FILE'
$	IF LA36      THEN RNO TI:/UL:L'ADDSW'='FILE'/DI/CS:'CSN'
$!
$!	Exit if pass two not requested
$!
$	IF "''CSN'" .NES. "1" THEN GOTO 1000
$	INQUIRE	GREEK "Go back for pass 2 [y/n]"
$	IF .NOT. GREEK THEN GOTO 1000
$ 400:
$	@_NL:
$	TYPE SYS$INPUT
!
!	Re-position paper to "top of form" at start of run
!
$	INQUIRE OK "Paper re-wound to top of form [Y/N]
"
$	IF .NOT. OK THEN GOTO 400
$!
$	COUNT = 1
$ 450:
$	WRITE SYS$OUTPUT "! Check line # ''COUNT' ---------- Pass 2"
$	INQUIRE OK  "Lined up ok [Y/N]"
$	IF OK THEN GOTO 500
$	COUNT = COUNT + 1
$	IF COUNT .LE. 8 THEN GOTO 450
$	GOTO 1000
$!
$ 500:
$	WRITE SYS$OUTPUT "!"
$	WRITE SYS$OUTPUT "!				Insert Greek wheel"
$	WRITE SYS$OUTPUT "!"
$	INQUIRE OK "				Greek wheel in place [Y/N]"
$	IF .NOT. OK THEN GOTO 500
$!
$	DEAS SYS$INPUT
$	RNO TI:'ADDSW'='FILE'/DI/CS:2
$!
$ 1000: