.TITLE	START
	.IDENT	/M02.4/

;
; COPYRIGHT (C) 1976
; DIGITAL EQUIPMENT CORPORATION, MAYNARD, MASS.
;
; THIS SOFTWARE IS FURNISHED UNDER  A LICENSE FOR USE ONLY  ON  A
; SINGLE COMPUTER SYSTEM AND MAY BE  COPIED ONLY WITH  THE INCLU-
; SION OF  THE  ABOVE  COPYRIGHT NOTICE.  THIS SOFTWARE,  OR  ANY
; OTHER COPIES THEREOF, MAY NOT BE  PROVIDED  OR  OTHERWISE  MADE
; AVAILABLE TO ANY OTHER PERSON EXCEPT  FOR  USE  ON  SUCH SYSTEM
; AND TO  ONE WHO AGREES  TO  THESE LICENSE  TERMS.  TITLE TO AND
; OWNERSHIP OF THE SOFTWARE SHALL AT ALL TIMES REMAIN IN DEC.
;
; THE INFORMATION IN THIS SOFTWARE  IS  SUBJECT TO CHANGE WITHOUT
; NOTICE AND SHOULD NOT BE CONSTRUED  AS  A COMMITMENT BY DIGITAL
; EQUIPMENT CORPORATION.
;
; DEC ASSUMES NO RESPONSIBILITY FOR THE USE OR RELIABILITY OF ITS
; SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DEC.
;
; VERSION M02 -- REVISION 1 (RAW TEXT FACILITY)
;
; AUTHOR: L. WADE 1-JUN-72
;
; MODIFIED BY:
;
;	E. POLLACK U. OF W. 19-DEC-73
;
;	D. N. CUTLER 27-JUL-75
;
; SIG MODIFICATIONS								;**NEW**
;	SIG01	CLEAN UP WAIT FUNCTION						;**NEW**
;	SIG02	RSTS CHANGES							;**NEW**
;										;**NEW**
;										;M02.1
; INCLUDE RAW TEXT FACILITY / AUGUST 1981					;M02.1
;										;M02.1
;	DAN DILL, CHEMISTRY DEPARTMENT, BOSTON UNIVERSITY			;M02.1
;	BOSTON, MASSACHUSETTS 02215	(617) 353-4277				;M02.1
;
; ADD EXIT WITH STATUS
;
;	BOB DENNY			01-DEC-81
;	CREATIVE SYSTEM DESIGN CO.
;	PASADENA,CA			(213) 792-9474
;										;M02.1

; RUNOFF START UP INITIALIZATION
;
; MACRO LIBRARY CALLS
;

	.MCALL	CLOSE$,CSI$,CSI$1,CSI$2,EXIT$S,GCMLD$,EXST$S		;2.4
	.MCALL	GCML$,GPRT$S,GTSK$S,OPEN$R,OPEN$W,PRINT$
	CSI$			;DEFINE CSI CONTROL BLOCK OFFSETS
	GCMLD$

;
; LOCAL MACROS
;
; ERROR MESSAGE OUTPUT
;

	.MACRO	MSGPUT NAM
	CALL	$ERMSG
	.WORD	MG'NAM
	.ENDM

;
; LOCAL DATA
;
; CSI CONTROL BLOCK
;

CSIBLK:	.BLKB	C.SIZE		;

;
; TASK MEMORY LIMITS
;
LIMIT:	.LIMIT									;SIG02
;+										;**-17
; **-$START-START UP INITIALIZATION
;-

$START::MOV	SP,SPSAV	;SAVE INITIAL STACK POINTER
	OPEN$W	#TTBLK		;OPEN COMMAND OUTPUT FILE
RUNOFF::MOV	SPSAV,SP	;RESET STACK POINTER				;**-1
	CALL	$INITL		;INITIALIZE VARIABLES
10$:	CLOSE$	#TTLDMY		;CLOSE INPUT FILE
	CLOSE$	#LSTBLK		;CLOSE LISTING FILE
	GCML$	#TTIBLK		;GET A COMMAND
	BCC	30$
	CMPNEB	#GE.EOF,G.ERR(R0),20$ ;NOT TOP LEVEL EOF
	CLOSE$	#TTBLK
	CLOSE$	#TTIBLK
	EXST$S	EXSTAT							;2.4
	EXIT$S
