SUBROUTINE KREPT (KD,MNTH,IDAY,KERN,PROG,IDOWN)
C****************************************************************
C
C	SYSTEM ACTIVITY REPORTING PROGRAM.  PRINTS A 
C	PRINTER GRAPH OF SYSTEM USAGE IN KERNAL AND 
C	PROGRAM ACTIVITIES.   TWO MODES ARE POSSIBLE...
C
C	IF KD=1	
C		DAILY SUMMARY
C
C	IF KD=2
C		MONTHLY SUMMARY
C
C	IF KD=3
C		MONTHLY SUMMARY ON DAY RANGE
C
C****************************************************************
C
	LOGICAL*1 IDOWN(1),LINE(100)
C
	REAL KERN(1),PROG(1),MNTHS(3,12)
C
	INTEGER*2 MIN(2),IDAY(1)
C
	DATA MNTHS /'  JA','NUAR','Y   ','  FE','BRUA','RY  ',
     *		    '   M','ARCH','    ','   A','PRIL','    ',
     *		    '    ','MAY ','    ','    ','JUNE','    ',
     *		    '    ','JULY','    ','   A','UGUS','T   ',
     *		    ' SEP','TEMB','ER  ','  OC','TOBE','R   ',
     *		    '  NO','VEMB','ER  ','  DE','CEMB','ER  '  /
C
	DATA LINE / 100*' ' /,  MIN/ 2H00, 2H30  /
C
9000	FORMAT (1H1,48X,'S Y S T E M    U T I L I Z A T I O N',
     *		/49X,36('*'),/)
9010	FORMAT (60X,3A4,/60X,12('*'),/)
9020	FORMAT (58X,I2,2X,3A4,/57X,16('*'),/)
9030	FORMAT (4X,'P=',I3,'% K=',I3,'%  ',I2,':',A2,2X,'*',100A1,'*')
9040	FORMAT (4X,124('*'))
9050	FORMAT (56X,I3,' -',I3,2X,3A4,/56X,21('*'),/)
9060	FORMAT (25X,'0 %',46X,'50 %',46X,'100 %')
C
	WRITE (6,9000)
	IF (KD.EQ.1) WRITE (6,9020) IDAY(1),MNTHS(1,MNTH),MNTHS(2,MNTH),
     *				    MNTHS(3,MNTH)
	IF (KD.EQ.2) WRITE (6,9010) MNTHS(1,MNTH),MNTHS(2,MNTH),
     *				    MNTHS(3,MNTH)
	IF (KD.EQ.3) WRITE (6,9050) IDAY(1),IDAY(2),MNTHS(1,MNTH),
     *				    MNTHS(2,MNTH),MNTHS(3,MNTH)
C
	WRITE (6,9060)
	WRITE (6,9040)
C
	N=0
	K=-1
	DO 2000 I=1,24
	K=K+1
C
	DO 1500 J=1,2
	N=N+1
C
	LINE(50)=1H.
	IF (IDOWN(N).GT.0) GO TO 1000
	LINE(1)=1HD
	LINE(2)=1HO
	LINE(3)=1HW
	LINE(4)=1HN
	K1=0
	K2=0
	WRITE (6,9030) K2,K1,K,MIN(J),LINE
	DO 500 L=1,4
500	LINE(L)=1H 
	GO TO 1500
C
1000	J1=KERN(N)*100.0+0.5
	K1=J1
	IF (J1.LT.1) J1=1
	IF (J1.GT.100) J1=100
	J2=PROG(N)*100.0+0.5
	K2=J2
	IF (J2.LT.1) J2=1
	IF (J2.GT.100) J2=100
	LINE(J1)=1HK
	LINE(J2)=1HP
	WRITE (6,9030) K2,K1,K,MIN(J),LINE
	LINE(J1)=1H 
	LINE(J2)=1H 
1500	CONTINUE
2000	CONTINUE
C
	WRITE (6,9040)
	RETURN
	END