0020 DIM A$[5],B$[1]
0030  N5=8
0040  N4=8
0050 PRINT "INSTRUCTIONS ";
0060 INPUT B$
0070 IF B$="Y" THEN RUN "KING1"
0080 PRINT "GOOD LUCK (YOU'LL NEED IT) !"
0090 RANDOMIZE
0400  M=INT(70000+(RND(0)*1000)-(RND(0)*1000))
0410  P=INT(500+(RND(0)*10)-(RND(0)*10))
0420  L=2000
0430  S1=0
0431  S0=0
0432  E0=0
0433  E1=0
0434  S9=0
0435  M5=0
0436  X1=0
0437  X2=0
0438  W=0
440 D1=INT(P/3)
450 L1=INT((RND(0)*5)+10)
460 L0=INT(RND(0)*10+95)
470 GOSUB 2220
480 PRINT "YOU HAVE";M;"RALLODS"
490 PRINT P;" COUNTRYMEN";
500 IF W=0 THEN 520
510 PRINT W;" FOREIGN WORKERS,";
520 PRINT " AND";L;" SQ. MILES OF LAND."
530 PRINT "THIS YEAR INDUSTRY WILL BY LAND FOR";L0;" RALLODS/SQ. MILE"
540 PRINT "LAND CURRENTLY COSTS";L1;" RALLODS/SQ. MILE TO PLANT"
550 IF S1=0 THEN 570
560 PRINT "POLLUTION LEVEL IS";S1;" UNITS"
570 GOSUB 2220
580 PRINT "HOW MANY SQ. MILES TO SELL TO INDUSTRY";
590 INPUT L2
610 IF L2<(L-1000) THEN 680
620 PRINT "THINK AGAIN, YOU'VE ONLY";L-1000;" SQ. MILES OF FARM LAND"
630 IF X1 <> 0 THEN 580
640 PRINT "(FOREIGN INDUSTRY NOT INSTERESTED IN FORESTS BECAUSE OF"
650 PRINT "GREATER DEVELOPMENT COSTS)"
660 X1=1
670 GOTO 580
680 LET M=INT(M+L2*L0)
690 L=INT(L-L2)
700 X9=INT(44*(2000-L))
710 M2=0
720 M3=0
730 M4=0
740 PRINT "HOW MANY RALLODS TO DISTRIBUTE TO COUNTRYMEN";
760 INPUT M1
780 IF M1<=M THEN 810
790 GOSUB 2250
800 GOTO 740
810 M=INT(M-M1)
820 IF M=0 THEN 1170
830 PRINT "HOW MANY SQ. MILES TO PLANT";
840 INPUT L3
860 IF L3<=P*2 THEN 890
870 PRINT "EACH COUNTRYMAN CAN ONLY PLANT 2 SQ. MILES"
880 GOTO 950
890 IF L3<=L-1000 THEN 920
900 PRINT "ONLY GOT";L-1000;" SQ. MILES OF FARM LAND"
910 GOTO 950
920 M4=INT(L3*L1)
930 IF M4<=M THEN 990
940 GOSUB 2250
950 PRINT "YOU CAN AFFORD";INT(M/L1);" AND HAVE LABOR FOR";P*2;
970 PRINT " AND HAVE";L-1000;" SQ. MILES"
980 GOTO 830
990 M=INT(M-M4)
1000 IF M=0 THEN 1170
1010 PRINT "HOW MUCH TO SPEND FOR EDUCATION ";
1020 INPUT M2
1040 IF M2<=M THEN 1070
1050 GOSUB 2250
1060 GOTO 1010
1070 M=INT(M-M2)
1080 IF M=0 THEN 1170
1090 IF L=2000 THEN 1170
1100 PRINT "HOW MUCH TO SPEND TO COMBAT POLLUTION";
1110 INPUT M3
1130 IF M3<=M THEN 1160
1140 GOSUB 2250
1150 GOTO 1100
1160 M=INT(M-M3)
1170 GOSUB 2220
1180 D0=0
1190 E2=M2/P
1200 D2=INT(P-M1/100)
1210 IF D2<=0 THEN 1240
1220 D0=D2
1230 PRINT D2;" COUNTRYMEN DIED FROM STARVATION"
1240 D3=INT((S1/100000)*(.1+.4*RND(0))*P)
1250 IF D3<=0 THEN 1280
1260 PRINT D3;" COUNTRYMEN DIED FROM EXCESS POLLUTION"
1270 D0=D0+D3
1280 IF D0<=0 THEN 1400
1290 F=D0*9
1300 PRINT "YOU WERE FORCED TO SPEND";F;" RALLODS FOR FUNERALS"
1310 M=INT(M-F)
1320 IF M>=0 THEN 1400
1330 PRINT "INSUFFICIENT RESOURCES FORCED SALE OF LAND"
1340 T0=-INT((M-L0+1)/L0)
1350 L=L-T0
1360 IF L>=1000 THEN 1390
1370 PRINT "NOT ENOUGH LAND TO SELL"
1380 GOTO 2270
1390 M=M+T0*L0
1400 IF D0>200 THEN 2300
1410 P=P-D0
1420 D1=D1-D0
1430 IF D1<0 THEN 2410
1440 IF D2<=2 THEN 1460
1450 IF M>500 THEN 2520
1460 IF L2=0 THEN 1520
1470 T0=INT(L2+L2*RND(2)*2)
1480 IF W=0 THEN 1500
1490 T0=INT(T0+.1*W)
1500 PRINT T0;" WORKERS CAME TO THE ISLAND AND";
1510 W=W+T0
1520 T0=INT(((500-P)/10-D3/3-D2/5)*.75*(1+RND(0)))
1530 PRINT ABS(T0);" COUNTRYMEN ";
1540 IF T0<0 THEN 1570
1550 PRINT "CAME TO";
1560 GOTO 1580
1570 PRINT "LEFT";
1580 PRINT " THE ISLAND"
1590 P=P+T0
1600 IF P<W THEN 2480
1610 T0=0
1620 IF L=2000 THEN 1680
1630 LET T0=INT((S1/100000)*L3)
1640 IF T0<=L3 THEN 1660
1650 T0=L3
1660 IF T0=0 THEN 1680
1670 PRINT "OF";L3;" SQ. MILES PLANTED, ";
1680 PRINT "YOU HARVESTED";L3-T0;" SQ. MILES OF CROPS.";
1690 IF T0=0 THEN 1760
1700 IF X2>=2 THEN 1760
1710 PRINT " (DUE TO"
1720 PRINT " POLLUTION)";
1750 X2=X2+1
1760 T1=INT((42+RND(0)*20)*(1+.25*(E0+E1)/20))
1770 PRINT " MAKING";INT(T1*(L3-T0));" RALLODS"
1780 M=M+INT(T1*(L3-T0))
1790 E0=E1
1800 IF E2<=10 THEN 1820
1810 E2=10
1820 E1=E2
1830 T0=2000-L
1840 IF T0<2 THEN 2100
1850 IF T0<=26 THEN 1870
1860 T0=26
1870 T0=INT(T0*500*(.52+.5*RND(0)))
1880 T1=S1/100000
1890 IF T1<=1 THEN 1910
1900 T1=1
1910 T1=T1*T0
1920 PRINT "YOU MADE";INT(T0-T1);" RALLODS FROM TOURIST TRADE"
1930 M=M+INT(T0-T1)
1940 IF INT(T0-T1)<=M5 THEN 2080
1950 IF S1<=S9 THEN 2080
1960 PRINT " DECREASE BECAUSE ";
1970 T2=INT(RND(0)*5+1)
1980 IF T2=1 THEN PRINT " WATER POLLUTION KILLING FISH"
1990 IF T2=2 THEN PRINT "AIR POLLUTION KILLING GAME BIRDS"
2000 IF T2=3 THEN PRINT "WATER POLLUTION RUINING MINERAL BATHS"
2010 IF T2=4 THEN PRINT "SMOG DISCOURAGING SUN BATHERS"
2020 IF T2=5 THEN PRINT "SMOG MAKING HOTEL ROW LOOK SHABBY"
2080 M5=INT(T0-T1)
2090 S9=S1
2100 S2=(2000-L)*(2000-L)-M3/.44
2110 PRINT "YOU RECEIVED";X9;" RALLODS FROM TAXES ON INDUSTRY"
2115 M=M+X9
2120 IF S2>=0 THEN 2170
2130 S1=INT(S1+S2/2)
2140 IF S1<0 THEN LET S1=0
2160 GOTO 2190
2170 S1=INT(S1+S2)
2190 N5=N5-1
2200 IF N5>0 THEN 450
2210 GOTO 2570
2220 PRINT
2230 PRINT
2240 RETURN
2250 PRINT "ONLY GOT";M;" RALLODS LEFT !"
2260 RETURN
2270 PRINT "YOU HAVE BEEN THROWN OUT OF OFFICE AND ARE NOW IN PRISON"
2280 STOP
2300 PRINT D0;" COUNTRYMEN DIED IN ONE YEAR !!!!"
2310 PRINT "DUE TO THIS EXTREME MISMANAGEMENT YOU HAVE NOT ONLY"
2320 PRINT "BEEN IMPEACHED AND THROWN OUT OF OFFICE BUT YOU"
2330 T0=INT(RND(0)*2.01)+1
2340 IF T0=1 THEN PRINT "ALSO HAD YOUR LEFT EYE GOUGED OUT"
2350 IF T0=2 THEN PRINT "HAVE GAINED A VERY BAD REPUTATION"
2360 IF T0=3 THEN PRINT "HAVE BEEN ELECTED NATIONAL FINK"
2370 STOP
2410 PRINT "OVER ONE THIRD OF THE POPULATION HAS DIED SINCE YOU"
2420 PRINT "WERE ELECTED. THOSE REMAINING HATE YOUR GUTS!!!"
2430 IF RND(0)<=0.5 THEN 2270
2440 PRINT "YOU HAVE JUST BEEN ASSASINATED !!!"
2450 STOP
2480 PRINT "THE NUMBER OF FOREIGN WORKERS HAS EXCEEDED THE NUMBER"
2490 PRINT "OF COUNTRYMEN. THEY HAVE TAKEN OVER THE COUNTRY"
2500 GOTO 2430
2520 PRINT "MANY COUNTRYMEN DIED OF STARVATION WHILE MUCH MONEY"
2530 PRINT "REMAINED IN YOUR TREASURY. THE PUBLIC IS ENRAGED AND"
2540 PRINT "YOU MUST RESIGN OR YOU WILL BE ASSASINATED"
2550 STOP
2570 PRINT
2580 PRINT "CONGRATULATIONS !! YOU HAVE SUCCESSFULLY COMPLETED"
2590 PRINT N4;" YEARS OF OFFICE"
2600 STOP