SUBROUTINE MNTH
C
C PRODUCE REPORT OF USE VS MONTH
C
	INCLUDE	'DAGCOM.FTN'
C
	BYTE	LINE	(48)	!HOLDS LINE OF GRAPH
	REAL	TTUSE	(31)	!TT-HOURS
	REAL	TSKUSE	(31)	!TSK-USE

C
C INITIALIZE
C
	DO 1000,I=1,31
	  TTUSE(I)=0.
	  TSKUSE(I)=0.
1000	  CONTINUE
	MAXDAY = 0		!LAST DAY OF THE MONTH
C
C COLLECT THE DATA
C
10	IF (GTREC() .EQ. EOF) GOTO 40
	  J = SPYDA		!DAY OF MONTH
	  IF (J .GT. MAXDAY) MAXDAY = J
	  TTUSE(J) = TTUSE(J) + NTERMS(0)
	  TSKUSE(J) = TSKUSE(J) + SPYTKS
	  GOTO 10
40	CONTINUE
C
C CONVERT DATA TO HOURS AND FIND SCALE FOR GRAPH
C
	HRSMAX = 0.		!MAX HRS IN A DAY
	FACT = STIME/60.	!CONVERT NUMBER OF INCIDENTS TO HOURS
	DO 1100,I=1,MAXDAY
	  TTUSE(I) = TTUSE(I)*FACT	!CONVERT TO HOURS
	  TSKUSE(I) = TSKUSE(I)*FACT
	  IF (TTUSE(I) .GT. HRSMAX) HRSMAX=TTUSE(I)
	  IF (TSKUSE(I) .GT. HRSMAX) HRSMAX=TSKUSE(I)
1100	  CONTINUE
	I = (HRSMAX+24.)/24.
	SCALE = 2./I		!CONVERTS HOURS TO COLUMN NUMBER

C
C PRODUCE THE GRAPH
C
	WRITE (RPTLUN,100)
100	FORMAT ('0'/20X,'REPORT OF SYSTEM USE BY DAY OF MONTH'/
	1	'0',7X,'O -- TASK-HOURS'/8X,'X -- TERMINAL-HOURS')
	DO 1500 I=1,48
1500	  LINE(I) = "40			!BLANK OUT LINE
	K = 48./SCALE
	DO 1600 I=12,K,12		!LABEL EVERY 12 HOURS ON LINE
	  J = I*SCALE-4.9		!COLUMN TO START LABELING
	  ENCODE (6,103,LINE(J)) I
103	  FORMAT (I2,'HRS!')
1600	  CONTINUE
	WRITE (RPTLUN,110)LINE
110	FORMAT ('0',8X,'DAY !',48A1/8X,55(1H-))
C
	DO 2000 I=1,MAXDAY
	  J = SCALE*TTUSE(I) + .5	!NUMBER OF TT-HOURS
	  K = SCALE*TSKUSE(I) + .5	!AND TASK-HOURS
	  LL = 48-K
	  IF (LL .GT. 47) LL=47
	  WRITE (RPTLUN,120) I,(1HO,L=1,K),(1H ,L=1,LL)
120	  FORMAT (8X,'!',I3,' !',48A1,'!')
	  WRITE (RPTLUN,121)(1HX,L=1,J)
121	  FORMAT ('+',13X,48A1)
2000	  CONTINUE
C
	WRITE (RPTLUN,130)
130	FORMAT (8X,55(1H-))
C
	REWIND (SPYLUN)
	END