.TITLE	VUEXIT - PROGRAM EXIT FOR VUE			;RBD-VUE

	.IDENT	/V2.0/						;RBD-VUE

;
; COPYRIGHT (C) 1976 BY DIGITAL EQUIPMENT CORPORATION,
; MAYNARD, MASSACHUSETTS
;
; THIS SOFTWARE IS FURNISHED UNDER A LICENSE FOR USE ONLY ON A
; SINGLE  COMPUTER  SYSTEM AND MAY BE COPIED ONLY WITH THE IN-
; CLUSION OF THE ABOVE COPYRIGHT NOTICE.   THIS  SOFTWARE,  OR
; ANY  OTHER  COPIES THEREOF, MAY NOT BE PROVIDED OR OTHERWISE
; MADE AVAILABLE TO ANY OTHER PERSON EXCEPT FOR  USE  ON  SUCH
; SYSTEM  AND TO ONE WHO AGREES TO THESE LICENSE TERMS.  TITLE
; TO AND OWNERSHIP OF THE SOFTWARE SHALL AT ALL  TIMES  REMAIN
; IN DIGITAL.
;
; THE INFORMATION IN THIS SOFTWARE IS SUBJECT TO CHANGE  WITH-
; OUT  NOTICE  AND  SHOULD NOT BE CONSTRUED AS A COMMITMENT BY
; DIGITAL EQUIPMENT CORPORATION.
;
; DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY  FOR
; THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT WHICH IS
; NOT SUPPLIED BY DIGITAL.
;
; ANDREW C. GOLDSTEIN  27-SEP-77  20:24
;
;-----------------------------------------------------------------------------
;			     *** VUEXIT.MAC ***
;
; THS MODULE IS A MODIFIED VERSION OF "EXIT X0207", FURNISHED WITH TECO FOR
; RSX-11M. 
;
; THE USER'S SCREEN IS CLEARED WHEN VUE EXITS BACK TO THE MONITOR.
;
; ALSO, I REMOVED THE DUMMY 'WATCH' ROUTINE, SO TKB WILL BOMB OUT IF THE
; SPECIAL VUE "SCREEN" MODULE IS NOT PRESENT IN THE INPUT FILES
; SPECIFICATION.
;
	.ENABL	LC
;
;	The modifications to this TECO/RSX-11M I/O module were
;	made by:
;
;		Bob Denny
;		Gould, Inc.  NavCom Systems Division
;		4323 N. Arden Drive.
;		El Monte, Ca.  91731
;		(213) 442-0123 Ext. 587
;
;	If you have any questions about the mods, or find (and maybe fix)
;	a problem, feel free to contact me.
;
;-------------------------------------------------------------------------


	.MCALL	EXIT$S,DIR$


EX$ERR	= 2			; EXIT WITH ERROR STATUS
EX$SUC	= 1			; EXIT WITH SUCCESS STATUS

.SBTTL	EXIT ROUTINES

;+
;
; *** - EXERR	EXIT WITH ERROR STATUS
;
; THIS ENTRY IS CALLED BY TECO WHEN IT IS EXITING DUE TO AN ERROR AND
; THE EXIT-ON-ERROR BIT IN ETYPE IS SET.
;
; *** - GEXIT	EXIT AND GO
;
; *** - TEXIT	EXIT
;
; THESE TWO ENTRIES ARE CALLED BY TECO TO EXIT. "TEXIT" SIMPLY EXITS
; TO THE MONITOR; "GEXIT" IS AN EXIT AND GO. SINCE ITS FUNCTION IS
; NOT CLEARLY DEFINED IN RSX-11, IT ALSO JUST EXITS TO THE MONITOR.
;
; NO INPUTS, NO OUTPUTS, NO RETURN.
;
;-

	.PSECT	CODE,RO
	.ENABL	LSB

EXERR::
	MOV	#EX$ERR,-(SP)	; SET FOR EXIT WITH ERROR STATUS
	BR	10$

GEXIT::

TEXIT::
	MOV	#EX$SUC,-(SP)	; SET FOR EXIT WITH SUCCESS STATUS
10$:	TST	OUTFDB+F.BDB	; SEE IF THERE IS AN OUTPUT FILE OPEN
	BEQ	20$		; BRANCH IF NOT
	CALL	KILFIL		; IF SO, DELETE IT
20$:	CALL	CLOSIF		; CLOSE THE INPUT FILE IF NECESSARY
	CALL	INDCLS		; CLOSE THE INDIRECT FILE IF OPEN
	CALL	TDRDEL		; DELETE TEMP DIRECTORY, IF ANY
	BIS	#ET.IMG,ETYPE(R5) ;SET THE IMAGE OUTPUT BIT		;RBD
	MOV	#CLRSTR,R3	;R3 ==> SCREEN CLEAR STRING		;RBD
	MOV	#CLSLEN,R4	;R4 = # BYTES IN STRING			;RBD
	CALL	PRINT		;SEND IT TO THE TERMINAL		;RBD
	BIC	#ET.IMG,ETYPE(R5) ;SAFETY !!				;RBD
	CALL	TTDET		; DETACH THE TERMINAL
	MOV	#<2*256.>+29.,-(SP) ; EXIT WITH STATUS DIC
	DIR$			; TRY EXIT WITH STATUS
	EXIT$S			; ELSE DO NORMAL EXIT

CLRSTR:	.BYTE	33,'H,33,'J	;VT52 CLEAR SCREEN SEQUENCE		;RBD
CLSLEN = .-CLRSTR		;...AND IT'S LENGTH			;RBD
	.EVEN								;RBD

	.DSABL	LSB

.SBTTL	NO CONTROL/O

;+
;
; *** - NOCTLO	NO CONTROL/O
;
; THIS ROUTINE DISABLES THE AFFECT OF A PREVIOUSLY TYPED CONTROL O.
;
; INPUTS:	NONE
;
; OUTPUTS:	NONE
;
; ALL REGISTERS ARE PRESERVED
;
;-

	.PSECT	CODE,RO

NOCTLO::
	BIT	#ET.DET,ETYPE(R5) ; IF RUNNING DETACHED
	BNE	10$		; CTRL O IS UP TO THE TERMINAL DRIVER
	CALL	TTDET		; DETACH THE TERMINAL
	CALL	TTATT		; AND REATTACH IT
10$:	RETURN



	.END