.TITLE	ID - TERMINAL AND NODE
	.IDENT	/01/
;
;	DW. ENSTROM
;	28-NOV-78
;
;		TERMINAL ID AND NODE ID
;
;	THIS TASK SENDS TO THE INITIATING TERMINAL ITS TERMINAL
;	NUMBER AND THE NAME OF THE DECNET NODE TO WHICH IT IS 
;	ATTACHED.
;
;	THE COMMAND FILE TO BUILD THIS TASK IS:
;
;
;
;	ID,ID=ID
;	/
;	UNITS=2
;	ASG=TI:1
;	TASK=...TID
;	STACK=40
;	ACTFIL=0
;	//
;
;
;
;	NOTE:	LUN	1 IS ASSIGNED TO TI:
;		LUN	2 IS ASSIGNED TO NS:
;
	.MCALL	QIOW$C,ALUN$C,GLUN$C,EXIT$S,CLSW$S,OPNW$S,GLNW$S
;
;
START:	ALUN$C	2,NS,0		;ASSIGN LUN 2 TO NETWORK
	CMP	#IE.IDU,$DSW	;INVALID DEVICE ...
	BEQ	SKIP		;BR IF YES - NET NOT UP
	OPNW$S	#2,#1,#IOST	;SET TASK AS NETWORK TASK
	BCC	1$		;BR IF DIR ACCEPTED
	MOV 	$DSW,R0
	CMPB	#IE.HWR,R0	;DEVICE DRIVER NOT RESIDENT - NET IS DOWN
	BEQ	1$		;BR IF YES
	HALT
1$:	TSTB	IOST
	BPL	SKIP
	MOV	IOST,R1
	HALT
SKIP:	GLUN$C	1,UNITB		;GET LUN INFORMATION
	MOVB	UNITB+G.LUNU,R3	;GET TERMINAL NUMBER
	CLR	R2		;SET UP DIVIDE
	DIV	#8.,R2		;RESULT IN R2 & R3
	ADD	#60,R2		;CONVERT TO ASCII #
	ADD	#60,R3		;CONVERT TO ASCII #
	MOVB	R2,NUMBER	;PUT IN BUFFER
	MOVB	R3,NUMBER+1	;SAVE
	GLNW$S	#2,#1,#IOST,,<#NODE,#6>
	BCC 	1$
	MOV	$DSW,R0
	CMPB	#IE.HWR,R0	;DEVICE DRIVER NOT RESIDENT - NET DOWN
	BEQ	1$		;BR IF YES
	HALT
1$:	TSTB	IOST
	BPL	2$
	CMPB	#IE.IFC,IOST	;INVALID FUNCTION CODE(NET DOWN) ...
	BEQ	2$		;BR IF YES
	MOV	IOST,R1
	HALT
2$:	QIOW$C	IO.WLB,1,1,,IOST,,<TERMSG,45.>	;SEND ID'S
	CLSW$S	#2,#1,#IOST
	EXIT$S			;EXIT
;
;
	.NLIST	BEX
UNITB:	.BLKW	6		;LOGICAL UNIT NUMBER INFO BUFFER
TERMSG:	.BYTE	15,12		;<CR> <LF>
	.ASCII	/YOU ARE TERMINAL NUMBER /
NUMBER:	.BYTE	60,60		;TERMINAL NUMBER
	.ASCII	/ ON NODE: /
NODE:	.BYTE	40,40,40,40,40,40	;DECNET NODE NAME
	.BYTE	15,12		;<CR> <LF>
	.EVEN
IOST:	.BLKW	2		;STATUS OF I/O
	.END	START