.SBTTL	PARTITION REPORTING
	.TITLE	RPU8B
	.IDENT	/V004B/                                                         ;**NEW**
;                                                                               ;**-1
;
;
;
;
;
;    COPYRIGHT (C) 1974, DIGITAL EQUIPMENT CORP., MAYNARD, MASSACHUSETTS 01754.
;
;
;    THE SOFTWARE DESCRIBED IN THIS DOCUMENT, INCLUDING BUT NOT LIMITED TO, IN-
;    STRUCTION EXECUTION TIMES AND OPERATING SPEEDS IS FOR INFORMATION PURPOSES
;    ONLY.   ALL  SUCH  MATERIAL  IS  SUBJECT   TO   CHANGE   WITHOUT   NOTICE.
;    CONSEQUENTLY  DIGITAL MAKES NO CLAIM AND SHALL NOT BE LIABLE FOR ITS ACCU-
;    RACY.
;
;    THE SOFTWARE DESCRIBED IS FURNISHED TO THE PURCHASER UNDER A  LICENSE  FOR
;    USE  ON  A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH THE INCLUSION OF
;    DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH  SYSTEM,  EXCEPT  AS  MAY
;    OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
;
;    DIGITAL ASSUMES NO RESPONSIBILITY  FOR  THE  USE  OR  RELIABILITY  OF  ITS
;    SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DIGITAL.
;
;
;    UNLESS SPECIFIED OTHERWISE, THE TERMS "RSX" AND "RSX-11"  IN THIS DOCUMENT
;    IMPLY "RSX-11D".
;
;
;
;
;	VERSION:	VOO3E
;	AUTHOR:		R. KLEINMAN
;	DATE:		5 FEB 74
;
;	VERSION:	V004A                                                   ;**NEW**
;	MODIFIED BY:	RODGER S. MILES                                         ;**NEW**
;	DATE:		22-AUG-74                                               ;**NEW**
;                                                                               ;**NEW**
;	SEVERAL LINE FEEDS REMOVED AND THE MODIFICATION OF                      ;**NEW**
;	THE CONTROL CHARACTER IN TG3P WAS REMOVED                               ;**NEW**
;                                                                               ;**NEW**
;
;   THIS MODULE CONTAINS
;	1-- CODE FOR EVALUATE
;
;
	.PAGE
;
	.MCALL	CALL
	.MCALL	RETURN
;
;+
;THIS SECTION IS CONCERNED WITH OUTPUTTING THE PARTITON AND POOL
;INFORMATION OF THE EVALUATION REPORT.  IT IS CALLED FROM RPU8M
;THE TOTAL TASKS INVOLVED + OVERLAY STRUCTURE IS:
;
;[EVALU8-(AST8,RPU8M-(RPU8A,RPU8B,RPU8C))]
;-
RPB::
	MOV	#TB1P,R5	;WRITE HEADER
	CALL	WLINE
	CALL	WLINE		;AND LABELS
	MOV	#TPDTBS,R0	;INITIALIZE PARTITION NAMES
RPB1:
	MOV	(R0),R2		;IS THERE ANOTHER PARTITION?
	BNE	10$
	JMP	RPB8		;NO.  ALL THROUGH.  DO POOL
10$:				;YES.  CONVERT NAME.  SPECIFY:
	MOV	#TBAS1,R3	;ASCII BUFFER
	MOV	#6,R1		;# CHAR TO BE CONVERTED
	ADD	#T.PN,R2	;START OF RAD50 BUFFER
	CALL	@#..RDTA	;DO CONVERSION
				;
	MOV	(R0),R2		;GET PARTITION SIZE
	MOV	T.PZ(R2),R4
	CALL	DECCN		;ASCII BUFFER SIZE IS AT TG3
				;
	MOV	#TG3,R1		;TRANSFER IT
	MOV	#TBAS3,R2
	MOV	#5,R3
20$:
	MOVB	(R1)+,(R2)+
	SOB	R3,20$
	.PAGE
RPB2:				;CHECK IF USER PARTITION
	MOV	#TBASP,R5
	MOV	(R0),R1
	BIT	#TF.UC,T.FW(R1)
	BEQ	RPB5		;NO.  ITS SYSTEM
				;YES.  ITS USER.
	MOVB	#'U,TBAS2	;INSERT "U"
	CALL	WLINE		;WRITE FIRST PART
				;NOW MERELY CALCULATE % OCCUPIED
				;= # IN AP.SM/TOTAL SNAPSHOTS
	MOV	AP.SM(R0),R2	;GET TOP HALF
	MOV	TTIME,R4	;AND BOTTOM HALF
