.TITLE PCPRSX  MCR BUFFER STUFFER
;
;NEW FEATURES--PCP-LIKE ARGUMENTS. DIFFERENCES FROM DOS VERSION:
;
;1. ARGUMENTS ARE ALL 9 CHARACTERS LONG, NOT 6
;2. LINE MUST BEGIN WITH / TO HAVE ARGUMENTS STUFFED
;3. ARGUMENTS ARE SEPARATED BY ^ (UPARROW)
;4. & GETS REPLACED BY ^ IN ARGS (SHOULD BE INFREQUENTLY NEEDED)
;5. ?<CHAR> REPLACES OLD CTL-CHAR, THOUGH CHARS ARE CORRESPONDING.
;
;ALTERED TO ATTEMPT TO MAKE IT GENERALLY USABLE AS AN
;INDIRECT MCR FACILITY FOR RSX11D G. EVERHART 8/13/1976
	.IDENT /GCE002/
;
;
;THIS ROUTINE MAY BE USED (ONE COPY PER TI: ONLY!) TO PERMIT
;MCR COMMANDS TO BE ISSUED VIA INDIRECT FILES. NO CHANGES
;TO THE SYSTEM ARE NEEDED---JUST INSTALL THIS TASK, BUILT M/U,
;AND REQUEST IT. ITS PROMPT IS "PCP>"  (YEAH, JUST LIKE THE DOS
;PROGRAM) AND ANY FILE MAY BE SPECIFIED. DEVICE NAME MUST BE
;MENTIONED EXPLICITLY IN FILE CALLS (@SY:NAME.TYP, NOT
;JUST @NAME.TYP; DEFAULT DEVICE IS TI:, NOT SY:).
;
;THIS PROGRAM IS A STRAIGHTFORWARD EXTENSION OF 'START' BY
;J.E. POLLACK, REMOVING SOME RESTRICTIONS OF HIS VERSION THAT
;MADE IT IMPRACTICAL FOR USE EXCEPT JUST AFTER A BOOT.
;THE FULL SET OF COMMANDS OF 'START' IS AVAILABLE. IF MULTIPLE
;VERSIONS OF THIS TASK ARE RUN, IT WILL BECOME CONFUSED AS TO
;WHAT TASKS TO WAIT FOR AND MAY START A STEP OF A PROCEDURE TOO
;SOON. HOWEVER, IT IS NOT FORBIDDEN EXPLICITLY IN CASE A USER
;WANTS THIS EFFECT. COPIES AT DIFFERENT TI'S SHOULD BE SAFE
;AGAINST ONE ANOTHER.
;
;	G. EVERHART, 8/14/76 16:30:00
;
;
;
.MCALL CALL,RETURN,FSRSZ$
.MCALL FDBDF$,FDOP$A,FDRC$A,FDAT$A,FDBF$A,OPEN$R,NMBLK$
.MCALL EXIT$S,MRKT$S,WTSE$S
;
;
; SPECIAL COMMANDS HANDLED..
;	*E TO EXIT QUIETLY
;	*D TO DELAY ONE SECOND
;	*Q TO SUPRESS ECHOS
;	*N TO RESUME COMMAND ECHO
;
	GCMLD$		;DEFINE SOME STUFF
;
;
GTAB:	GCMLB$	CFDB,FFDB,0,0,5,PCP
;
TSKDTA:	.BLKW	22.	;DATA FOR GTSK$
	.MCALL	GTSK$S
CFDB:	FDBDF$
	FDAT$A	R.VAR,FD.CR
	FDRC$A	,BUFFR,80.
	FDOP$A	CLUN,,DFCFDB
	FDBF$A	,,1
;
DFCFDB:	NMBLK$	CMD,CMD,,TI,0
BUFFR:	.BLKB	82.
;
FFDB:	FDBDF$
	FDAT$A	R.VAR
	FDOP$A	FLUN
	FDBF$A	,,1
;
.ECHOF:	1	;ECHO FLAG
;
CLUN=6
FLUN=1
;
PRELN0:	;PREFIX FOR FORCED PROCEDURE INVOCATION BY NAME
		;CALLED AUTOMATICALLY IF TASK NOT FOUND
	.ASCII	/@SY:[01,200]/	;SHOULD BE EVEN # BYTES
