.TITLE	DELTMP
	.IDENT	"V1.0"
	.ENABL	LC
	.NLIST	ME,BEX,CND
	.sbttl	Author's credits
 
;	Author:		Henry R. Tumblin
 
;	Date:		07-Feb-79
 
;	Version:	1.0
 
;	For:		Research and training office
 
;	Module Name:	DELTMP
 
;	Residence:	DB1:[107,6]DELTMP.MAC
 
;	Machine/System:	PDP-11/70 IAS V2.0
 
;	Type/Language;	Subroutine/Assembler
 
;	Abstract:	This subroutine will delete all temporary
;			files used in generating a mailing list.
;			
;	Edits:
 
;	Date	By	Reason
;     ---------	-----	--------------------------------------------------
;	none

	.sbttl	Mcalls and such.
 
	.MCALL	FCSMC$
 
	FCSMC$				; MCALL all FCS macros
 
;	This subroutine deletes files, so due to the nature
;	of the FCS utilty routines that do this, we have to use a
;	dummy fdb.
 
DFDB:	FDBDF$				; Allocate a fdb.
	FDOP$A	2,DSDS			; Dummy in a couple of fields
 
DSDS:	.WORD	DEVS,DEV		; Dataset descriptor
	.WORD	UICS,UIC
	.WORD	NAMS,NAM
 
DEV:	.ASCII	"DB1:"			; Device
	DEVS=.-DEV
UIC:	.ASCII	"[107,6]"		; UIC
	UICS=.-UIC
NAM:	.ASCII	"MAIL.TMP"		; File name and type
	NAMS=.-NAM 
	.EVEN

	.SBTTL	Start mainline code
 
DELTMP::
	CALL	$SAVAL			; Preserve our registers
 
;	Set up for call to .PARSE

	MOV	#DFDB,R0		; @ of FDB in R0
	MOV	#DFDB+F.FNB,R1		; @ of FNB in FDB
	MOV	#DSDS,R2		; @ of dataset descriptor
	CLR	R3			; No default FNB specified.
	CALL	.PARSE			; Parse filespecs.
 
;	Now set up to find and delete all .TMP files.

	MOV	#DFDB,R0		; @ of FDB in R0
	MOV	#DFDB+F.FNB,R1		; @ of FNB in FDB
10$:	CALL	.FIND			; Locate the directory entry
	BCS	20$			; CS - no more files
	CALL	.DLFNB			; Delete the file
	CLR	N.FVER(R1)		; Clear for next .FIND
	BR	10$			; Go delete the next file
 
20$:	RETURN				; All thru, return
 
	.END