.TITLE	MUNDEF
	.IDENT	/V04N/
	.PSECT	MUNDEF
;
	.MCALL	RAD50C,DEFMSG,DH0DVO,DH0CMO
	DEFMSG
	DH0DVO
	DH0CMO
MS.NUL=27
P$TN=4
P$UIC=10
P$ADMD=3
P$TA0=12
	.MACRO	PRINT,A
	MOV	#A,(R5)+
	.ENDM
	.MACRO	RCLAB,R
	.WORD	RCL'R'
	.ENDM
	.MACRO	RGLAB,R
	.WORD	RGL'R'
	.ENDM
	.MACRO	RCDEF,R
	.NCHR	RC,R
RCL'R':
	.IIF EQ	RC-3	.ASCIZ	;'R'/;<11>
	.IIF EQ	RC-2	.ASCIZ	;0'R'/;<11>
	.IIF EQ	RC-1	.ASCIZ	;00'R'/;<11>
	.ENDM
	.MACRO	RGDEF,R
RGL'R':	.ASCIZ	/REG'R'/
	.ENDM
;
ADAPTO::
COMM::
;
UTYPE::	BR	UNTYPE
UENTRY::BR	UEP
USEQ::	BR	USP
;
UEP:	JMP	UNTRY
USP:	JMP	UNSEQ
;
UNTYPE:	INC	NMUDET
	MOVB	IBUF+A$DCDT,UDC	;DEVICE CLASS
	MOVB	IBUF+A$DTYP,UDT	;DEVICE TYPE
	PRINT	USDL
	PRINT	TLOG		;"LOGGED
	MOV	$CONFG,R0
	BEQ	10$
	MOVB	A$SYUN+1(R4),TPROC1
	MOV	R0,TCONF1
	PRINT	TPROC
10$:	PRINT	TCRLF
	PRINT	TSTAR		;"***...
	PRINT	TIDENT
	MOVB	IBUF+A$SYUN,TLNAM2	;LOGICAL UNIT NUMBER
	PRINT	TLNAME
	MOV	#IBUF,R2
	MOVB	A$UNTN(R2),TNAM2	;PHYSICAL UNIT NUMBER
	MOVB	TNAM2,TNAM2A
	MOVB	A$CNTN(R2),R1		;CONTROLLER INDEX
	ASR	R1
	CLR	A$CNTN(R2)		;CLEAR INDEX
	PRINT	TNAME
	TSTB	44(R2)
	BEQ	11$
	PRINT	TNAMS1
11$:	MOVB	R1,ACONTL		;CONTROLLER NUMBER
	BITB	#100,ACONTL
	BNE	12$
	BISB	#60,ACONTL
12$:	PRINT	TNAMC
	TSTB	44(R2)
	BEQ	13$
	PRINT	TNAMS2
13$:	PRINT	TNAMND
	PRINT	TSOFTS
	MOV	IBUF+A$PGF,R2		;OFFSET TO PROG FIELD
	CALL	$GETFL
	BCC	14$
	JMP	16$
14$:	MOV	P$TN(R2),RTNM1	;TASK NAME
	MOV	P$TN+2(R2),RTNM1+2
	PRINT	TTNAM
	MOVB	P$UIC(R2),TUIC2	;UIC
	MOVB	P$UIC+1,TUIC1
	PRINT	TTUIC
	TSTB	P$ADMD(R2)	;ADDRESS MODE
	BNE	15$
	MOV	P$TA0(R2),TPSU1	;REAL BASE ADDRESS
	PRINT	TPSU
	BR	16$
15$:	MOV	P$TA0(R2),TPSM1	;MAPPED ADDRESS
	PRINT	TPSM
16$:	MOV	#8.,R0		;IOFUN + PARAMETERS
	ADD	#14,R2
	MOV	#PARML,R1
	MOV	#12,R3
17$:	MOV	R1,(R5)+
	ADD	R3,R1
	MOV	(R2)+,(R1)
	ADD	#4,R1
	DEC	R0
	BNE	17$
	PRINT	DRL
	MOV	IBUF+A$DRF,R2	;START OF DEVICE REGISTER FIELD
	BEQ	30$		;IF EQ, NO FIELD
	ADD	R4,R2
	CALL	$CKOFF
	BCS	30$
	MOV	(R2)+,R0	;SIZE OF REGISTER FIELD
	SUB	#4,R0		;REMOVE SIZE AND RESERVED WORD
	ASR	R0
	BEQ	30$
	TST	(R2)+		;SKIP RESERVED WORD
	MOV	#REGL,R1
	MOV	#12,R3
