.TITLE	FIRST - SFGL70 ROUTINE TO PLOT 1ST PT FOR PLOT[C]

.IDENT	'FIRS00'

.PSECT	FIRST

;	KEN DEMERS
;	UTRC
;	OCTOBER 1979

;	THIS ROUTINE IS PART OF THE SMALL FAST
;	GRAPHIC LIBRARY ON THE 11/70(SFGL70), WHICH
;	HAS THE SAME FUNCTIONALITY OF THE PDP-6
;	MEMO SCOPE LIBRARY. THIS ROUTINE IS NEEDED
;	BECAUSE DEPENDING WHETHER IT WAS 1. CALLED
;	FROM PLOT OR PLOTC AND 2. WHETHER THE CALL
;	WAS IN CONTINUOUS OR DASHED MODE, THE ACTION
;	FOR THE 1ST POINT IS DIFFERENT.

;	ON ENTRY:

;	NEXPLT = FLG WHICH SPECIFIES WHETHER TO PLOT OR MOVE CURSOR
;	0 = MOVE CURSOR
;	-1 = PLOT
;	R3 = WHETHER CALLED FROM PLOT OR PLOTC
;	0 = PLOT
;	-1= PLOTC
;	R4 = DASH OR CONTINUOUS PLOT MODE FLG
;	0 = CONTINUOUS
;	-1 = DASH


;	INTERNAL GLOBALS

.GLOBL	F$IRST

;	EXTERNAL GLOBALS

.GLOBL	MVCURI,L$INE,S$CALE,N$EXPLT,A$RGB1



F$IRST:	CALL	S$CALE		;S$CALE PTS TO PLOT FOR GRID COORD SYSTEM
	MOV	#A$RGB1,R5	;R5= A(MVCURI OR L$INE ARG BLK)
	TST	R3		;CALLED FROM PLOT?
	BNE	FIR10		;NO,CALLED FROM PLOTC
	CALL	MVCURI		;MOVE CURSOR
	COM	R3		;FLG= -1 = PLOT L$INE NEXT TIME
	BR	FIR30
FIR10:	TST	N$EXPLT		;SHOULD WE PLOT OR MOVE CURSOR?
	BEQ	FIR20		;MOVE CURSOR
	CALL	L$INE		;PLOT L$INE
	TST	R4		;DASH MODE?
	BEQ	FIR30		;NO,KEEP PLOTTING
	COM	R3		;FLG=0= NEXT TIME MOVE CURSOR
	BR	FIR30
FIR20:	CALL	MVCURI		;MOVE CURSOR
				;FLG ALREADY=-1= PLT L$INE NEXT TIME
FIR30:	MOV	R3,N$EXPLT	;SAVE WHAT NEXT PLT WILL BE
	RETURN
	.END