.TITLE	VADD  SUM OF TWO VECTORS
	.IDENT  /1.0/					;  08/15/79
;+							++EXTSPC>>
;.NAME VADD
;.INDEX V3ADD
;.INDEX VADDD
;.INDEX V3ADDD
;.TITLE  SUBROUTINE VADD 
;
;		CALL VADD   (C,A,B,N)
;
;		CALL V3ADD  (C,A,B)
;
;		CALL VADDD  (C,A,B,N)
;
;		CALL V3ADDD (C,A,B)
;
;
; VERSION:  VECTOR / MATRIX ROUTINES     SAM MILLER     REL 1.0  
;
; FUNCTION:
;
;	VECTOR ADDITION 
;
;	C = A + B
;
;
; LANGUAGE:  MACRO-11
;
;
; ARGUMENTS:
;
;       C   = OUTPUT VECTOR
;       A,B = INPUT VECTORS
;       N   = VECTOR DIMENSION
;
;
; COMMONS:
;
;	(NONE)
;
;
; GENERAL DESCRIPTION:
;
;  ALL REAL ARGUMENTS EXCEPT INTEGER N.
;
;	SINGLE PRECISION -	VADD	FOR N-VECTORS
;				V3ADD	FOR 3-VECTORS
;
;	DOUBLE PRECISION -	VADDD	FOR N-VECTORS
;				V3ADDD	FOR 3-VECTORS
;
;
; PERIPHERAL INPUT/OUTPUT:
;
;	(NONE)
;
;
; LOGICAL UNIT USAGE:
;
;	(NONE)
;
;
; EXTERNAL ROUTINES CALLED:
;
;	NAM$
;	$BOMB
;
;-							--EXTSPC>>
;
; WRITTEN BY:
;
;       DENIS MAHONY AND SAM MILLER     08/15/79
;
;
; MODIFIED BY:
;
;	**********	**DATE**
;
;	****DETAILS****
;
;-							--EXTSPC>>
	.PAGE
	.GLOBL  VADD, V3ADD
	.ENABL	LSB
;
F0=R0				;DEFINE FLOATING REGISTER 0
F1=R1				;DEFINE FLOATING REGISTER 1
V3ADD:
	CMP	#3,(R5)+	;CHECK NUMBER OF ARGUMENTS
	BNE	BOMB3		;BOMB IF # OF ARGS. NE 3
	MOVB	#3,R1		;R1=VECTOR SIZE=3
	BR	10$
VADD:
	CMP	#4,(R5)+	;ARE THERE 4 ARGUMENTS?
	BNE	BOMB		;BOMB IF # OF ARGS. NE 4
	MOVB 	@6(R5),R1	;R1=VECTOR SIZE 
10$:	MOV	(R5)+,R2	;R2=ADDRESS OF C
	MOV	(R5)+,R3	;R3=ADDRESS OF A
	MOV	(R5),R4		;R4=ADDRESS OF B
	SETF			;SET FLOATING DOUBLE MODE
;		LOOP TO ADD VECTORS
20$:	LDF	(R3)+,F1	;GET A(I)
	LDF	(R4)+,F0	;GET B(I)
	ADDF	F0,F1		;A(I) + B(I)
	STF	F1,(R2)+	;PUT SUM IN C(I)
	SOB	R1,20$		;DONE?
	RTS	PC		;RETURN
BOMB3:	MOV	#14640,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#107251,R4	;MOVE 1ST HALF OF NAME TO R4
	BR	30$
BOMB:	MOV	#14400,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#104654,R4	;MOVE 1ST HALF OF NAME TO R4
30$:	JSR	R4,NAM$		;SUBR TO PUT NAME IN WALKBACK
	JMP	$BOMB		;ABORT, $BOMB DOES NOT EXIST
	.END