.PAGE
	.SBTTL	RDIHLP	-  USER HELP FOR AUTOMATIC REDIRECT INPUT
;
QUERY6:	.ASCII	<15><12>/TLK:Enter destination file name:/
LENQ6=.-QUERY6
	.EVEN
RDIHLP::
	QIOMAC	R0,#WALTIO,#QUERY6,#LENQ6,Y	; WRITE QUERY6 TO TERMINAL
	INCB	BCAFLG			; SET FLAG FOR ENTERING COMMAND
	INCB	BLDFLG			; INDICATE ONE OF THE BUILD FLAGS SET
	MOV	#LENCMA,LENCMD		; SET INITIAL LENGTH OF COMMAND
	CLR	NAMECT			; CLEAR FILE NAME LENGTH
	MOV	#FNAMEA,FNPTR		; POINT TO START OF FILE NAME BUFFER
	MOV	#CMDA,CMDPTR		; POINT TO BEGINNING OF COMMAND STRING
	INCB	HLPFLG			; INDICATE THAT TALK IS HELPING
	RTS	PC
	.PAGE
	.SBTTL	RDOHLP	-  USER HELP FOR AUTOMATIC REDIRECT OUTPUT
;
QUERY5:	.ASCII	<15><12>/TLK:Enter source file name:/
LENQ5=.-QUERY5
	.EVEN
RDOHLP::
	QIOMAC	R0,#WALTIO,#QUERY5,#LENQ5,Y	; WRITE QUERY5 TO TERMINAL
	INCB	BCBFLG			; SET FLAG FOR ENTERING COMMAND
	INCB	BLDFLG			; INDICATE ONE OF THE BUILD FLAGS SET
	MOV	#LENCMB,LENCMD		; SET INITIAL LENGTH OF COMMAND
	CLR	NAMECT			; CLEAR FILE NAME LENGTH
	MOV	#FNAMEB,FNPTR		; POINT TO START OF FILE NAME BUFFER
	MOV	#CMDB,CMDPTR		; POINT TO BEGINNING OF COMMAND STRING
	INCB	HLPFLG			; INDICATE THAT TALK IS HELPING
	RTS	PC
	.SBTTL	PAUSE	-  DETACH FROM TALK
;
PAUSE::
	JSR	PC,DETDEV		; DETACH TERMINAL
	QIOMAC	R0,#WALTIO,#PASMSG,#LENPM,Y ; WRITE INTERRUPT MESSAGE
	STOP$S				; STOP THE PROGRAM
	JSR	PC,ATTDEV		; REATTACH TERMINAL
	RTS	PC			; RETURN
	.PAGE
	.SBTTL	ASKEOR	-  INITIATE NEW EOR PROCESSING
;
QUERY2:	.ASCII	<15><12>/TLK:Enter new EOR character: /
LENQ2=.-QUERY2
	.EVEN
ASKEOR::
	QIOMAC	R0, #WALTIO, #QUERY2, #LENQ2, Y	; WRITE QUERY3 TO TERMINAL
	INCB	CGEFLG			; INTERCEPT NEXT TERMINAL CHARACTER FOR EOR
	RTS	PC
	.PAGE
	.SBTTL	ENTEOR	-  SET UP NEW EOR CHARACTER
;
ENTEOR::
	MOVB	CHAR, EKOBUF		; MOV CHARACTER TO WRITE BUFFER
	QIOMAC	R0, #WALTIO, #EKOBUF, #3, Y	; ECHO CHARACTER
	MOVB	CHAR, EOR		; SET EOR CHARACTER
	CLRB	CGEFLG			; CLEAR INTERCEPT NEXT CHARACTER FOR EOR FLAG
	RTS	PC
;
	.END