;
;	AUTHOR:
;		R. STODOLA
;		THE INSTITUTE FOR CANCER RESEARCH
;		7701 BURHOLME AVE.
;		PHILADELPHIA, PA.  19111
;
;      *******************************************************
;      *                                                     *
;      *      THIS SOFTWARE WAS DEVELOPED WITH SUPPORT       *
;      *      FROM THE NATIONAL INSTITUTES OF HEALTH:        *
;      *         NIH CA06927                                 *
;      *         NIH CA22780                                 *
;      *                                                     *
;      *      DIRECT INQUIRIES TO:                           *
;      *            COMPUTER CENTER                          *
;      *            THE INSTITUTE FOR CANCER RESEARCH        *
;      *            7701 BURHOLME AVENUE                     *
;      *            PHILADELPHIA, PENNSYLVANIA   19111       *
;      *                                                     *
;      *      NO WARRANTY OR REPRESENTATION, EXPRESS OR      *
;      *      IMPLIED, IS MADE WITH RESPECT TO THE           *
;      *      CORRECTNESS, COMPLETENESS, OR USEFULNESS       *
;      *      OF THIS SOFTWARE, NOR THAT USE OF THIS         *
;      *      SOFTWARE MIGHT NOT INFRINGE PRIVATELY          *
;      *      OWNED RIGHTS.                                  *
;      *                                                     *
;      *      NO LIABILITY IS ASSUMED WITH RESPECT TO        *
;      *      THE USE OF, OR FOR DAMAGES RESULTING FROM      *
;      *      THE USE OF THIS SOFTWARE                       *
;      *                                                     *
;      *******************************************************
;      *                                                     *
;      *      THIS SOFTWARE WAS DESIGNED FOR USE ON A        *
;      *      PDP-11/70 OPERATING UNDER IAS V2.0 USING       *
;      *      THE IAS PDP-11 MACRO ASSEMBLER.                *
;      *                                                     *
;      *******************************************************
	.TITLE	GENC  -- GEN PARTITION COUNTER
	.IDENT	/ICR001/
	.MCALL	MRKT$,WTSE$,GTIM$,EXIT$,DIR$
	.PSECT	GENP	RW,D
WD=.				;LIST OF 15 MINUTE INTERVALS
.=.+192.
;
	.PSECT
;
GT:	GTIM$	TMBF
EX:	EXIT$
MR:	MRKT$	1,3375.,1	;(15 MINS)*(3600 TICKS/MIN)/(16 SAMPLES/PERIOD)
WT:	WTSE$	1
TMBF:	.BLKW	8.
;
GENC:	MOV	@#.TPDBA,R4	;GET GEN TPD
LOOP0:	CMP	T.PN(R4),#^RGEN
	BNE	10$
	CMP	T.PN+2(R4),#^R   
	BNE	10$
	MOV	T.HP(R4),R4	;GET MUL HEADER
	BEQ	20$		;BAD ERROR.
	ADD	#M.TS,R4	;GET FREE SPACE INDICATER ADDRESS.
	BR	START		;GO DO IT.
10$:	ADD	#T.SZ,R4	;NOT HERE, SO CHECK OUT NEXT TPD ENTRY.
	CMP	@#.TPDEA,R4	;ABORT IF LAST.
	BNE	LOOP0
20$:	DIR$	#EX
START:
	MOV	#16.,R5
LOOP1:	DIR$	#GT		;GET TIME OF DAY
	MOV	TMBF+G.TIMI,R3	;CONVERT TO 15 MINUTE PERIOD NUMBER
	CLR	R2
	DIV	#15.,R2
	MOV	TMBF+G.TIHR,R3
	ASL	R3
	ASL	R3
	ADD	R2,R3
	ASL	R3		;SHIFT TO WORD ADDRESS
	MOV	R5,R2		;SET COUNT
	CLR	R0		;CLEAR INITIAL SUM
	CLR	R1
LOOP2:	ADD	(R4),R1		;ADD IN FREE SPACE.
	ADC	R0
	DIR$	#MR		;WAIT 1/16TH PERIOD
	DIR$	#WT
	DEC	R2		;SEE IF DONE.
	BGT	LOOP2		;NO.
	ASHC	#-4,R0		;DONE, SO DIVIDE SUM BY 16.
	MOV	R1,WD(R3)	;SAVE AVERAGE IN TABLE.
	BR	LOOP1
	.END	GENC