.TITLE RENAME  -- RENAME A FILE FROM FORTRAN
	.IDENT /00/
 
 
;
; FORTRAN CALL:
;	CALL RENAME(LUN1,LUN2,IERR)
;
;	LUN1 - THE UNIT NUMBER OF THE OLD FILE, WHICH MUST BE OPEN
;	LUN2 - THE UNIT NUMBER OF THE NEW FILE NAME INFORMATION
;		USE 'CALL ASSIGN'
;	IERR - RETURN STATUS:	FCS ERROR CODE OR 0
;
 
RENAME::
	MOV	@#$OTSV,R3		; OBTAIN OTS IMPURE PTR
	CLR	@6(R5)			; ASSUME SUCCESSFL REMANE
	MOV	@4(R5),R2		; GET ADDRESS OF 2ND LUN'S FDB
	JSR	PC,$FCHNL
	ADD	#14,R0			; POINT TO FCS PORTION OF FDB
	MOV	R0,R4			; SAVE THE VALUE
	MOV	@2(R5),R2		; GET ADDRESS OF 1ST LUN'S FDB
	JSR	PC,$FCHNL
	ADD	#14,R0			; POINT TO FCS PORTION OF FDB
	MOV	R4,R1			; RESTORE 2ND LUN PTR
	MOV	R0,R2			; MAKE PTRS TO FILE ID PORTIONS
	ADD	#F.FNB+N.FID,R2		;  OF THE FILE NAME BLOCK
	ADD	#F.FNB+N.FID,R4		;
	MOV	(R2)+,(R4)+		; COPY THE FILE ID TO THE NEW NAME BLOCK
	MOV	(R2)+,(R4)+		;   TO INHIBIT A .PARSE BY .RENAM
	MOV	(R2)+,(R4)+
 
	CALL	.RENAM			; RENAME THE FILE
	BCC	10$			; ERROR?
	MOVB	F.ERR(R0),@6(R5)	; RETURN THE FCS ERROR CODE
 
10$:	SUB	#14,R0			; POINT TO FORTRAN FDB PORTIONS
	SUB	#14,R1			;
	MOV	#66,R2			; CLEAR FDBS FOR LATER USE
20$:	CLR	(R0)+
	CLR	(R1)+
	SOB	R2,20$
 
	RTS	PC
 
 
	.END