.TITLE	GETUIC
	.IDENT	/V01/
	.SBTTL	DESCRIPTION
;
;
;  COMPONENT:	GETUIC
;
;  DATE:	02-AUG-79
;
;  AUTHOR:	GR JOHNSON
;		BATTELLE NORTHWEST
;		P O BOX 999
;		RICHLAND WA 99352
;
;  SOURCE:	MACRO-11
;
;  CALLER:	FORTRAN IV-PLUS
;
;  CALLING SEQUENCE:
;
;		CALL GETUIC([DEFUIC],[CURUIC])
;
;		DEFUIC	= VARIABLE TO RECEIVE AN INTEGER REPRESENTATION
;			  OF THE USER'S DEFAULT UIC.
;
;		CURUIC	= VARIABLE TO RECEIVE AN INTEGER REPRESENTATION
;			  OF THE USER'S CURRENT UIC.
;
;
;  DESCRIPTION:
;
;	"GETUIC" FETCHES THE CALLING ROUTINE'S DEFAULT AND CURRENT USER
;  IDENTIFICATION CODE.  THE UIC(S) ARE RETURNED AS INTEGER VALUES.
;
;

	.SBTTL	ENTRY POINT -- FETCH UIC(S)
;
;
					;
	.PSECT				;
	.MCALL	GTSK$S			;
					;
GETUIC::				;
					;
	CMPB	#1,(R5)			; AT LEAST ONE ARGUMENT?
	BGT	RTN			; NO, RETURN TO CALLER
	MOV	#TSKBUF,R0		; R0 POINTS TO BUFFER
	GTSK$S	R0			; FETCH TASK PARAMETERS
					;
	TST	2(R5)			; RETURN DEFAULT UIC?
	BLT	2$			; NO, TRY RETURNING CURRENT UIC
	MOV	G.TSDU(R0),@2(R5)	; YES, RETURN DEFAULT UIC TO CALLER
					;
	CMPB	#2,(R5)			; TWO ARGUMENTS?
	BGT	RTN			; NO, RETURN TO CALLER
2$:	TST	4(R5)			; NULL ARGUMENT?
	BLT	RTN			; YES, RETURN TO CALLER
	MOV	G.TSPC(R0),@4(R5)	; NO, RETURN CURRENT UIC TO CALLER
					;
RTN:	RTS	PC			; RETURN TO CALLER
					;
	.EVEN				;
					;
TSKBUF:	.BLKW	20			; TASK PARAMETERS BUFFER
					;
	.END				;