.NLIST	LOC,BIN
	.TITLE	RSXERR - RSX ERROR MSG SUBROUTINE		
	.IDENT	/V001.0/
;+
;
;   AUTHOR:  M. YANKUS		PLANNING RESEARCH CORP.
;				1508 KENNEDY DR.
;				BELLEVUE, NEBR.  68005
;
;   DATE:	APR-78
;
;
;   FUNCTIONAL DESCRIPTION
;
;	USES MO TO PRINT QIO, FCS, AND DSW ERRORS.
;
;
;   RECORD OF MODIFICATIONS
; 	VERSION     DATE	BY		DESCRIPTION
;	-------     ----	--		-----------
;
;	NO MODIFICATIONS
;
;
;   TASK BUILDER COMMAND STRING
;
;	N.A.
;
;
;   GLOBAL EVENT FLAG USAGE
;
;	NONE
;
;-
	.PAGE
	.LIST	LOC,BIN
;+
;
;   LOCAL MACRO DEFINITIONS AND SYSTEM MACRO CALLS
;
;-
	.MCALL	MOUT$,DIR$,MOWA$S
;
;+
;
;   LOCAL SYMBOL DEFINITIONS AND DATA
;
;-
MOUT:	MOUT$	STR,PRM,0
;
STR:	.WORD	FLEN,FNAM
FNAM:	.ASCII	/[1,2]RSX.MSG/
FLEN=	.-FNAM
	.EVEN
PRM:	.WORD	0		;PROGRAM COUNTER
EC:	.WORD	0		;ERROR CODE
;
	.PAGE
QIOERR::
	MOV	(SP)+,PRM	;PC
	MOV	(SP),EC		;ERROR WORD
	MOV	PRM,(SP)	;REPLACE RETURN ADDRESS
	BR	ERR0
FCSERR::
	MOV	(SP),PRM	;PC OF ERROR
	MOVB	F.ERR(R0),EC	;ERROR CODE
ERR0:
	MOVB	EC,-(SP)
	SXT	EC
	MOVB	(SP)+,EC
	CLR	MOUT+M.ONUM	;REC # OFFSET
	BR	ERR2
DSWERR::
	MOV	(SP),PRM	;PC OF ERROR
	BR	ERR1
DSWER1::
	MOV	2(SP),PRM	;PC OF ERROR
ERR1:
	MOV	$DSW,EC		;DIRECTIVE STATUS WORD
	MOV	#-128.,MOUT+M.ONUM ;REC # OFFSET
ERR2:
	ADD	EC,MOUT+M.ONUM	;COMPUTE -
	NEG	MOUT+M.ONUM	; REC #
	MOV	.MOLUN,MOUT+M.OLUN ;LUN FOR MO....
	DIR$	#MOUT
	BCS	10$
	MOWA$S			;WAIT FO MO....
10$:	ROL	EC		;SET/CLR CARRY BIT
	RTS	PC
;
	.END