.PSECT	FN2FNB
	.TITLE	FN2FNB - INPFDB FNB SAVE AND RESTORE
	.IDENT	/781117/
;
;    THIS CODE HAS BEEN DEVELOPED BY THE COMPUTING
;    GROUP OF THE ATMOSPHERIC SCIENCES DIVISION,
;    ALBERTA RESEARCH. THIS WORK FUNDED BY THE
;    ALBERTA WEATHER MODIFICATION BOARD.
;
;    THERE IS EXPLICITLY NO COPYRIGHT ON THIS SOFTWARE,
;    AND ITS DISTRIBUTION IS ENCOURAGED. NO RESPONSIBILITY
;    NOR GUARANTEE IS MADE OR ASSUMED BY THE AUTHOR, OR
;    BY ALBERTA RESEARCH.
;
;    SUGGESTIONS OR CHANGES ARE INVITED, AND WILL BE
;    DISTRIBUTED TO OTHER USERS OF THIS SOFTWARE THROUGH
;    THE DECUS IAS/RSX SPECIAL INTEREST GROUP.
;
;
; VERSION:	781020
; WRITTEN BY:	W. KORENDYK
; DATE WRITTEN:	2-NOV-78
; 
;	
;
; MODIFICATIONS:
;
; CODE		NAME		DATE
;

;+
;
; *** - FDB2FN -- SAVE FILE NAME BLOCK OF INPFDB
; *** - FN2FDB -- MOVE SAVED FILE NAME BLOCK TO INPFDB
;
; SAVE AND RESTORE OF THE FILE NAME BLOCK OF THE INPU
; FILE FDB.
;
;-
	.DSABL	GBL
	.MCALL	ENTER,LEAVE
	.MCALL	MAIGBL
	.MCALL	FCSMC$,FDOF$L
	MAIGBL
	FCSMC$
	FDOF$L
;
; WHERE THE  FNB IS SAVED
;
INPFNB:	.BLKW	S.FNBW

;
; SAVE THE FILE NAME BLOCK
FDB2FN:	ENTER	R0,R1,R2	;WORK REGISTERS
	MOV	#S.FNBW,R2	; THE SIZE OF THE FNB
	MOV	#INPFNB,R1	; WHERE TO SAVE IT
	MOV	#INPFDB+F.FNB,R0; AND WHERE IT STARTS
1$:	MOV	(R0)+,(R1)+	; MOVE IT OVER
	SOB	R2,1$		;
	LEAVE			;LEAVE, AND
	RETURN			;RETURN
;
; AND THE OTHER WAY ROUND
FN2FDB:	ENTER	R0,R1,R2	;WORK REGISTERS
	MOV	#INPFNB,R0	; WHERE IT IS SAVED
	MOV	#INPFDB+F.FNB,R1; WHERE IT MUST GO
	MOV	(R0)+,(R1)+	; MOVE IN THE FIRST WORD
	BEQ	2$		; IF EQ, DON'T BOTHER WITH THE REST
	MOV	#S.FNBW-1,R2	; NUMBER OF WORDS REMAINING
1$:	MOV	(R0)+,(R1)+	; MOVE THEM IN
	SOB	R2,1$		;
2$:	LEAVE			;
	RETURN			;
	.END