10 ! PROGRAM TO SEPERATE RUNOFF FILES INTO LEFT AND RIGHT PAGES
20 DIM A$[255]V,N$[30]V,N1$[30]V,N2$[30]V,N3$[30]V,NP(5)
25 DIM B$[20],C$[20]V
30 B$="                    "
40 PRINT "NAME OF SOURCE FILE ";
50 INPUT N$
55 IF POS(N$,".")<1 THEN LET N$=N$+".DOC"
60 N3$=N$+"/RO/LN:255"
65 LET N$=SBS$(N$,1,POS(N$,".")-1)
70 N1$=N$+".LFT/WR/LN:255"
80 N2$=N$+".RGT/WR/LN:255"
85 FF=0			:! CLEAR FORM-FEED FLAG
90 OPEN #3,N3$
95 OPEN #4,N1$
100 INPUT "SKIP PRINTING ON BACK OF FIRST (TITLE PAGE) "A$
103 TP=0
105 IF A$="Y" THEN LET TP=1
106 CF=0
107 INPUT "PRINT CHAPTERS & APPENDICES ON RIGHT PAGE ";A$
109 IF A$="Y" THEN LET CF=1
110 OPEN #5,N2$
115 OL=4		: ! FIRST FF WILL SWITCH US TO RIGHT HAND PAGE
117 IF END #3 THEN 170
120 INPUT LINE #3,A$
125 IF FF=-1 THEN PRINT A$ : FF=0
130 IF ASC(SBS$(A$,1,1)) <> 12 GOTO 150	:! NOT A FORM FEED
135 ! SWITCH OUTPUT FILES
140 FF=1		:! SHOW FF JUST SEEN
142 OL=OL+1
145 IF OL=6 THEN OL=4
147 NP(OL)=NP(OL)+1
148 !		! FIRST RNO PAGE HAS TAB, SUBSEQUENT HAVE TAB,CR
150 IF LEN(A$)=2 THEN 161		:!SKIP TEST IF A FF ON 2ND..N PAGES
151 IF FF<1 THEN 161			:! SKIP TEST IF FF NOT PREVIOUS LINE
152 FF=-1		:! CLEAR FORM FEED SWITCH, THIS IS A HEADER LINE
153 C$=SBS$(B$,1,LEN(A$)-1)+CHR$(13)	:! MAKE SPACE STRING SAME LENGTH
154 PRINT A$
155 IF C$<>A$ THEN 160			:! SKIP IF NOT BLANK LINE
156 IF OL*CF=5 THEN 160			:! OK IF CHAPTER,APP, ON RIGHT PAGE
157 PRINT #5,CHR$(12) : OL=5		:! PUT A BLANK PAGE
158 PRINT "SHIFTED TO RIGHT PAGE"
159 NP(5)=NP(5)+1
160 IF TP=1 AND OL=4 THEN LET TP=0 : GOTO 157 :! RIGHT PAGE IF TITLE PAGE
161 IF LEN(A$)<>2 THEN 165
162 IF ASC(SBS$(A$,2,1))<>13 THEN 165	:! SKIP IF NOT 2-CHAR HEADER
163 A$=SBS$(A$,1,1)			:! TRIM SO DIA PROGRAM NOT CONFUSED
165 IF OL=4 THEN  PRINT #4,A$
166 IF OL=5 THEN  PRINT #5,A$
167 GOTO 120
170 PRINT NP(4);" PAGES FOR FILE  ";N$;".LFT"
171 PRINT NP(5);" PAGES FOR FILE  ";N$;".RGT"
175 IF NP(4)<>NP(5) THEN  PRINT #4 CHR$(12)
176 IF NP(4)<>NP(5) THEN  PRINT "PAGE ADDED TO ";N$;".LFT"
177 CLOSE 
180 STOP