! - - - - - - - - - - - - - - -	!
! TECO MACRO ANALYSIS ROUTINE	!
! - - - - - - - - - - - - - - -	!
! THIS TECO MACRO PERFORMS A	!
! SIMPLE ANALYSIS OF THE COND-	!
! ITIONAL NESTING WITHIN OTHER	!
! TECO MACROS.  IT REPLACES	!
! CHARACTERS WITHIN CONDITIONAL	!
! CODE WITH A CHARACTER CORRES-	!
! PONDING TO THE LEVEL OF THE	!
! CONDITIONAL, WITH "A" BEING	!
! THE LOWEST LEVEL.  IF THE	!
! CONDITIONAL CONTAINS AN "ELSE"!
! CLAUSE, THE CHARACTERS WITHIN	!
! IT ARE REPLACED BY THE LOWER	!
! CASE VALUE OF THE CURRENT	!
! LEVEL.			!
! - - - - - - - - - - - - - - -	!
! FOR EXAMPLE,			!
! 				!
! 0A"D Z-5"G OEX$'| OSTART$'	!
! 				!
! WOULD BECOME			!
!				!
! AA"BBBBB"CCCCCC'|bbbbbbbb'	!
!				!
! - - - - - - - - - - - - - - -	!
!				!
! THE CONTENTS OF THE MACRO	!
! MUST BE IN THE BUFFER WHEN	!
! THIS MACRO IS INVOKED, I.E.	!
! "ERXXX.TEC$YEIANAL$$"		!
!				!
! - - - - - - - - - - - - - - -	!
!				!
! COMMENTS (AND TAGS) ARE	!
! SKIPPED, AS ARE STRINGS IN	!
! @S SEARCHES, @O JUMPS,	!
! @I INSERTS, @^U INSERTS,	!
! @FX SEARCHES, @Ex DEFINITIONS,!
! AND @^A PRINTOUT		!
! COMMANDS.  IF THE ", ', OR	!
! EXCLAMATION POINT		!
! CHARACTERS APPEAR ANYWHERE	!
! ELSE, THE ANALYSIS WILL FAIL.	!
! - - - - - - - - - - - - - - -	!

! 				!
! IF THIS IS A SCOPE, ASK IF	!
! HE WANTS TO WATCH THE PROGRESS!
! 				!

@EI%% ET&512"N @^A#Watch progress on CRT? [Y/N]: # 0UW ^T-^^Y"E -1UW ' '

^^AUA

J:@S%"%"F @^A%No conditionals found.
% @O%EX%' J

! MAIN LOOP STARTS HERE.	!

< Z-."G
QW"T -1W '

! IF NOT SPECIAL CHARACTER - REPLACE IT. !
0A"C !A! D QA@I%% F< '
! SKIP SPACES.		!
! 0A-32"E C F< '	!

0A-^^!"E C :@S%!%"F @^A%Unmatched comment delimiter.
% @O%EX%' F<'

::@S%^^"% "S F<'
::@S%^^'% "S F<'
::@S%^^!% "S F<'
::@S%^^|% "S F<'

::@S%@FS% "S 0AUD C 0ED :@S%^EUD%"S R' @O%DELIM% '
::@S%@FN% "S 0AUD C 0ED :@S%^EUD%"S R' @O%DELIM% '

0ED ::@S%@E^X% "S @O%DELIM%'
1ED ::@S%@S% "S @O%DELIM%'
::@S%@O% "S @O%DELIM%'
::@S%@I% "S@O%DELIM%'
::@S%@^A% "S !DELIM! 0AUD C 0ED :@S%^EUD%"F @^A%Unmatched quoted string.
% @O%EX%' F<'

! FOLLOWING CHECKS FOR @^U^X	!
::@S%@^% "S 0ED ::@S%U^X% "S @O%DELIM%' '

0A-13"E L F<'
0A-10"E L F<'
0A-12"E L F<'

0A-^^""E [A 32^_&QA+1UA C F<'

0A-^^|"E 32#QAUA C F<'

0A-^^'"E ]A C F<'

1ED @O%A% | ^N"F :P"F @^A%Page output operation failed - executing yank.
% EY ' F< ' 0; ' >

!EX!