PRELN2:	.BLKB	100.	;ALLOW BIG HUGE LINES.
;PRELIN:	.ASCIZ ^MOU SY0:/OVR^
;	.ASCIZ ^@SY0:STARTUP.CMD^
;	.BYTE 0
;	.EVEN
PRELIN:
	.ASCII	/@SY0:[1,200]/
TSKNAM:	.ASCIZ	/SPCP.CMD/
	.BYTE	0,0,0,0,0,0,0,0	;SAFETY
	.BYTE	0	;SAFETY MARGIN
	.EVEN
;
	FSRSZ$	2		;TWO OPEN FILES
;
;
	.EVEN
	.PSECT	PURE,RO		;MAKE A PURE PSECT FOR CODE
START:
	GTSK$S	#TSKDTA		;GET TASK DATA (INCLUDING NAME)
	MOV	#TSKNAM,R0	;BUFFER ADDR
	MOV	TSKDTA,R1
	JSR	PC,$C5TA	;CONVERT RAD50 TO ASCII 3 CHARS
	MOV	TSKDTA+2,R1	;GET NEXT RAD50
	JSR	PC,$C5TA	;AND CONVERT
	MOVB	#'.,(R0)+
	MOVB	#'P,(R0)+
	MOVB	#'C,(R0)+
	MOVB	#'P,(R0)+
	CLRB	(R0)+		;ZERO TRAILER
	MOV	.CRTSK,R0	;GET OUR ATL ADDR
	MOV	A.TI(R0),R0	;THEN GET OUR PUD ADDR
	BISB	#<UT.LG+UT.PR>,U.PR(R0) ; SET LOGGED-ON, PRIV BITS
	TSTB	U.PC(R0)	;FORCE LEGAL PPN
	BNE	1$
	MOVB	#200,U.PC(R0)
1$:	TSTB	U.GC(R0)
	BNE	2$
	MOVB	#200,U.GC(R0)
2$:
;	DEFAULT TO [200,200]
;	CLR	.ECHOF		;RESET ECHO ON
	OPEN$R	#CFDB		;OPEN COMMAND FDB
;
;
; NOW FORCE INITAL COMMAND LINES
	SCML$	#GTAB,#PRELIN	;SET UP [1,200]SPCP.CMD STARTUP CMD
;
;	SCML$	#GTAB,#PRELIN	;SET MOUNT AND @FILE COMMANDS
;***** REMOVE ";" ABOVE TO ENABLE AUTOMATIC STARTING OF COMMAND FILE
;
; AND GET NEXT COMMAND LINE
;
10$:
	GCML$	#GTAB
	BCS	20$		;IF ERROR
;
;HERE TEST FOR ARGUMENTS AND ACTIVITIES. CALL MACDO TO DO
;ARGUMENT THINGS FOR US. THEN POSSIBLY ECHO.
	MOV	R1,-(SP)
	MOV	R2,-(SP)
	MOV	R3,-(SP)	;NEED THESE REGS FOR MACDO
	MOV	#GTAB,R1	;GCML BLOCK ADDR
	ADD	#G.CMLD,R1	;LENGTH OF LINE ADDRESS
	MOV	@R1,R3		;SAVE LINE SIZE IN R3
	BEQ	11$		;(SKIP IF NULL)
	ADD	#2,R1		;POINT AT ADDR ADDR
	MOV	@R1,R1		;POINT R1 AT LINE
	CLR	R2		;ASSUME TTY INPUT
	BITB	#FD.TTY,F.RCTL(R0)	;SEE IF IT REALLY WAS
	BNE	12$		;YES
	MOV	#2,R2		;NO, FLAG THIS A PROCEDURE
12$:	JSR	PC,MACDO	;DO ARGS
11$:	MOV	(SP)+,R3
	MOV	(SP)+,R2	;PUT THE REGS BACK THEN
	MOV	(SP)+,R1
