$ ! FLE.COM		MAO		18-JUL-80
$ SAVE_VERIFY = 'F$VERIFY()'		!INITIAL VERIFY STATUS
$ SET NOVERIFY				!NO ECHO COMMANDS
$ !
$ ! FILE TO TRANSLATE AND COMPILE A FLECS MODULE.
$ !
$ ! CALLING SEQUENCE:	$ @FLE FILENAME FORSW
$ !
$ ! INPUT:	FILENAME=FILE NAME (WITHOUT EXTENSION) FOR FLECS INPUT FILE.
$ !			 FILE TYPE MUST BE .FLX.
$ ! 		FORSW=ANY FORTRAN QUALIFIERS TO BE USED (MAY BE BLANK).
$ !
$ ON ERROR THEN GOTO FIN		!GIVE UP IF ERROR OCCURS
$ !
$ IF P1 .EQS. "" THEN GOTO ASK
$ !
$ NAME := 'P1'
$ SW := 'P2'
$ GOTO TRAN
$ !
$ ASK:
$ INQUIRE NAME GIVE FLECS FILE NAME
$ IF NAME .EQS. "" THEN GOTO ASK
$ INQUIRE SW GIVE FORTRAN QUALIFIERS
$ !
$ TRAN:
$ SET VERIFY				!ECHO COMMANDS
$ DELETE 'NAME'.OBJ;*,'NAME'.FLL;*		!DELETE OLD OBJ AND FLL FILES
$ ON WARNING THEN GOTO FIN		!GIVE UP IF ERROR OCCURS
$ MCR FLE 'NAME'.FOR,'NAME'.FLL/-SP='NAME'.FLX	!TRANSLATE
$ FOR/LIST='NAME'.LST'SW' 'NAME'			!COMPILE
$ APPEND 'NAME'.LST 'NAME'.FLL
$ DELETE 'NAME'.LST;*,'NAME'.FOR;*		!DELETE INTERMEDIATE FILES
$ FIN:
$ IF .NOT.SAVE_VERIFY THEN SET NOVERIFY !RESET INITIAL VERIFY STATUS
$ EXIT
$ !
$ ! END OF FILE FLE.COM