.NLIST    TTM,SYM                                                     
          .TITLE    DELETE FUNCTION FOR FORTRAN\                                
;                                                                               
;                   FORTRAN CALL:                                               
;                             ERR=DELETE(LUN)                                   
;                   WHERE LUN = LOGICAL UNIT NUMBER                             
;                             ERR=FCS ERROR CODE RETURN (ZERO FOR OK)           
;                                                                               
;                                                                               
;                   NOTE:                                                       
;                   THE FILE MUST BE OPEN, OF FDBSET MUST BE USED (ALONG        
;                   WITH CALL ASSIGN) TO FILL INTHE REQUIRED INFO IN THE        
;                   FDB.                                                        
;                                                                               
;                   INVALID LUN'S WILL RESULT IN A FORTRAN ERROR TRAPPED BY     
;                    THE FCHNL ROUTINE9                                         
          .MCALL    DELET$                                                      
          .GLOBL    DELETE,$FCHNL,$OTSV                                         
DELETE:   MOV       @2(R5),R2 ;GET LUN PARAMETER                                
          MOV       @#$OTSV,R3          ;GET WORK AREA ADDRESS                  
          JSR       PC,$FCHNL ;FIND FDB ADDRESS                                 
          MOV       R0,R1     ;SAVE ADDRESS OF FORTRAN FDB                      
          ADD       #14,R0    ;GET TO RSX FDB                                   
          DELET$    R0        ;DELETE THE FILE NOW\                             
          BCS       ERR       ;AM I IN TROUBLE?                                 
          MOV       #66,R0    ;ZERO 66 WORDS OF FDB TO RECYCLE IT               
LUP:      CLR       (R1)+     ;ZAP!!!                                           
          SOB       R0,LUP    ;KEEP AT IT UNTIL YOUR'E DONE                     
          RTS       PC                                                          
ERR:      MOVB      F.ERR(R0),R0        ;GET FCS ERROR CODE FROM FDB            
          RTS       PC                                                          
          .END