.TITLE	CTLIMP FORCE CTLIMP FOR FORTRAN FILES
	.IDENT	-010000-
;+
; ABSTRACT:
;
;	THIS SUBROUTINE SETS THE CTLIMP BIT FOR FORTRAN FILES.
;	IT MUST BE CALLED AFTER THE FILE HAS BEEN OPENED
;	(I. E., WRITTEN TO);  IF THE FILE IS NOT A TERMINAL
;	OR TAPE FILE IT WILL AFFECT ALL RECORDS, INCLUDING
;	THOSE ALREADY WRITTEN.
;
; CALLING SEQUENCE:
;
;	CALL CTLIMP(LUN)
;
; ARGUMENTS:
;
; LUN	INTEGER*2
;	THE LOGICAL UNIT OF THE FILE WHICH IS TO HAVE THE
;	CTLIMP BIT SET.
;
; LIBRARIES:
;
;	REFERENCES $FCHNL AND $OTSV IN THE FORTRAN LIBRARY.
;
; FILES:
;
;	AS PASSED BY THE USER.
;
; EXTERNALS:
; ERRORS:
;
;	NO ERRORS ARE POSSIBLE.
;
; NONSTANDARD FEATURES:
;
;	THIS FUNCTION IS NOT IMPLEMENTED IN ANY DEC SOFTWARE
;	FOR FORTRAN.
;
; WRITTEN:
;
;	BRUCE C. WRIGHT
;	CLINICAL EPIDEMIOLOGY LABORATORY
;	DUKE UNIVERSITY MEDICAL CENTER
;	DURHAM, N. C. 27710
;	11-SEP-77, -1.0.0-
;
; MODIFIED:
; VERIFIED:
; REFERENCES:
;
;	MAY 1976 SOFTWARE DISPATCH, PP. 228, 234
;	I/O OPERATIONS REFERENCE MANUAL, P. 2-5, P. A-2
;-

	.MCALL	FDAT$R
	.GLOBL	$FCHNL,$OTSV
	.LIST	MEB
;
CTLIMP::MOV	@2(R5),R2	;GET THE LUN.
	MOV	@#$OTSV,R3	;GET THE WORK AREA ADDRESS.
	JSR	PC,$FCHNL	;FIND THE FDB ADDRESS.
	ADD	#14,R0		;GET TO THE RSX FDB.
	FDAT$R	R0,,#FD.CR	;FORCE FILE NOT TO BE FORTRAN CTL
	RTS	PC		;AND RETURN TO THE CALLER.
	.END