;
	TST	.ECHOF		;ECHO THE LINE?
	BNE	15$		;BR IF NO
	ECML$			;ECHO THE LINE
15$:	ADD	#G.CMLD,R0	;POINT TO LINE DESCRIPTOR
;
;CHECK FOR DOT COMMANDS TACKED IN VIA ?RN AND POSSIBLE NEW
;INDIRECTS HERE. PUT IN VIA SCML$ AND GO BACK IF FOUND.
	CMPB	#'.,@2(R0)	;DOT COMMAND?
	BEQ	18$		;YES, HAVE TO PACK LINE
	CMPB	#'@,@2(R0)	;@ COMMAND?
	BNE	17$		;NO, CHECK *
18$:
	MOV	R1,-(SP)	;GRAB COUPLE REGS FOR SCRATCH
	MOV	R2,-(SP)
	MOV	R3,-(SP)
	MOV	2(R0),R1	;LINE ADDR
	MOV	@R0,R2		;SIZE OF LINE
	MOV	#PRELN2,R3	;OUTPUT LINE ADDR
;HERE COPY LINE AND SET .SCML STUFF UP
16$:	MOVB	(R1)+,(R3)+	;COPY A BYTE
	SOB	R2,16$		;DO ALL OF THEM
	CLRB	(R3)+		;MAKE IT ASCIZ
	CLRB	(R3)+		;MAKE IT ASCIZ
	SCML$	#GTAB,#PRELN2	;"PUT INTO" GCML$ PGM
;HOPE GCML$ PGM HANDLES THESE OK.
	MOV	(SP)+,R3
	MOV	(SP)+,R2
	MOV	(SP)+,R1
	BR	10$		;GO GET "NEXT" COMMAND LINE
17$:				;CHECK * COMMANDS
	CMPB	#'*,@2(R0)	;IS THIS A SPECIAL?
	BEQ	30$		;BR IF YES
	CMPB	#'<,@2(R0)	;PROCEDURE FROM PREDEFINED AREA?
	BEQ	45$		;IF YES, BRANCH THERE
	CALL	DOMCR		;FORCE A MCR LINE
	BR	10$		;GOFER NEXT
;
; COMMAND READ ERROR
;
20$:
	CMPB	#GE.EOF,G.ERR(R0);END FILE?
	BNE	10$		;NOPE, IGNORE IT
;
25$:	EXIT$S		;YUP, EXIT QUIETLY
;
;
; SPECIAL COMMANDS
;
30$:
	DEC	(R0)+	;COUNT THE *
	INC	(R0)	;POINT TO NEXT
;
	CMPB	#'Q,@(R0)	;QUIET?
	BEQ	35$
	CMPB	#'N,@(R0)	;NOQUIET?
	BEQ	40$
	CMPB	#'E,@(R0)	;EXIT?
	BEQ	25$		;BYE
;
	CMPB	#'D,@(R0)	;DELAY?
	BEQ	33$		;DO IT
	CMPB	#'R,@(R0)	;RESET?
	BNE	10$			;IF NOT, FORGET IT
	RCML$	#GTAB	;YES, SET COMMAND INPUT TO TOP LEVEL
49$:	BR	10$	;GET NEXT
33$:
;
	MRKT$S	#1,#1,#2	;WAIT ONE SEC
	WTSE$S	#1
	BR	49$		;AND GO FOR NEXT
;
35$:	INC	.ECHOF		;SET NO ECHO
	BR	49$
40$:	CLR	.ECHOF		;SET ECHO
	BR	49$
;
;
45$:
	JSR	PC,PRCCAL	;CALL SCML$ TO GET PROC (AND ARGS)
	BR	49$		;THEN GET LINE.
;
;THIS PERMITS LINES OF FORM
;<NAME/ARG0^ARG1^ARG2^ARG3.....ETC
;TO GET INPUT FROM PROCEDURE "NAME.CMD" IN A PREDEFINED UIC
;(ASSEMBLED IN AS [1,200] HERE BUT POTENTIALLY ANY WILL DO)
;AND PASS ARGUMENTS TO IT CONVEINENTLY.

