; =======================================================================
;
;	SYSTEM/MACHINE	- IAS V2.0 / PDP-11/70, TEKTRONIX-4662
;
;	AUTHOR		- J.N. GUIDI
;
;	DATE		- 4-OCT-78
;
;	TYPE/LANGUAGE	- SUBROUTINE / ASSEMBLY (MACRO-11)
;
;	RESIDENCE	- [133,45]PRINT.MAC
;
;	RESTRICTIONS	- THIS ROUTINE REQUIRES THAT LUN 1 BE CONNECTED
;			  TO A TEKTRONIX-4662 DIGITAL PLOTTER
;
;	MODIFICATIONS	- NA
;
;	ABSTRACT	- THIS SUBROUTINE WILL ALLOW A CALLING ROUTINE
;	TO PRINT ALPHA CHARACTERS ON A TEKTRONIX-4662 DIGITAL PLOTTER
;	WHICH IS ASSOCIATED WITH LUN 1.
;
;	CALL		- CALL PRINT(ARRAY,DIM)
;				ARRAY IS DECLARED AS BYTE (LOGICAL*1)
;				DIM IS SIZE OF ARRAY
;
; =======================================================================
	.TITLE	PRINT
	.IDENT	/V1.0/
	.PSECT	$$PLOT,RW,I,CON,LCL
	.MCALL	DIR$,QIOW$
;
;
	.MACRO	TYPE,A,B
	MOV	A,PLOT+Q.IOPL
	MOV	B,PLOT+Q.IOPL+2
	DIR$	#PLOT
	.ENDM	TYPE
;
US:	.BYTE	37	;UNIT SEPARATOR
	.EVEN
	PLTLUN=1	;PLOTTER LUN
PLOT:	QIOW$	IO.WVB,PLTLUN,1,,,,<0,0,>
PRINT::
	CMPB	#2,(R5)		;DO WE HAVE 2 ARGUMENTS ?
	BEQ	1$		;YES
	JMP	99$		;NOPE - EXIT WITH DISGRACE
;
;	SET PLOTTER INTO ALPHA MODE, THEN PRINT TEXT
;
1$:	TYPE	#US,#1		;THROW PLOTTER INTO ALPHA MODE
	TYPE	2(R5),@4(R5)	;DISPLAY TEXT
99$:	RTS	PC
	.END