.;		O P T . C M D
.;
.; OPT.CMD WILL PRODUCE A TKB OPTION COMMAND FILE.  A GENERAL FORMAT
.; FOR A TKB COMMAND FILE IS       COMMAND-LINE
.;				   /
.;				   @OPTION.CMD
.;				   //
.; OPT.CMD WILL PRODUCE THE @OPTION.CMD COMMAND FILE.
.;
.; COMMAND FORMAT:
.;		  @OPT  FILENAME OPT1 OPT2 OPT3 OPT4 OPT5 OPT6 OPT7 OPT8
.;   WHERE:
.;	   FILENAME = 1-9 CHARACTER FILENAME WITH NO EXTENSIONS
.;	   OPT1...OPT8 = EACH OPTION(SEPERATED BY SPACES FROM THE OTHERS)
.;	   		 REPRESENTS A SINGLE TKB OPTION.
.;			 EG   OPT1=LIBR=F4PRES/RO
.;			      OPT2=PRI=55
.;			   ETC.
.;   EXAMPLE:
.;	@OPT.CMD FOO LIBR=F4PRES/RO PRI=55 ASG=TI:1:2 ASG=SY:3:4 UIC=[200,200]
.;    WILL PRODUCE A COMMAND FILE:	FOO.OPT;1
.;    OF THE FORM		LIBR=F4PRES/RO
.;				PRI=55
.;				ASG=TI:1:2
.;				ASG=SY:3:4
.;				UIC=[200,200]
.;
	.ENABLE SUBSTITUTION
	.TEST COMMAN
	.IF <STRLEN> GT 79. 	.GOTO TOLONG
	.IF P1 EQ "" 		.GOTO NOFILE
	.OPEN 'P1'.OPT
	.IF P2 NE "" .DATA 'P2'
	.IF P3 NE "" .DATA 'P3'
	.IF P4 NE "" .DATA 'P4'
	.IF P5 NE "" .DATA 'P5'
	.IF P6 NE "" .DATA 'P6'
	.IF P7 NE "" .DATA 'P7'
	.IF P8 NE "" .DATA 'P8'
	.IF P9 NE "" .DATA 'P9'
	.CLOSE
	.EXIT 1
.TOLONG:.DISABLE QUIET
	; ERROR(OPT.CMD) -- TOTAL COMAND LENGTH TOO LONG
	.STOP 4
.NOFILE:.DISABLE QUIET
	; ERROR(OPT.CMD) -- FILE NAME MISSING
	.STOP 4