.TITLE	LUDMP
;
; MODIFICATIONS:
;
;	0104A -- CHECK FOR FILES-11 DEVICE BEFORE ACCESSING FCB
;
	.IDENT	/0104A/

	.PSECT
.BLK.	= .

.	= .BLK.+4
NOWIND:

.	= .BLK.+14
UCBADR:

.	= .BLK.+1036
	CALL	PAT1			;CALL PATCH 1
	BCS	10$			; IF CS, DONE WITH LUN

.	= .BLK.+1250
10$:

.	= .BLK.

	.PSECT	PAT1
PAT1:
	MOV	#NOWIND,R1		;ASSUME NO WINDOW
	MOV	R2,R4			;GET WINDOW ADDRESS
	MOV	UCBADR,R5		;GET UCB ADDRESS
	BEQ	10$			; IF EQ, IT IS UNASSIGNED

5$:	MOV	R5,R3			;COPY UCB ADDRESS
	ADD	#2,R3			;POINT TO REDIRECT POINTER
	TRAP	0			;GET IT
	CMP	R2,R5			;END OF REDIRECT CHAIN?
	BEQ	7$			; IF EQ - YES
	MOV	R2,R5			;GET NEXT UCB ADDRESS IN CHAIN
	BR	5$			; AND LOOP

7$:	MOV	R5,UCBADR		;SAVE UCB ADDRESS
	MOV	R5,R3			;COPY UCB ADDRESS
	ADD	#10,R3			;POINT TO DEVICE CHARACTERISTICS
	TRAP	0			;GET IT
	BIC	#007727,R2		;ISOLATE DESIRED BITS
	CMP	#140010,R2		;IS DEVICE NOT MOUNTABLE BY FILES-11
					; OR NOT FILE STRUTURED OR IS IT SEQ,
					; PSEUDO, OR A COMMUNICATIONS CHANNEL?
	BNE	10$			;IF NE, YES, DONE WITH LUN
	MOV	R5,R3			;COPY UCB ADDRESS
	ADD	#5,R3			;POINT TO STATUS BYTE
	TRAP	0			;GET IT
	BITB	#140,R2			;IS DEV NOT MOUNTED OR MOUNTED FOREIGN?
	BNE	10$			; IF NE, YES, DONE WITH LUN
	CLC				;SET FILES-11 FLAG
	BR	20$			;

10$:	SEC				;SET NON FILES-11 FLAG
20$:	RETURN				;

	.END