;
; DO MCR
;
;
; FORCE A MCR COMMAND LINE AND REQUEST THE TASK
; WIAT FOR TASK EXIT AND RETURN FOR NEXT LINE
;
; INPUT: R0 POINTS TO THE COMMAND LINE DESCRIPTOR IN THE FDB.
; (R0) IS BYTE COUNT
; 2(R0) IS ADDRESS OF LINE.
;
	.MCALL RQST$,WSIG$S,DIR$
;
;
DOMCR:
	TST	T$FLAG		;CHECK 'TEST FLAG'
	.PSECT
	.EVEN
T$FLAG::	.WORD	0	;(PUT INTO RW AREA)
				;USE TKB COMMAND
				;GBLPAT=T$FLAG:1 TO SET FOR TEST
	.PSECT	PURE,RO
				;	'GBLPAT=T$FLAG:1 TO SET FOR TEST
	BEQ	7$
	JMP	75$	;"BNE 75$"
7$:
	;
	MOV	R0,R5		;SAVE LINE DESCRIPTOR POINTER
;
; FIRST ACQUIRE A MCR BUFFER FROM THE SYSTEM POOL
;
	MOV	#6,R3		;COUNT OF 8-WORD NODES
	CALL	..PICV			;PICK A VARIABLE NODE
;	BCS	80$			;BR IF NO POOL
	BCC	8$
	JMP	80$
8$:
;
; NOW FILL BUFFER WITH ELEMENTARY INFORMATION
;
	MOV	R4,-(SP)		;SAVE BUFFER ADDRESS FOR LATER
;
	MOV	.CRTSK,R0		;GET MY ATL ADDRESS
	MOV	A.TI(R0),M.TI(R4)	;SET MY TI0: POINTER
	ADD	#M.BF,R4		;POINT TO STRING AREA OF BUFFER
	MOV	R4,R3		;SAVE STRING START ADDRESS
;
; COPY INPUT STRING TO BUFFER, COMPRESSING BLANKS AND TABS,
; EXTRACT TASK NAME AND CONVERT TO RAD50. APPEND AN ALTMODE
; TO END OF THE STRING
;
20$:	SUB	#1,(R5)		;COUNT ONE
	BLT	30$		;BR IF LAST
	MOVB	@2(R5),R0	;GET NEXT BYTE
	INC	2(R5)		;AND BUMP POINTER
;
	CMPB	#TAB,R0		;TAB?
	BNE	22$		;NOPE
	MOVB	#SPA,R0		;CHANGE IT TO A SPACE
22$:
	CMPB	#SPA,R0		;SPACE
	BNE	24$		;NOPE
	CMPB	#SPA,-1(R4)	;PREVIOUS A SPACE?
	BEQ	20$		;YES, SKIP MULTI-SPACES
24$:
	MOVB	R0,(R4)+	;PUT IT
	BNE	20$		;GOFER NEXT
	DEC	R4		;ZAP NULL
	BR	20$		;GO FOR NEXT
;
30$:
	MOVB	#ALT,(R4)	;AND PUT A TERMINATION CHARACTER
	SUB	R3,R4		;ADJUST TO COUNT OF CHARACTERS
	BGT	31$
32$:	JMP	65$		;BR IF NULL LINE
31$:
	CMP	#3,R4		;MUST HAVE A 3-CHAR NAME
	BGT	32$		;TREAT AS NULL IF NOT
;
; NOW CHECK FOR COMMENT
;
	CMPB	#'!,(R3)	;IAS COMMENT?
	BEQ	32$
	CMPB	#';,(R3)	;MCR COMMENT?
	BEQ	32$
;
; NOW CONVERT NAME TO RAD50
;
	MOV	R3,R0		;POINT TO STRING
	CLR	R1		;'.' IS A TERMINATOR
	CALL	$CAT5		;CONVERT ONE WORD
;
; SAVE THE NAME IN THE REQUEST DPB
;
	MOV	R1,RQST+R.QSTN+2
	MOV	R2,-(SP)
;CHECK FOR SPECIAL ONES (...MFT REQUEST)
	MOV	#SPTL$T,R2
