SUBROUTINE NEWNAM (TSK)
C********************************************************
C
C	THIS ROUTINE TAKES A TWO WORD RADIX-50
C	PROGRAM NAME AND SHRINKS IT TO A THREE
C	CHARACTER (1 WORD) RADIX NAME.
C
C	METHOD --
C	SHIFTS THE SIX CHARACTERS LEFT INSERT-
C	ING BLANKS ON RIGHT.  THE SHIFT IS
C	REPEATED UNTIL A NON-BLANK AND NON-DOT
C	(.) IS IN POSITION ONE.  IF THE FIRST
C	TWO CHARACTERS ARE 'TT' AND THE THIRD
C	IS A NUMERIC, THE NUMERIC IS ALSO SET
C	TO BLANK.  THE SECOND WORD OF THE NAME
C	IS SET TO RADIX-50 BLANKS.
C
C********************************************************
C
	LOGICAL*1 C(6),BLANK,DOT,T,ZERO,NINE
C
	INTEGER*2 TSK(2)
C
	DATA BLANK,DOT,T,ZERO,NINE/1H ,1H.,1HT,1H0,1H9/
C
	CALL R50ASC (6,TSK,C)
C
	N=0
	DO 100 I=1,6
	IF (C(I).NE.BLANK.AND.C(I).NE.DOT) GO TO 200
100	N=I
200	IF (N.EQ.0) GO TO 500
C
	DO 400 I=1,N
	DO 300 J=2,6
300	C(J-1)=C(J)
400	C(6)=BLANK
C
500	IF (C(1).NE.T) GO TO 600
	IF (C(2).NE.T) GO TO 600
	IF (C(3).LT.ZERO.OR.C(3).GT.NINE) GO TO 600
	C(3)=BLANK
600	CALL IRAD50 (3,C,TSK)
	TSK(2)=0
	RETURN
	END