.TITLE	PLTSYM - ROUTINE TO PLOT VARIOUS SYMBOLS ON THE SCREEN

.IDENT	'PLTS00'

.PSECT	PLTSYM

;	KEN DEMERS
;	UTRC
;	NOVEMBER 1979

;	THIS ROUTINE PLOTS VARIOUS SYMBOLS ON THE TEKTRONIX
;	SCOPE. ANY ASCII CHARACTER(SYMBOL) IS VALID.

;	ON ENTRY:

;	R5 = A(FORTRAN ARG BLK)

;	CALLING FORMAT:

;	CALL PLTSYM(NUMSYM,XARRAY,YARRAY,SYMBOL)

;	WHERE:

;	NUMSYM	- NUMBER OF SYMBOLS TO DISPLAY
;	XARRAY	- VIRTUAL F.P. X COORDINATE TO PLACE SYMBOL
;	YARRAY	- VIRTUAL F.P. Y COORDINATE TO PLACE SYMBOL
;	SYMBOL	- SYMBOL TO BE DISPLAYED


;	INTERNAL GLOBALS

.GLOBL	PLTSYM

;	EXTERNAL GLOBALS

.GLOBL	S$CALE,A$RGB1,A$RGB2,MVCURI,H$TXT,B$UFPTR



PLTSYM:	TST	(R5)+		;BUMP PAST # ARG LOC IN ARG BLK
	MOV	@(R5)+,R0	;R0 = # SYMBOLS TO BE DISPLAYED
	MOV	(R5)+,R1	;R1= A(XARRAY)
	MOV	(R5)+,R2	;R2= A(YARRAY)
	MOV	(R5),B$UFPTR	;INIT PTR TO SYMBOL TO BE DISPLAYED
PLT10:	CALL	S$CALE		;S$CALE COORDINATES TO ABS INT COORDS
	MOV	#A$RGB1,R5	;SET UP MVCURI ARG BLK
	CALL	MVCURI		;POSITION CURSOR TO REQUESTED POSITION
	MOV	#A$RGB2,R5	;SET UP H$TXT ARG BLK
	CALL	H$TXT		;DISPLAY THE SYMBOL
	SOB	R0,PLT10	;DISPLAY NEXT SYMBOL
	RETURN
	.END