15$:	CMP	(R2)+,R1	;TASK FUNCTION IN ...MFT TASK?
	BNE	16$		;NO, LEAVE NAME
MFTRAD=51104;RAD50 /MFT/
	MOV	#MFTRAD,RQST+R.QSTN+2	;BASH NAME
16$:	TST	@R2		;AT END OF LIST?
	BNE	15$		;NO, BRANCH AND KEEP LOOKING
	MOV	(SP)+,R2
;
; AND FIRST TRY THE "...XXX" FORM
;
	MOV	DOTS,RQST+R.QSTN+0
;
; NOW TRY REQUEST OF TASK
;
	DIR$	#RQST		;REQUEST TASK
	BCC	39$		;BR IF SUCCESSFUL
	CMP	#IE.INS,$DSW	;NO SUCH TASK ERROR?
	BNE	35$		;BR IF ANOTHER ERROR
;
; ELST, TRY "$$$XXX" FORM OF NAME
;
	MOV	DOLS,RQST+R.QSTN+0
;
; TRY REQUEST AGAIN
;
	DIR$	#RQST		;REQUEST TASK
	BCC	39$
;
; HANDLE 'NO SUCH TASK' OR OTHER FAILURES
;
35$:
	NOP
	BR	65$		;AND RETURN TO CALLER
;
;
; REQUEST SUCCESSFUL.
; LOCATE THE ATL ASSOCIATED WITH THE REQUEST
;
; WE ASSUME HERE THAT THE JUST REQUESTED TASK WILL
; BE THE ONLY TASK IN THE SYSTEM WITH THIS TASK AS THE REQUESTOR.
; IE. THE NODE ACCOUNTING WORD OF THE TASK WILL POINT TO THIS
; TASKS ATL.
;
39$:
	MOV	.CRTSK,R0	;GET OUR ATL
	MOV	A.TD(R0),R1	;GET OUR STD ADDRESS
	MOV	#.ATLLH,R0	;GET ATL CHAIN
;
40$:
	MOV	(R0),R0		;ADVANCE TO NEXT NODE
	CMP	R0,.ATLLH+2	;LAST TASK?
	BEQ	55$		;BAAD STUFF.
	CMP	N.AW(R0),R1	;OUR TASK?
	BNE	40$		;NOPE. TRY NEXT ATL NODE.
	BR	60$		;GO USE TASK
55$:		;CHECK MRL FOR HIM. IF ON MRL, EMIT MSG ANYHOW
	MOV	@.TPDBA,R0	;MRL LISTHEAD IS IN TPD
57$:	CMP	@R0,PRTNAM	;SEE IF OUR PARTITION (USUALLY GEN)
	BEQ	58$		;IF SO, GET MRL ADDR OUT
	ADD	#T.SZ,R0	;ELSE LOOK AT NEXT TPD ENTRY
	CMP	R0,@.TPDEA	;TEST PAST TPD
	BHIS	65$		;LOSE IF SO...
	BR	57$		;UNTIL DONE...
58$:	ADD	#T.RF,R0	;ADD ADDR OFFSET TO MRL LISTHEAD
	MOV	2(R0),MRLLHN	;SAVE END OF MRL ADDR
56$:	MOV	(R0),R0		;ADVANCE TO NEXT NODE
	CMP	R0,MRLLHN	;LAST ONE?
	BEQ	65$		;IF SO, NO HOPE
	CMP	N.AW(R0),R1	;OUR TASK?
	BNE	56$		;NO, KEEP TRYING
;IF STUFF IS NOW ON MRL, MUST TEST TASK NAME TOO!!
	MOV	A.TD(R0),R5	;STD ADDR
	CMP	RQST+R.QSTN+2,S.TN+2(R5)	;TASK NAME (2ND HALF) MATCH?
	BNE	56$		;IF NOT, THIS TASK ISN'T IT...GO ON
60$:
;
; GET THE ADDRESS OF HIS 'COUNT OF ACTIVE VERSIONS' IN HIS STD
;
	MOV	A.TD(R0),R5	;POINT TO HIS STD
	ADD	#S.AV,R5	;BIAS BY OFFSET TO COUNT BYTE
