SUBROUTINE DALUPD
C
C
C  COMPONENT:	DALUPD -- UPDATE VOLUME ALLOCATION ENTRY(S)
C
C  DATE:	27-NOV-79
C
C  AUTHOR:	GR JOHNSON
C		BATTELLE NORTHWEST
C		P O BOX 999
C		RICHLAND WA 99352
C
C  SOURCE:	FORTRAN IV-PLUS
C
C  DESCRIPTION:
C
C	ROUTINE "DALUPD" UPDATES ENTRIES IN THE VOLUME ALLOCATION FILE.
C
C	THE VOLUME TO BE UPDATED IS SPECIFIED BY INITIALIZING VARIABLES
C  "VAFDEV" AND "VAFUNT" IN THE COMMON BLOCK "VAFILE".  A SPECIFIC USER
C  DIRECTORY MAY BE SPECIFIED BY INITIALIZING THE VARIABLE "VAFUIC".
C  IF THE USER DIRECTORY ARGUMENT IS NOT INITIALIZED, ALLOCATION LIMITS
C  WILL BE UPDATED FOR ALL ENTRIES IN THE VOLUME ALLOCATION FILE.
C
C	THE VOLUME DEFAULT ALLOCATION LIMIT MAY BE UPDATED (CREATED) BY
C  INITIATING THE ROUTINE VIA THE "DALDUP" ENTRY POINT.
C
C	THE ALLOCATION LIMIT IS SPECIFIED BY INITIALIZING VARIABLE "VAFLIM"
C  IN THE COMMON BLOCK "VAFILE".  A NEGATIVE VALUE FOR VAFLIM INDICATES
C  THE UFD IS TO MAINTAIN "UNLIMITED" STORAGE.  A ZERO VALUE INDICATES
C  THE VOLUME DEFAULT IS TO BE ENTERED.
C
C

C	G L O B A L   P A R A M E T E R S   A N D   V A R I A B L E S
C
C
C
	INCLUDE 'VAFILE.COM/NOLIST'	! VOLUME ALLOCATION FILE
C
C

C	L O C A L   P A R A M E T E R S   A N D   V A R I A B L E S
C
C
C
	PARAMETER	VAFLUN = 1	! VAFILE LUN
	PARAMETER	TTYLUN = 5	! TERMINAL I/O LUN
C
	LOGICAL	  ALL			! UPDATE ALL UFD'S
	LOGICAL	  DEF			! UPDATE VOLUME DEFAULT
C
	INTEGER	  DALUIC		! SPECIFIED USER DIRECTORY
	INTEGER*4 DALLIM		! SPECIFIED ALLOCATION LIMIT
C
C

C	P R E L I M I N A R Y
C
C
C
C  SET "ALL" FLAG IF SPECIFIC UFD NOT REQUESTED
C
 10	DALUIC=VAFUIC
	ALL=DALUIC.EQ.0
C
C
C
C  "UPDATE DEFAULT" ENTRY POINT -- SET FLAG
C
	DEF=.FALSE.
	GO TO 1002
C
C
	ENTRY DALDUP
	DEF=.TRUE.
C
C
C
C  INITIALIZE DEFAULT VAF ENTRY
C
	VAFFAR=2
	VAFLAR=2
	DEFLIM=VAFLIM
	IF(DEFLIM.EQ.0) DEFLIM=1000	! DEFAULT DEFLIM
C
C
C
C  INITIALIZE LOCAL UFD LIMIT BUFFER
C
 1002	DALLIM=VAFLIM
C
C

C	U P D A T E   V O L U M E   A L L O C A T I O N   E N T R Y ( S )
C
C
C
C  ASSIGN LOGICAL UNIT
C
 20	CALL ASNLUN(VAFLUN,VAFDEV,VAFUNT)
C
C
C
C  OPEN VOLUME ALLOCATION FILE
C
	CALL NOLOCK(VAFLUN)
C
 2002	OPEN(UNIT=VAFLUN,NAME=VAFFIL,TYPE='OLD',ACCESS='DIRECT',
	2    RECORDSIZE=2,EXTENDSIZE=2,ERR=2004)
	READ(VAFLUN'1,ERR=90200) VAFDEF
	GO TO 2006
C
 2004	CALL ERRSNS(ISW,IFCS)
	IF(ISW.EQ.29) GO TO 90000
	IF(ISW.NE.30) GO TO 90100
	IF(IFCS.NE.-27.AND.IFCS.NE.-29) GO TO 90100
	CALL WAIT(1,2,ISW)
	GO TO 2002
C
C
C
C  UPDATE VOLUME DEFAULT AND RETURN (IF REQUESTED)
C
 2006	IF(.NOT.DEF) GO TO 2008
C
	DEFLIM=DALLIM
C
	WRITE(VAFLUN'1,ERR=90300) VAFDEF
C
	GO TO 2014
C
C
C
C  SCAN AND UPDATE VOLUME ALLOCATION FILE
C
 2008	IF(DALLIM.EQ.0) DALLIM=DEFLIM
C
	DO 2010 VAFPNT=VAFFAR,VAFLAR
	READ(VAFLUN'VAFPNT,ERR=90200) VAFREC
C
	IF((.NOT.ALL).AND.(VAFUIC.NE.DALUIC)) GO TO 2010
C
	VAFLIM=DALLIM
	WRITE(VAFLUN'VAFPNT,ERR=90300) VAFREC
C
	IF(.NOT.ALL) GO TO 2014
C
 2010	CONTINUE
C
	IF(ALL) GO TO 2014
C
C
C
C  OUTPUT WARNING MESSAGE -- (SPECIFIED VAF ENTRY NOT FOUND)
C
	WRITE(TTYLUN,2012)
 2012	FORMAT(' VAF entry not found')
C
C
C
C  CLOSE VOLUME ALLOCATION FILE AND RETURN TO CALLER
C
 2014	CLOSE(UNIT=VAFLUN)
C
	RETURN
C
C

C	P R O C E S S   F A T A L   E R R O R S
C
C
C
90000	WRITE(TTYLUN,90001)
90001	FORMAT(' Volume not initialized for directory allocation'/)
	CALL EXIT
C
90100	WRITE(TTYLUN,90101)
90101	FORMAT(' DAL -- VAF open error'/)
	CALL EXIT
C
90200	WRITE(TTYLUN,90201)
90201	FORMAT(' DAL -- VAF read error'/)
	CALL EXIT
C
90300	WRITE(TTYLUN,90301)
90301	FORMAT(' DAL -- VAF write error'/)
	CALL EXIT
C
C
	END