SUBROUTINE HOUR
C
C  REPORTS ON SYSTEM USE BY HOUR OF DAY
C
	INCLUDE 'DAGCOM.FTN'
C
	REAL	TTUSE	(0:23)	!USE OF TT FOR EACH HOUR
	REAL	TKUSE	(0:23)	!TASK-USAGE FOR EACH HOUR
	INTEGER	NDAYS	(12)	!NUMBER OF DAYS IN EACH MONTH
	INTEGER	THISMO		!MONTH OF THIS REPORT
	INTEGER	THISYR		!YEAR OF THIS REPORT
	DATA	NDAYS	/31,28,31,30,31,30,31,31,30,31,30,31/

C
C INITIALIZE ARRAYS
C
	DO 1000,I=0,23
	  TTUSE(I) = 0.
	  TKUSE(I) = 0.
1000	  CONTINUE
C
C ACCUMULATE DATA
C
10	IF (GTREC() .EQ. EOF) GOTO 40
	  THISMO = SPYMO
	  THISYR = SPYYR
	  J = SPYHR
	  TTUSE(J) = TTUSE(J) + NTERMS(0)
	  TKUSE(J) = TKUSE(J) + SPYTKS
	  GOTO 10
40	  CONTINUE
	IF (MOD(THISYR,4) .EQ. 0) NDAYS(2)=29
	DAYS = NDAYS(THISMO)
C
C GET SCALE FACTORS  FOR GRAPHING DATA
C
	FACT1 = STIME/60.		!CONVERT OCCURANCE TO HRS
	UMAX = 0.
	DO 1100, I=0,23
	  TTUSE(I) = TTUSE(I)*FACT1	!CONVERT TO HOURS
	  TKUSE(I) = TKUSE(I)*FACT1	!AND AGAIN
	  IF (TTUSE(I) .GT. UMAX) UMAX=TTUSE(I)
	  IF (TKUSE(I) .GT. UMAX) UMAX=TKUSE(I)
1100	  CONTINUE
	NPCT = UMAX/DAYS + 1.		!MULTIPLE OF 100% FOR GRAPH
	SCALE = 45./(NPCT*DAYS)
C
C WRITE OUT HEADERS FOR GRAPH
C
	WRITE (RPTLUN,100)
100	FORMAT (1H1/1H0,20X,'REPORT OF SYSTEM USE BY HOUR OF DAY'/
	1	'0',7X,'0 -- TASK-HOURS'/8X,'X -- TERMINAL-HOURS')
	WRITE (RPTLUN,110)NPCT*100
110	FORMAT (1H0,9X,'HOUR  !',14X,'% OF FULL USE',14X,I3,'%!'/
	1	8X,55(1H-))
C
C WRITE BODY OF GRAPH
C
	DO 2000 I=0,23
	  J = SCALE*TTUSE(I) + .5
	  K = SCALE*TKUSE(I) + .5
	  LL = 45-K
	  IF (LL .GT. 44) LL = 44
	  WRITE (RPTLUN,120) I,(1HO,L=1,K),(1H ,L=1,LL)
120	  FORMAT (8X,'!',I3,':00 !',45A1,'!')
	  WRITE (RPTLUN,121)(1HX,L=1,J)
121	  FORMAT (1H+,16X,48A1)
2000	  CONTINUE
C
C NOW FOR THE EPIGRAPH
C
	WRITE (RPTLUN,130)
130	FORMAT (8X,55(1H-))
C
	REWIND (SPYLUN)
	END