1  REM BASIC DOCUMENTATION PROGRAM "BASDOC.BAS"
2  REM 15-OCT-76 - LARRY SIMPSON
3  REM READS FROM SOURCE FILES BASIC0-BASIC3(.MAC)
4  REM AND MAKES RUNOFF FILE BASIC.RNO
10 DIM L$[80]V,L1$[80]V,C2$[6]V,S$[40]V(5)
20 DIM N$[40]V(5),M$[40]V
30 C2$=".WC 84"
40 M$="----------------------------------------"
200 DATA ^^INTRODUCTION\\
210 DATA ^^TEXT + FILE MANIPULATION\\
220 DATA ^^PROGRAM STATEMENTS\\
230 DATA ^^SYSTEM FUNCTIONS\\
240 DATA ^^SUBROUTINE CALLS\\
300 FOR I=1 TO 5
310 N$(I)="BASIC"+STR$(I-1)+".RNO"
320 OPEN #3,N$(I)+"/WR"
330 READ S$(I) : S$(I)=LTR$(S$(I))
340 PRINT #3,".ST      ";S$(I)
350 PRINT #3,".PG"
360 PRINT #3,C2$ : PRINT #3,S$(I)
370 PRINT #3,C2$ : PRINT #3,SBS$(M$,1,LEN(S$(I))-4)
380 PRINT #3,".SL 2"
390 CLOSE 3
400 N$(I)=N$(I)+"/AP"
410 NEXT I
420 F=0
500 FOR I2=1 TO 5
510 N$="BASIC"+STR$(I2-1)+".MAC/RO/EN:600"
520 OPEN #4,N$
530 INPUT LINE #4,L$
540 IF SBS$(L$,1,2) <> ";+" THEN 530
550 GOSUB 700
560 GOTO 530
600 CLOSE 4
605 PRINT "END FILE";I2-1
610 NEXT I2
620 GOTO 1000
700 F1=VAL(SBS$(L$,2))
710 IF F1=F THEN 750
720 CLOSE 3
730 F=F1
740 OPEN #3,N$(F)
750 INPUT LINE #4,L$
760 IF SBS$(L$,1,1) <> ";" THEN 750
770 IF SBS$(L$,2,1) = "-" THEN RETURN
790 PRINT #3,LTR$(SBS$(L$,2))
800 GOTO 750
1000 CLOSE 3
1010 OPEN #3,"BASIC.RNO/WR"
1020 PRINT #3,".PS 60,80" : PRINT #3,".LS 1"
1030 PRINT #3,".LM 10" : PRINT #3,".TS 15"
1040 PRINT #3,".TITLE      ^^BASIC DOCUMENTATION\\"
1045 PRINT #3,".FG 18"
1050 L$=DAT$(0)
1055 PRINT #3,".DT ";L$
1060 PRINT #3,C2$
1070 PRINT #3,"^^BASIC DOCUMENTATION\\"
1080 PRINT #3,C2$
1090 PRINT #3,L$
1100 FOR I=1 TO 5
1110 OPEN #4,SEG$(N$(I),1,LEN(N$(I))-3)+"/RO/EN:1200"
1120 INPUT LINE #4,L$
1130 PRINT #3,L$
1140 GOTO 1120
1200 CLOSE 4
1210 NEXT I
1220 PRINT #3,".ST      ^^INDEX\\"
1230 PRINT #3,".PG"
1240 PRINT #3,C2$
1250 PRINT #3,"^INDEX"
1260 PRINT #3,C2$
1270 PRINT #3,SBS$(M$,1,5)
1280 PRINT #3,".PX"
1290 CLOSE 3
1300 STOP