SUBROUTINE AUTOVR
	CALL AUTONT(16,0)
	RETURN
	END
	SUBROUTINE GRAB
	CALL AUTONT(14,1)
	RETURN
	END
	SUBROUTINE AUTONT(II,IGRAB)
	INCLUDE 'TREK.COM/-LI'
C--------CHECK TO SEE IF CAPTAIN ON A PLANET
 5    IF(LANDED .NE. 1) GO TO 45
      IF(DAMAGE(12) .GT. 0) GO TO 25
      CALL PROUT(42HSCOTTY RUSHES TO THE TRANSPORTER CONTROLS.,42) 
      IF(SHLDUP .EQ. 0) GO TO 20
      CALL PROUT(38HBUT WITH THE SHIELDS UP IT'S HOPELESS.,8)       
      GO TO 25
 20   CALL CRAM(42HHIS DESPERATE ATTEMPT TO RESCUE YOU . . . )
      IF(RANF(0) .GT. 0.5) GO TO 30 
      CALL CRMDMP(6HFAILS. ) 
 25   CALL FINISH(II)
	RETURN
 30   CALL CRMDMP(9HSUCCEEDS!)       
      IF(IMINE .EQ. 0) GO TO 45 
      IMINE=0 
      CALL CRAM(24HTHE CRYSTALS MINED WERE )
      IF(RANF(0) .GT. 0.25) GO TO 40
      CALL CRMDMP(5HLOST.)  
	GO TO 45
 40   CALL CRMDMP(6HSAVED.)
	IXTL=1
 45   IF(IGRAB.NE.0) RETURN 
C--------CHECK TO SEE IF CAPTAIN IN SHUTTLE CRAFT 
      IF(ICRAFT.NE.0) CALL FINISH(17) 
      IF(ALLDON.NE.0) RETURN 
C--------INFORM CAPTAIN OF ATTEMPT TO REACH SAFETY
      CALL SKIP(1)
      IF(JUSTIN .EQ. 0) GO TO 50
 47   CALL RDALRT
      CALL CRAM(7H***THE )
      CALL CRMSHP
      CALL CRMDMP(37H HAS STOPPED IN A QUADRANT CONTAINING)
      CALL PROUT(15H   A SUPERNOVA.,2)
      CALL SKIP(1)
 50   CALL CRAM(49H***EMERGENCY AUTOMATIC OVERRIDE ATTEMPTS TO HURL ) 
      CALL CRMSHP
      CALL CREND
      CALL PROUT(23HSAFELY OUT OF QUADRANT.,23)
      STARCH(QUADX,QUADY)=1 
C--------TRY TO USE WARP ENGINES
      IF(DAMAGE(6) .EQ. 0) GO TO 100
      CALL SKIP(1)
      CALL PROUT(21HWARP ENGINES DAMAGED.,21)
      CALL FINISH(8)
      RETURN
 100  WRPFAC=6.0+2.0*RANF(0) 
      WFACSQ=WRPFAC*WRPFAC
      CALL CRAM(19HWARP FACTOR SET TO ) 
      CALL CRAMF(WRPFAC,0,1) 
      CALL CREND
      POWER=0.75*ENERGY 
      DSTMAX=POWER/(WRPFAC*WRPFAC*WRPFAC*(SHLDUP+1))
      DSTREQ=1.4142+2.0*RANF(0)
      DIST=AMIN1(DSTMAX,DSTREQ) 
      TIME=10.0*DIST/WFACSQ 
      DIREC=12.0*RANF(0)
      JUSTIN=0
      INORBT=0 
      CALL WARPX
      IF(ALLDON.NE.0) RETURN 
      IF(JUSTIN.NE.0) GO TO 200   
      CALL SKIP(1)
      CALL PROUT(38HINSUFFICIENT ENERGY TO LEAVE QUADRANT.,38) 
      CALL FINISH(8)
      RETURN
C--------REPEAT OVERRIDE IF SHIP JUMPED FROM ONE SUPERNOVA TO ANOTHER 
 200  IF(GALAXY(QUADX,QUADY) .EQ. 1000) GO TO 47
      IF(REMKL .EQ. 0) CALL FINISH(1) 
      RETURN
      END