;
; NOW FINISH FILLING MCR BUFFER AND CHAIN IT INTO THE
; MCR BUFFER LIST.
;
	MOV	(SP)+,R1	;GET BUFFER ADDRESS
	MOV	RQST+R.QSTN+2,M.TN(R1);SET IN TASK NAME
	MOV	R4,M.BC(R1)	;SET CHARACTER COUNT OF LINE
	MOV	#.MCRLH,R4		;LIST HEAD ADDRESS
	CALL	..NADD			;ENQUEUE BUFFER
;
; NOW WAIT FOR THE REQUESTED TASK TO EXIT
;
	MOVB	(R5),R0		;GET CURRENT COUNT
	DECB	R0		;REDUCE BY ONE TO PRE-REQUEST LEVEL
;
;*****
;THE COMMENT BELOW APPLIED TO J.E. POLLACK'S 'START' ROUTINE.
;
;*****NOTE--WE ASSUME HERE THAT WHEN THE COUNT OF ACTIVE VERSIONS
;*****IS REDUCED BY ONE THAT THE TASK HAS EXITED. THIS IS DEFINATELY
;*****A KLUDGE. BUT IS THE SIMPLEST TECHNIQUE. THIS METHOD INVALIDATES
;*****THE USE OF THIS TASK IN ANY OTHER SITUATION THAN IMMEDIATELY
;*****AFTER A BOOT BECAUSE OF THE CHANCE OF MORE THAN ONE
;*****ACTIVE COPY OF SOME TASKS.
;********
45$:
	WSIG$S				;WAIT A TICK
;	CMPB	R0,(R5)		;HAS HIS COUNT REDUCED BY ONE?
;	BLT	45$		;BR IF NOT
;	HERE SIMPLY CHECK FOR REQUESTED TASK AGAIN. IF WE
;FIND IT IN THE ATL, THEN HE HASN'T EXITED. OTHERWISE, HE HAS,
;AND SO WE CAN GO ON. THIS TECHNIQUE WILL SERVE TO
;FIND WHEN HE EXITS EVEN IN MULTI-USER TASKS, WHICH EVEN SO HAVE
;UNIQUE ATL ADDRESSES FOR EVERY VERSION.
;
;G.EVERHART 8/76
;
;IN ORDER TO PERMIT MULTIPLE VERSIONS OF THIS TASK, WE WILL
;CHECK THAT THE REQUESTED TASK'S TI IS THE SAME AS OURS TOO.
;SINCE THIS INFORMATION IS IN ATL ENTRIES, IT IS UNIQUE, AND
;IT SHOULD LET EVERY TI RUN ITS OWN COPY OF THIS TASK.
;WITHOUT SUCH A CHECK, THERE CAN BE ONLY ONE VERSION OF THIS
;TASK AROUND AT A TIME.
;
;	GCE
;
;
	MOV	R0,-(SP)	;GET COUPLE REGS
	MOV	R1,-(SP)
	MOV	.CRTSK,R0	;OUR ATL
	MOV	#.ATLLH,R1	;ATL START
42$:	MOV	@R1,R1		;NEXT ATL NODE
	CMP	R1,.ATLLH+2	;TEST END
	BEQ	43$		;END ALL RIGHT
	CMP	N.AW(R1),A.TD(R0)	;POINT AT OUR STL ENTRY?
	BEQ	44$	;IF FOUND HIM, HAVE TO WAIT MORE
	BR	42$	;OR KEEP LOOKING
43$:
	MOV	(SP)+,R1
	MOV	(SP)+,R0	;RESTORE REGS
	BR	75$		;END WAIT
