.TITLE  VSUB  SUBTRACTION OF TWO VECTORS 
	.IDENT  /1.0/					;  08/15/79
;+							++EXTSPC>>
;.NAME VSUB
;.INDEX V3SUB
;.INDEX VSUBD
;.INDEX V3SUBD
;.TITLE  SUBROUTINE VSUB 
;
;		CALL VSUB   (C,A,B,N)
;
;		CALL V3SUB  (C,A,B)
;
;		CALL VSUBD  (C,A,B,N)
;
;		CALL V3SUBD (C,A,B)
;
; VERSION:  VECTOR / MATRIX ROUTINES     SAM MILLER     REL 1.0  
;
; FUNCTION:
;
;	VECTOR SUBTRACTION 
;
;	C = A - B
;
;
; LANGUAGE:  MACRO-11
;
;
; ARGUMENTS:
;
;       C   = OUTPUT VECTOR
;       A,B = INPUT VECTORS
;       N   = VECTOR DIMENSION
;
;
; COMMONS:
;
;	(NONE)
;
;
; GENERAL DESCRIPTION:
;
;	ALL REAL ARGUMENTS EXCEPT INTEGER N.
;
;
;       SINGLE PRECISION -      VSUB    FOR N-VECTORS
;                               V3SUB   FOR 3-VECTORS
;
;       DOUBLE PRECISION -      VSUBD   FOR N-VECTORS
;                               V3SUBD  FOR 3-VECTORS
;
;
;
; PERIPHERAL INPUT/OUTPUT:
;
;	(NONE)
;
;
; LOGICAL UNIT USAGE:
;
;	(NONE)
;
;
; EXTERNAL ROUTINES CALLED:
;
;	NAM$
;	$BOMB
;
;-							--EXTSPC>>
;
; WRITTEN BY:
;
;       DENIS MAHONY AND SAM MILLER     08/15/79
;
;
; MODIFIED BY:
;
;	**********	**DATE**
;		**DETAIL**
;
;-							--EXTSPC>>
	.PAGE
	.GLOBL  VSUB, V3SUB
	.ENABL	LSB
;
F0=R0				;DEFINE FLOATING REGISTER 0
F1=R1				;DEFINE FLOATING REGISTER 1
V3SUB:	CMP	#3,(R5)+	;CHECK NUMBER OF ARGUMENTS
	BNE	BOMB3		;BOMB IF # OF ARGS. NE 3
	MOVB	#3,R2		;R2=VECTOR SIZE=3
	BR	10$
VSUB:	CMP	#4,(R5)+	;CHECK NUMBER OF ARGUMENTS
	BNE	BOMB		;BOMB IF # OF ARGS. NE 4
	MOVB 	@6(R5),R2	;R2=VECTOR SIZE=N
10$:	MOV	(R5)+,R3	;R3=ADDRESS OF C
	MOV	(R5)+,R4	;R4=ADDRESS OF A
	MOV	(R5),R5		;R5=ADDRESS OF B
	SETF			;SET FLOATING MODE
;		LOOP TO SUB VECTORS
20$:	LDF	(R4)+,F1	;GET A(I)
	SUBF	(R5)+,F1	;A(I) - B(I)
	STF	F1,(R3)+	;PUT DIF IN C(I)
	SOB	R2,20$		;DONE?
	RTS	PC		;RETURN
BOMB3:	MOV	#101620,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#107273,R4	;MOVE 1ST HALF OF NAME TO R4
	BR	30$
BOMB:	MOV	#6200,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#106215,R4	;MOVE 1ST HALF OF NAME TO R4
30$:	JSR	R4,NAM$		;SUBR TO PUT NAME IN WALKBACK
	JMP	$BOMB		;ABORT, $BOMB DOES NOT EXIST
	.END