RPB3:
	CALL	PCCAL		;ASCII BUFF XX.XX IN TG1
				;R5 SET TO PRINT IT OUT
	INC	TG1P+2		;SET FOR END OF LINE
	CALL	WLINE		;PRINT OUT % USED.  GO BACK FOR MORE.
	ADD	#AP.SZ,R0	;UPDATE TPD POINTER
	JMP	RPB1		;RETURN
	.PAGE
RPB5:				;SYSTEM PARTITION SEEN
	MOVB	#'S,TBAS2	;INSERT "S"
	CALL	WLINE		;WRITE FIRST PART
				;
	MOV	(R0),R1		;GET SIZE OF TPD AS DIVISOR
	MOV	T.PZ(R1),R4	;[RETAIN R4 AS DIVISOR]
	MOV	AP.SM(R0),R2
	CALL	PCCAL		;ASCII BUFF XX.XX IN TG1
				;[SMALL %]
	CALL	WLINE
	MOV	AP.LG(R0),R2
	CALL	PCCAL		;[LARGE %]
	CALL	WLINE		;OUTPUT IT
	MOV	AP.HM(R0),R2	;CALCULATE MEAN OF FREE AREA
	MOV	AP.HM+2(R0),R3
	DIV	TTIME,R2	;MEAN IN R2
	MOV	R2,-(SP)	;GET % OF TOTAL PARTITION
	CALL	PCCAL
	CALL	WLINE		;OUTPUT IT
	MOV	AP.LM(R0),R2	;CALCULATE MEAN OF LARGEST HOLE
	MOV	AP.LM+2(R0),R3
	DIV	TTIME,R2	;MEAN IN R2
	MOV	R2,-(SP)	;GET % OF TOTAL PARTITION
	CALL	PCCAL
	CALL	WLINE		;OUTPUT IT
				;NOW FIND FRAGMENTATION RATIO
	MOV	(SP)+,R2	;TOP=LARGEST HOLE MEAN
	MOV	(SP)+,R4	;BOTTOM=TOTAL FREE MEAN
	JMP	RPB3		;OUTPUT AS LAST LINE.  RETURN FOR
				;MORE PARTITIONS
	.PAGE
RPB8:				;DO POOL LINE
	MOV	#PLTBS,R0	;GET TABLE LOCATION
				;TRANSFER "POOL" TO PART NAME
	MOV	#TB4,R1
	MOV	#TBAS1,R2
	MOV	#6,R3
10$:
	MOVB	(R1)+,(R2)+
	SOB	R3,10$
				;FILL TYPE WITH -
	MOVB	#55,R2
	MOVB	R2,TBAS2
				;FILL SIZE WITH -'S
	MOV	#TBAS3,R1
	MOV	#5,R3
20$:
	MOVB	R2,(R1)+
	SOB	R3,20$
	MOV	#TBASP,R5
				;WRITE LINE
	CALL	WLINE
				;WRITE LEAST # NODES                            ;**-1
	MOV	AL.SM(R0),R4
	CALL	DECCN		;CONVERT TO 5 DECIMAL DIGITS
	CALL	WLINE		;OUTPUT IT
				;WRITE MOST # NODES
	MOV	AL.LG(R0),R4
	CALL	DECCN
	CALL	WLINE
				;WRITE MEAN # NODES
	MOV	AL.FS(R0),R4
	MOV	AL.FS+2(R0),R5
	DIV	TTIME,R4	;GET AVERAGE # NODES IN R4
	CALL	DECCN
	CALL	WLINE		;OUTPUT BUFFER LINE                             ;**-1
	RETURN			;FINISHED WITH PART B
	.PAGE
	.SBTTL	TEXT BUFFERS
;+
;TEXT BUFFERS FOR SECTION B
;-
TB1:	.BYTE	12,12                                                           ;**NEW**
	.ASCII	/PARTITION AND POOL UTILIZATION/                                ;**-1
TB3:	.ASCII	QP NAME T SIZE %LO/OC %HIGH  %AVG %CONT %F RATQ                 ;**-1
	.BYTE	12
TB4:	.ASCII	/**POOL/
TBAS1:	.BYTE	0,0,0,0,0,0	;PARTITION NAME
	.BYTE	40
TBAS2:	.BYTE	0		;TYPE
	.BYTE	40
TBAS3:	.BYTE	0,0,0,0,0	;SIZE
	.BYTE	40
TBAS4:	.EVEN
;
;+
;OUTPUT CONTROL FOR SECTION B
;-
TB1P:	.WORD	TB1,TB3-TB1,CT	;HEADER
TB3P:	.WORD	TB3,TB4-TB3,CTLC;LABELS
TBASP:	.WORD	TBAS1,TBAS4-TBAS1,CTL ;ENTRIES
	.END
	.PAGE