.TITLE PAPER-TAPE VERIFICATION PROGRAM
        .IDENT  /V01.1B/
        .ENABL AMA
        .NLIST BEX
        .MCALL DIR$,QIOW$,EXIT$S,EXST$S
CR=     15
LF=12
BELL=7
B.SIZE=140.
BUFFER: .BLKB   B.SIZE
IOST:   .BLKW   2
PRMPT: .BYTE    CR,LF
        .ASCII /PLACE TAPE IN READER AND HIT RETURN/
$PRMPT=.-PRMPT
GOOD:   .BYTE   CR,LF
        .ASCII /TAPE IS GOOD!/
$GOOD=.-GOOD
BAD:    .BYTE   CR,LF,BELL
        .ASCII /**** T A P E   I S   B A D ****/
        .BYTE   BELL
$BAD=.-BAD
        .EVEN
PROMPT: QIOW$   IO.WVB,1,3,,IOST,,<PRMPT,$PRMPT,0>
WAIT:   QIOW$   IO.RVB,1,3,,IOST,,<BUFFER,1>
READIT: QIOW$   IO.RVB,2,3,,IOST,,<BUFFER,B.SIZE>
OK:     QIOW$   IO.WVB,1,3,,IOST,,<GOOD,$GOOD,0>
BADTAP: QIOW$ IO.WVB,1,3,,IOST,,<BAD,$BAD,0>
START:
1$:    DIR$     #PROMPT                 ;SEND OUT PROMPT
        DIR$    #WAIT
        CMPB    #IE.EOF,IOST            ;DO THEY WANT TO QIUT?
        BEQ     20$                     ;BR IF YES
5$:     DIR$    #READIT                 ;READ A BLOCK OF TAPE
        TSTB    IOST                    ;ANY ERRORS?
        BMI     10$
        CMP     #2,IOST+2               ;LAST BLOCK?
        BNE     5$
        DIR$    #OK                     ;SAY OK
        BR      START                   ;BEG FOR MORE
10$:    DIR$      #BADTAP
        BR      START
20$:    EXIT$S                          ;BYE
        .END    START