20$:	MSGPUT	CMDE		;COMMAND ERROR
	BR	10$
30$:	MOV	G.CMLD(R0),R1	;GET BYTE COUNT
	BEQ	10$
	CSI$1	#CSIBLK,TTIBLK+G.CMLD+2,R1;CHECK SYNTAX
	BCS	20$
	CSI$2	#CSIBLK,INPUT,#SWTBL
	BCC	50$
40$:	MSGPUT	IFER		;INPUT FILE SPEC ERROR
	BR	10$
50$:	BITNEB	#CS.MOR!CS.WLD,C.STAT(R0),40$ ;MORE INPUT FILES?
	OPEN$R	#TTLDMY,,#CSIBLK+C.DSDS
	BCC	60$
	MSGPUT	IPER
	BR	10$
60$:	CSI$2	#CSIBLK,OUTPUT,#SWTBL
	BCC	80$
70$:	MSGPUT	OFER		;INPUT FILE SPEC ERROR
	BR	10$
80$:	BITNEB	#CS.MOR!CS.WLD,C.STAT(R0),70$ ;MORE OUTPUT FILES?
	OPEN$W	#LSTBLK,,#CSIBLK+C.DSDS
	BCC	100$
	MSGPUT	OPER		;INPUT FILE OPEN ERROR
	BR	10$
100$:	MOV	PRMRG,	RMARG	;SET RIGHT MARGIN
	TST	PNLPG		;SEE IF /PS::N GIVEN
	BNE	105$
	MOV	#INLPG,	PNLPG	;REINITIALIZE
105$:	MOV	PNLPG,	NLPG	;AND PAGE LENGTH
	CMPNEB	#'B,ULSWT,110$	;NOT BACKSPACE MODE?
	COMB	$ULMSW		;SET BACKSPACE MODE
	BR	130$
110$:	CMPNEB	#'S,ULSWT,120$	;NOT SIMULATE MODE?
	COMB	$ULSSW		;SET SIMULATE SWITCH
	BR	130$
120$:	CMPEQB	#'L,ULSWT,130$	;LINE MODE?
	COMB	$ULNSW		;SET NO UNDERLINE SWITCH


130$:	BITEQB	#RAWSW,$SWTCH,131$	;PASS RAW TEXT				;M02.1
	INCB	$RAWSW			;STRIP RAW TEXT				;M02.1
131$:										;M02.1
	GTSK$S	#CSIBLK		;GET TASK PARAMETERS				;**-2
	MOV	CSIBLK+G.TSTS,R4 ;GET SIZE OF PARTITION IN BYTES
	GPRT$S	,#CSIBLK	;GET STARTING VIRTUAL ADDRESS
	ADD	$DSW,R4		;CALCULATE ENDING VIRTUAL ADDRESS
	MOV	R4,XTOP		;INITIAL INDEX POINTERS				;SIG01-2
	MOV	R4,XBOT		; ..						;SIG01-2
	MOV	LIMIT+2,R2	;GET START OF FOOTNOTE AREA			;SIG01-2
	DEC	R2		;						;SIG01-2
	MOV	R2,FOOTP1	;STORE						;SIG01-2
	MOV	R2,FOOTP2							;SIG01-2
	MOV	R2,FOOTP3	;IN BOTH POINTERS				;SIG01-2
	CALL	LINSET		;SET UP FOR LINE				;SIG01-2
	CALL	FFEED		;START AT TOP OF NEW FORM			;SIG01-2
	CALL	OPRWAT		;WAIT FOR OPERATOR IF REQUESTED TO		;SIG01-2
	CLR	TTBLK+F.NRBD	;CLEAR OUTPUT BUFFER				;SIG01-2
	JMP	LGO		;AND INTO MAIN LOOP, LINE INPUT			;SIG01-2
ENDFIL::CALL	OUTPUT		;FLUSH LAST LINE				;SIG01-2
										;SIG01-2
										;SIG01-2
	.IF	NDF	RSTS							;SIG01-2
										;SIG01-2
	BITEQ	#SPLSW,$SWTCH,10$ ;DON'T SPOOL TEXT FILE?			;SIG01-2
	PRINT$	#LSTBLK		;SUBMIT FILE TO PRINT SYMBIONT			;SIG01-2
										;**-17
	.ENDC


10$:	JMP	RUNOFF								;**-24

	.END