20$:	MOV	R1,(R5)+
	ADD	R3,R1
	MOV	(R2)+,(R1)	;REGISTER CONTENTS
	ADD	#4,R1
	CMP	R1,#REGLE	;HAVE WE DONE 26 REGISTERS
	BCC	40$
	DEC	R0		;ARE THERE MORE TO DO
	BNE	20$
	BR	40$
30$:	PRINT	NRFL		;NO REGISTERS FOUND
40$:	BR	END
;
UNTRY:	INC	NMUDET
	MOVB	IBUF+A$ENTY,UNT	;ENTRY TYPE
	MOVB	IBUF+A$FMT,UFT	;FORMAT TYPE
	PRINT	UNTL
	MOV	#UNRDL,R2	;DUMP THE RECORD
	MOV	#20,R3
10$:	MOV	#4,R1
20$:	ADD	#6,R2
	MOV	(R4)+,(R2)
	DEC	R1
	BNE	20$
	ADD	#4,R2
	DEC	R3
	BNE	10$
	PRINT	UNRDL
	BR	END
;
UNSEQ:	MOV	IBUF+A$SEQN,R1	;ERROR SEQUENCE NUMBER
	MOV	UESNUM,R0	;LAST ERROR NUMBER
	SUB	R0,R1		;NUMBER MISSING ENTRIES
	MOV	R1,NFE
	MOV	#OUTLST,R5
	PRINT	TBLNK
	PRINT	TENTRY		;"ENTRIES...
	PRINT	NFEL
	PRINT	TSTAR		;"***...
;
END:	BIT	#10000,FLAG
	BNE	10$
	CLR	(R5)
	CALL	OUTPUT
10$:	RETURN
;
UNRDL:
RCL=0
	.REPT	32.
	MS.ASC
	RCLAB	\RCL
	.REPT	3
	MS.OCZ,	0
	MS.TAB
	.ENDR
	MS.OCZ,	0
	MS.NUL
RCL=RCL+10
	.ENDR
	MS.EOL
;
UNTL:	MS.R50,	MUSET
	MS.TAB
	MS.OCT
UNT:	0
	MS.NUL
	MS.R50,	MUSF
	MS.TAB
	MS.OCT
UFT:	0
	MS.NUL
	MS.ASC,	ASTARS
.BYTE	MS.NUL,	2
	MS.R50,	MDUSR
	MS.NUL
	MS.EOL
;
USDL:	MS.R50,	MUDC
	MS.OCT
UDC:	0
	MS.NUL
	MS.R50,	MUDT
	MS.OCT
UDT:	0
	MS.EOL
;
DRL:
.BYTE	MS.NUL,	2
	MS.R50,	MUDR
	MS.EOL
;
NRFL:	MS.NUL
	MS.TAB
	MS.R50,	MNRF
	MS.EOL
;
REGL:
	.RADIX	10
REG=1
	.REPT	26.
	MS.TAB
	MS.ASC
	RGLAB	\REG
	MS.TAB
	MS.OCZ,	0
	MS.EOL
REG=REG+1
	.ENDR
	.RADIX
REGLE=.
;
PARML:
	.IRP	X,<MF,M1,M2,M3,M4,M5,M6,M7>
	MS.TAB
	MS.R50,	X
	MS.TAB
	MS.OCZ,	0
	MS.EOL
	.ENDM
;
NFEL:	MS.DEC
NFE:	0
	MS.R50,	MERF
	MS.EOL
;
RCL=0
	.REPT	32.
	RCDEF	\RCL
RCL=RCL+10
	.ENDR
	.RADIX	10
RGL=1
	.REPT	26.
	RGDEF	\RGL
RGL=RGL+1
	.ENDR
	.RADIX
	.EVEN
	RAD50C	MUSET,<UNSUPPORTED ENTRY TYPE>
	RAD50C	MUSF,<UNSUPPORTED FORMAT>
	RAD50C	MDUSR,<DUMP OF UNSUPPORTED ERROR RECORD>
	RAD50C	MUDC,<UNSUPPORTED DEVICE CLASS >
	RAD50C	MUDR,<DEVICE REGISTERS AT ERROR TIME>
	RAD50C	MNRF,<NO DEVICE REGISTER FIELD FOUND>
	RAD50C	MUDT,<UNSUPPORTED DEVICE TYPE  >
	RAD50C	MERF,< ERRORS FAILED TO BE LOGGED>
	RAD50C	MF,<IO FUNCTION>
	RAD50C	M1,<PARAMETER 1>
	RAD50C	M2,<PARAMETER 2>
	RAD50C	M3,<PARAMETER 3>
	RAD50C	M4,<PARAMETER 4>
	RAD50C	M5,<PARAMETER 5>
	RAD50C	M6,<PARAMETER 6>
	RAD50C	M7,<PARAMETER 7>
	.END