.TITLE	SRDSRT-SORT THE DIRECTRY
	.IDENT	/V2.0/		;3-JUN-76
;+
;
;**SRD--SORT DIRECTORY
;
;THIS MODULE SORTS AND COMPRESSES THE DIRECTORY
;
;
; THIS TASK WILL SORT A RSX11M DIRECTORY
;THEN CREATE A LISTING WITH MANY SELECTION OPTIONS
;
;THIS IS THE MAIN ROUTINE, AND IS PURE.
;
;
;-
;
;SYSTEM MACRO CALLS
;
	.MCALL	CALLR,WRITE$,QIOW$,DIR$,ALUN$
;
;LOCAL MACRO
;
	.MACRO	C$MP ARG
	CMP	ARG(R3),ARG(R4) ;SEE WHICH IS BIGGER
	BHI	EXCHNG		;IF HI EXCHANGE POINTERS
	BLO	CONTINUE	;I LO-CONINTUE
	.ENDM
;
SRDSRT::
	MOV	F.BKDS+2+UFDFDB,R1 ;POINT AT END OF BUFFER
	MOV	DIRBF$,R3	;POINT AT TOP OF DIRECTORY
	MOV	R3,R2		;COPY THAT FOR SORT
40$:	TST	(R3)		;SEE IF OCCUPIED
	BNE	60$		;BR IF YES
50$:	SUB	#D.SIZ,R1	; BACK UP BOTTOM 1 ENTRY			
	CMP	R1,R3		; HAVE WE MET COMPRESS POINTER		
	BEQ	SORT		; YES-GO SORT				 
	TST	(R1)		; IS THIS SLOT OCCUPIED			
	BEQ	50$		; BR IF NO-LOOK SOME MORE			
	MOV	R1,R4		;COPY ADDRESS OF BUSY SLOT
	MOV	#<D.SIZ/2>,R5	;SET DIRECTORY SIZE IN WORDS
55$:	MOV	(R4)+,(R3)+	; FILL IN HOLE WITH				
	SOB	R5,55$		;DO ENTIRE ENTRY
	CLR	(R1)		; SHOW THIS ENTRY FREE			
	BR	65$		; R1=NEW LOGICAL END OF DIRECTORY		
60$:	ADD	#D.SIZ,R3	; INCREMENT TO NEXT				
65$:	CMP	R3,R1		; IS THIS THE END				
	BLO	40$		; BR IF NO					
SORT:
	.ENABL	LSB
; AT THIS POINT, THE DIRECTORY IS DENSE, AND
;	R1=LOGICAL END OF DIRECTORY
;	R2=FIRST ENTRY
;
; NOW WE SORT THE ENTRIES
;
10$:	MOV	R2,R3		;COPY ADDRESS OF CURRENT TOP
	MOV	R3,R4		;AGAIN
20$:	ADD	#D.SIZ,R4	;POINT AT NEXT ITEM
	CMP	R4,R1		;WATCH FOR END
	BHIS	40$		;BR WHEN ALL DONE
	TST	SWMSK$		;ORDER BY NAME?
	BMI	30$		;BR IF YES
	C$MP	D.TYP		;CK FOR FILE TYPE
30$:	C$MP	D.FNAM		;NOW FIRST PART OF NAME
	C$MP	D.FNAM+2	;SECOND PART
	C$MP	D.FNAM+4	;AND THIRD
	C$MP	D.TYP		;DO TYPE INCASE WE'RE GOING BY NAME
;
; FALL THROUGH FOR NAME MATCH
; ... NOW CHECK FOR HIGHEST VERSION
;
	CMP	D.VER(R3),D.VER(R4)
	BHI	CONTINUE
EXCHNG: MOV	R4,R3
CONTINUE: BR	20$
;
; COME HERE AFTER A SCAN COMPLETE
;
40$:	CMP	R2,R3		;MAKE SURE IT CHANGED
	BNE	45$		;BR IF EXCHANGE REQUIRED
	ADD	#D.SIZ,R2
	BR	60$
45$:	MOV	#<D.SIZ/2>,R4	;SET LOOP COUNT
50$:	MOV	(R2),-(SP)	;PUSH 1
	MOV	(R3),(R2)+	;COPY NEW OVER OLD
	MOV	(SP)+,(R3)+	;NOW PUT
	SOB	R4,50$	  ;
60$:	CMP	R2,R1		;SEE IF DONE
	BLO	10$		;BR IF MORE TO DO
	.DSABL	LSB
;
; DIRECTORY IS SORTED, NOW WRITE BACK
;
	TSTB	SWMSK$		;WRITE-BACK REQUESTED?
	BPL	80$		;BR IF NO
;
;ACCESS A NON-EXISTENT FILE FOR READ TO CAUSE THE ACP TO FLUSH ITS CACHE
;
	MOV	#ACPFNB,R3		;INIT FILE NAME BLOCK
	MOV	#SAVDID,R4
	CLR	(R3)+			;CLEAR FILE ID
	CLR	(R3)+
	CLR	(R3)+
	ADD	#N.DID-N.FNAM,R3	;COPY DIRECTORY ID
	MOV	(R4)+,(R3)+
	MOV	(R4)+,(R3)+
	CLR	(R3)+
	MOV	(R4)+,(R3)+		;COPY DEVICE INFO
	MOV	(R4),(R3)
	DIR$	#ASSLUN			;ASSIGN THE LUN
	DIR$	#FLUSH			;FLUSH THE ACP CACHE
;
;NOW IT IS SAVE TO DO WRITE BACK
;
	MOV	#1,F.EFBK+2(R0) ;RESET END-OF-FILE
	MOV	DIRBF$,F.BKDS+2(R0)  ;POINT I-O BUFFER TO TOP
	MOV	#1,F.VBN+2(R0)  ;AND ALSO VIRT. BLK NUMBER
70$:	WRITE$  R0		;WRITE OUT A BLOCK
	ADD	#512.,F.BKDS+2(R0)  ;ADJ. BUFFER TO NEXT BLK
	CMP	F.BKDS+2(R0),R1 ;SEE IF WE'RE PAST END OF DATA
	BLO	70$
80$:
	CALLR	.CLOSE		;CLOSE THE UFD
;
FLUSH:	QIOW$	IO.FNA,ACPLUN,DSKEFN,,IOSB$,,<,,,,,ACPFNB>
ASSLUN:	ALUN$	ACPLUN,SAVDVN,SAVUNM
	.END