.SBTTL	TASK DATA REPORTING
	.TITLE RPU8C
	.IDENT	/V004F/                                                         ;**NEW**
;                                                                               ;**-1
;
;
;
;
;
;    COPYRIGHT (C) 1974, DIGITAL EQUIPMENT CORP., MAYNARD, MASSACHUSETTS 01754.
;
;
;    THE SOFTWARE DESCRIBED IN THIS DOCUMENT, INCLUDING BUT NOT LIMITED TO, IN-
;    STRUCTION EXECUTION TIMES AND OPERATING SPEEDS IS FOR INFORMATION PURPOSES
;    ONLY.   ALL  SUCH  MATERIAL  IS  SUBJECT   TO   CHANGE   WITHOUT   NOTICE.
;    CONSEQUENTLY  DIGITAL MAKES NO CLAIM AND SHALL NOT BE LIABLE FOR ITS ACCU-
;    RACY.
;
;    THE SOFTWARE DESCRIBED IS FURNISHED TO THE PURCHASER UNDER A  LICENSE  FOR
;    USE  ON  A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH THE INCLUSION OF
;    DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH  SYSTEM,  EXCEPT  AS  MAY
;    OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
;
;    DIGITAL ASSUMES NO RESPONSIBILITY  FOR  THE  USE  OR  RELIABILITY  OF  ITS
;    SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DIGITAL.
;
;
;    UNLESS SPECIFIED OTHERWISE, THE TERMS "RSX" AND "RSX-11"  IN THIS DOCUMENT
;    IMPLY "RSX-11D".
;
;
;
;
;	VERSION:	VOO3E
;	AUTHOR:		R. KLEINMAN
;	DATE:		5 FEB 74
;
;
;   THIS MODULE CONTAINS
;	1-- CODE FOR EVALUATE
;
;
;                                                                               ;**NEW**
;	VERSION:	V004A                                                   ;**NEW**
;	MODIFIED BY:	RODGER S. MILES                                         ;**NEW**
;	DATE:		19-AUG-74                                               ;**NEW**
;                                                                               ;**NEW**
;	THIS MODULE WAS UPDATED TO OUTPUT ALL DATA FOR A TASK                   ;**NEW**
;	ON A SINGLE LINE WITH ONLY A TOP OF LIST HEADER.                        ;**NEW**
;                                                                               ;**NEW**
	.PAGE
;
	.MCALL	CALL
	.MCALL	RETURN
;
;+
;THIS SECTION IS CONCERNED WITH OUTPUTTING THE TASK INFORMATION
;OF THE EVALUATION REPORT.  IT IS CALLED FROM RPU8M.
;THE TOTAL TASKS INVOLVED, + OVERLAY STRUCTURE IS:
;
;[EVALU8-(AST8,RPU8M-(RPU8A,RPU8B,RPU8C))]
;
;POSSIBLE REASONS FOR TOTAL TASK STATUS <100%
;
;A.  TASK WAS LOADING/CHECKPOINTED ON PARTITION NOT INCLUDED IN REPORT
;B.  TASK STATUS WAS [FOR AN APPRECIABLE LENGTH OF TIME]:
;
;	1.  TASK EXITED
;	2.  TASK PARITY ERROR [SUSPENDED]
;
;-
RPC::
	MOV	#TC1P,R5	;WRITE HEADER
	CALL	WLINE
				;GET TO FIRST TASK SEEN
	MOV	#TASTBS,R0
RPC1:				;GET NEXT TASK TO OUTPUT
	TST	(R0)		;IS THERE ANY TASK?
	BNE	10$
	MOV	#TASTBN,R0	;NO.  OUTPUT NULL TASK
10$:					;YES.  CONVERT NAME TO ASCII.SET
	MOV	#TC3B,R3	;ASCII BUFFER
	MOV	#6,R1		;#CHAR TO BE CONVERTED
	MOV	R0,R2		;START OF RAD50 BUFFER
	CALL	@#..RDTA	;DO CONVERSION
				;
	MOV	#TC3P,R5
	CALL	WLINE		;OUTPUT IT
				;
	MOV	AT.AC(R0),R4	;GET #                                          ;**-1
	CALL	DECCN		;CONVERT TO ASCII
	CALL	WLINE		;OUTPUT IT
	.PAGE                                                                   ;**-2
RPC2:				;OUTPUT STATUS
	MOV	R0,R1
	ADD	#AT.LC,R1	;SET R1 TO FIRST OFFSET
	MOV	#AT.NUM,R3	;NUMBER TO DO
	CALL	DOTPC		;FILL IN %, OUTPUT
	CMP	#TASTBN,R0	;WAS THIS THE NULL TASK?
	BNE	10$
	RETURN			;YES.  ALL DONE.  RETURN
10$:				;NO.  UPDATE TO NEW TASK
	ADD	#AT.SZ,R0
	BR	RPC1
	.PAGE
;+
;LOCAL SUBROUTINE TO OUTPUT TASK STATUS %'S
;
;INPUT:
;R1=PTR TO STATUS TABLE
;R3=# ENTRIES IN THE TABLE
;
;OUTPUT: ALL STATUS DIVIDED BY # SNAPSHOTS, OUTPUT AS %
;
;REGISTERS ALTERED: R1,R2,R3,R4,R5
;-
DOTPC:				;INITIALIZE % LINE
	MOV	AT.AC(R0),R4	;GET DIVISOR [= TOTAL # SNAPSHOTS]              ;**-1
DOTP1:				;GET NEXT # IN R2
	MOV	(R1)+,R2
	CALL	PCCAL		;CONVERT TO %
	CALL	WLINE		;OUTPUT IT
	SOB	R3,DOTP1	;GO THROUGH UNTIL ALL DONE
				;
	RETURN			;EXIT SUBROUTINE                                ;**-1
	.PAGE
;+
;LOCAL SUBROUTINE'S SUBROUTINE
;
;OUTPUT 2 LF'S, CR
;-
LF2:				;OUTPUT 2 LF'S, CR
	MOV	R5,-(SP)
	MOV	#TG2P,R5	;USE LF BUFFER
	MOV	#3,TG2P+2
	CALL	WLINE
	MOV	(SP)+,R5
	RETURN
	.PAGE
	.SBTTL	TEXT BUFFERS
;+
;TEXT BUFFERS FOR SECTION C
;-
;                                                                               ;**NEW**
; HEADER                                                                        ;**NEW**
TC1:	.BYTE	12,12                                                           ;**NEW**
	.ASCII	/TASK RUN-TIME UTILIZATION/                                     ;**NEW**
	.BYTE	15,12                                                           ;**NEW**
	.ASCII	/TASK   ACTIVE   /                                              ;**NEW**
	.ASCII	$%C/L  %WT4  %R/T  %SUS  %RUN  %EXC$                            ;**NEW**
TC2:	.EVEN                                                                   ;**NEW**
TC3:                                                                            ;**NEW**
TC3B:	.ASCII	/000000  /                                                      ;**NEW**
TC4:	.EVEN                                                                   ;**NEW**
;+                                                                              ;**-10
;OUTPUT CONTROL FOR SECTION C
;-
TC1P:	.WORD	TC1,TC2-TC1,CTLC	;HEADER                                 ;**NEW**
TC3P:	.WORD	TC3,TC4-TC3,CTL		;TASK NAME                              ;**NEW**
	.END                                                                    ;**-4
	.PAGE