;FOUND HIM. (NOTE. THIS METHOD WILL WORK FOR M/U TASKS, BUT
;ALLOWS ONLY ONE VERSION OF THIS TASK FOR EACH TI:.
44$:
	CMP	N.TI(R0),N.TI(R1)	;HIS TI MATCH OURS?
	BNE	42$			;NO, HAVENT GOT HIM YEY.
	;IF WE FALL THRU, WE FOUND OUR BABY ON THE ATL AND HAVE TO
	;WAIT SOME MORE FOR HIM TO BUZZ OFF.
	MOV	(SP)+,R1
	MOV	(SP)+,R0
	BR	45$		;WAIT MORE
;	BR	75$
;
;
; REQUESTED TASK HAS EXITED, RETURN TO SENDER
;
65$:
	MOV	(SP)+,R1	;RETURN UNUSED BUFFER TO POOL
	MOV	#6,R3
	CALL	..NADV
;
;
75$:
	CLC			;NULL LINE AFTER COMPRESS OR COMMENT
	RETURN
80$:				;NO POOL FOR MCR BUFFER
;
	SEC
	BR	95$		;BAD RETURN
;
95$:	RETURN
PRCCAL:
	;CALL PROCEDURE FROM PRE-DEFINED UIC.
;LINE BEGINS WITH "<" WHICH IS IGNORED HERE
;ANYTHING AFTER A "/" CHARACTER IS TREATED AS PROCEDURE
;ARGUMENTS, SEPARATED BY "^" CHARACTERS.
	MOV	R0,-(SP)	;FIRST SAVE REGS WE NEED
	MOV	R1,-(SP)	;TO LOOK FOR LINES LIKE
	MOV	R2,-(SP)	;"NAME/ARG1^ARG2^ARG3^..."
	MOV	R3,-(SP)
	MOV	@R0,R1		;BYTE COUNT IN LINE
	DEC	R1		;SKIP THE "<"
	BEQ	40$		;(IF NO CHARS LEFT, GET OUT)
	MOV	2(R0),R0	;ADDRESS OF LINE
	INC	R0		;SKIP BY "<"
	MOV	#PRELN2,R2	;OUTPUT LINE ADDR
36$:	MOVB	(R0)+,(R2)+	;STASH A BYTE OUT
	CMPB	@R0,#'/		;GOT TO A / (ARG DELIM?)
	BEQ	37$		;YES, GO PROCESS ARGS TO 2ND LINE
	CMP	R1,#1		;CHECK LAST CHAR
	BEQ	43$		;(NULLS AT END ARE OK)
	CMPB	@R0,#60		;CHECK IT COULD BE A NAME
	BLT	40$		;IF CAN'T, QUIT FAST
	CMPB	@R0,#'Z
	BGT	40$
	CMPB	@R0,#72	;BE SURE IN RANGE 60-71 OR 101-132
	BLT	43$	;OK--NUMERIC
	CMPB	@R0,#101
	BLT	40$	;BAD. ? OR SOMETHING OF THE KIND.
43$:
	SOB	R1,36$	;OTHERWISE KEEP GOING FOR WHOLE LINE
	BR	38$		;THEN GO TO DOUBLE-NULLER
37$:				;GOT BYTES LEFT BUT SAW /.
	CLRB	(R2)+		;THUS, DELIMIT A LINE AND FORCE THE
				;REST ONTO A SEPARATE LINE
34$:	MOVB	(R0)+,(R2)+	;COPY ARGS
	SOB	R1,34$
38$:	CLRB	(R2)+		;SIGNAL ENDLINE
	CLRB	(R2)+		;AND END OF PRESET GROUP.
	SCML$	#GTAB,#PRELN0	;FORCE INPUT TO @ STUFF WANTED.
40$:
	MOV	(SP)+,R3
	MOV	(SP)+,R2	;RESTORE REGS WE USED
	MOV	(SP)+,R1
	MOV	(SP)+,R0
	RTS	PC
	.PSECT		;BACK TO RW AREA
;
;
	.EVEN
SPTL$T:	.RAD50	/ABOALTCANDISENAFIXLOARESUNF/
	.WORD	0,0;FENCE
PRTNAM:	.RAD50	/GEN   / ;PARTITION FOR MRL CHECK
MRLLHN:	.WORD	0	;ADDR OF MRL END
DOTS:	.RAD50 /.../
DOLS:	.RAD50 /$$$/
;
RQST:	RQST$	XXXXXX		;REQUEST DPB
;
ALT=33
SPA=40
TAB=11
;
;
	.END	START