.TITLE	INDCMD - INDIRECT FILE PROCESSOR COMMAND PROCESSOR
	.IDENT	/03JAN8/							;MPK004
;                                                                               ;**-1
;
; COPYRIGHT   1975,  DIGITAL  EQUIPMENT  CORP.,  MAYNARD,   MASS.
;
; THIS SOFTWARE IS FURNISHED TO PURCHASER UNDER A LICENSE FOR USE
; ON A  SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH INCLUSION
; OF DEC'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH SYSTEM, EXCEPT
; AS MAY OTHERWISE BE PROVIDED IN WRITING BY DEC.
;
; THE  INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT
; NOTICE AND  SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL
; EQUIPMENT CORPORATION.
;
; DEC  ASUMES NO  RESPONSIBILITY  FOR  THE  USE  OR RELIABILITY
; OF ITS  SOFTWARE ON  EQUIPMENT WHICH  IS NOT SUPPLIED BY DEC.
;
;VERSION:	03JAN8								;MPK004
; BY:		H.LEV                                                           ;**-1
; DATE:		6/16/75 BREAK THIS MODULE OFF FROM INDRCT
;                                                                               ;HJL007
;	HJL007	4/9/76 ADD OPEN, CLOSE, DATA, ENABLE AND DISABLE                ;HJL007
;                                                                               ;HJL007
;	HJL024	2/15/76  ADD STRING SUBSTITUTION                                ;HJL007
;                                                                               ;HJL007
;	JMM031	6/11/76	INCLUDE RSX-11D CONDITIONAL CODE                        ;JMM031
;                                                                               ;JMM031
;                                                                               ;JMM031
;	RSK001	01-DEC-76	R. KITTELL, LASL MP-3 -- ADDED PURE PSECT
;	RSK002	07-MAR-77	R. KITTELL, LASL MP-3 -- INCLUDED BELL
;				 CHARACTER IN QUESTION PROMPTS.
;	MPK001	18-JUL-77	M. KELLOGG, MP-1 - CHANGE CLR IN $DATER
;				TO CLRB
;	MPK002	29-DEC-77	GET RID OF '...AT. DELAYING' AND
;				'...AT. CONTINUING' MESSAGES IN .WAIT
;				UNLESS TRACE IS ON.
;	MPK003	30-DEC-77	ADD GLOBAL SYMBOL CAPABILITY FROM 11M
;				RELEASE VERSION
;	MPK004	3-JAN-78	TAKE OUT DEFS OF LIFLG BITS, SINCE THEY
;				ARE NOW GLOBALED IN INDRCT.MAC
;
; THIS PROGRAM PROVIDES A MEANS OF GIVING MCR COMMANDS FROM                     ;**-1
; A FILE.
;

;
; MACRO LIBRARY CALLS
;
	.MCALL	GCMLD$
	GCMLD$	DEF$L
	.MCALL	DIR$,RETURN,WTSE$S
	.MCALL	SPND$S,CSI$1,CSI$2,CLOSE$,OFNB$W,PUT$                           ;HJL007
                                                                                ;**-1
;
; EQUATED SYMBOLS
;
CR	=	15		; CARRIAGE RETURN
ESC	=	33		; ESCAPE
LUN1	=	1		; "TI" LUN
LUN2	=	2		; FILE LUN
EFN1	=	1		; EVENT FLAG TO WAIT ON
SYMSIZ	=	6.		; SYMBOL SIZE IN CHARACTERS
STRLEN	=	16.		; MAX STRING LENGTH                             ;HJL024
;                                                                               ;HJL024
; SYMBOL TYPE                                                                   ;HJL024
;                                                                               ;HJL024
TF	=	1		; LOGICAL                                       ;HJL024
NUM	=	2		; NUMERIC                                       ;HJL024
STR	=	3		; STRING                                        ;HJL024
;
; BIT DEFINITIONS FOR LIFLG
;
;	THESE ARE NOW ALL DEFINED GLOBALLY IN THE INDRCT MODULE			;MPK004
;
; BIT DEFINTITIONS FOR $LOGFL
;
LGCL	=	1		; LOGICAL FUNCTION IN PROGRESS
AND	=	2		; FUNCTION IS AND 1=YES
GO	=	4		; ALLOW COMMAND TO EXECUTE 1=YES
IFTST	=	10		; IF SEEN PREVIOUS TO CURRENT COMMAND 1=YES
;
; LOCAL DATA
;
ANS:	.BLKB	STRLEN+1	; ANSWER BUFFER , ROOM FOR MAX STRING           ;HJL024
	.EVEN
	.PSECT	PURE,RO,I,GBL,CON
YESNO:	.ASCIZ	%? [Y/N]:%<7>	; QUESTION SUFFIX                               ;**RSK002
STNG:	.ASCIZ	% [S]: %<7>	; STRING QUESTION SUFFIX                        ;RSK002
NMBR:	.ASCIZ	% [N]: %<7>	; NUMBER QUESTION PREFIX                        ;RSK002
                                                                                ;HJL024
ENATXT:	.ASCIZ	/SUBSTITUTION/	;                                               ;HJL024
	.ASCIZ	/DATA/		;                                               ;HJL024
	.ASCIZ	/GLOBAL/							;MPK003
	.BYTE	0		;                                               ;HJL024
	.EVEN                                                                   ;HJL024
	.PSECT
ENAADD:	.WORD	DEFSUB		; DEFAULT TO SUBSTITUTION                       ;HJL024
	.WORD	DEFDAT		; DEFAULT TO DATA                               ;HJL024
	.WORD	DEFGLS		; GLOBAL SYMBOLS				;MPK003

; BRANCH TABLE FOR IF TEST FOR LOGICAL AND NUMERICS                             ;HJL024
;                                                                               ;HJL024
	.PSECT	PURE
SNGTST:	BEQ	20$		; IF EQ                                         ;HJL024
	BR	10$		;                                               ;HJL024
	BNE	20$		; IF NE                                         ;HJL024
	BR	10$		;                                               ;HJL024
	BHIS	20$		; IF GE                                         ;HJL024
	BR	10$		;                                               ;HJL024
	BHI	20$		; IF GT                                         ;HJL024
	BR	10$		;                                               ;HJL024
	BLOS	20$		; IF LE                                         ;HJL024
	BR	10$		;                                               ;HJL024
	BLO	20$		;                                               ;HJL024
10$:	JMP	FALSE		; TEST IS FALSE                                 ;HJL024
20$:	JMP	TRUE		; TEST IS TRUE                                  ;HJL024
                                                                                ;HJL024
;                                                                               ;HJL024
; IF COMMAND CONDITIONALS                                                       ;HJL024
;                                                                               ;HJL024
CNDNL:	.ASCIZ	/EQ/		;                                               ;HJL024
	.ASCIZ	/=/		;                                               ;HJL024
	.ASCIZ	/NE/		;                                               ;HJL024
	.ASCIZ	/<>/		;                                               ;HJL024
	.ASCIZ	/GE/		;                                               ;HJL024
	.ASCIZ	/>=/		;                                               ;HJL024
	.ASCIZ	/GT/		;                                               ;HJL024
	.ASCIZ	/>/		;                                               ;HJL024
	.ASCIZ	/LE/		;                                               ;HJL024
	.ASCIZ	/<=/		;                                               ;HJL024
	.ASCIZ	/LT/		;                                               ;HJL024
	.ASCIZ	/</		;                                               ;HJL024
	.BYTE	0		;                                               ;HJL024
	.EVEN			;                                               ;HJL024

	.SBTTL	INDIRECT FILE COMMAND PROCESSOR
;+
; *** - $PRCMD  -  PROCESS INDIRECT FILE PROCESSOR COMMANDS
;
;	THESE COMMANDS ARE FLAGGED BY A PERIOD (.) IN CHARACTER
;	POSITION ONE OF THE LINE.
; INPUT:
;	R0 - ADDRESS OF FIRST CHARACTER IN LINE (PERIOD)
;
;-
$PRCMD:: TSTB	(R0)+		; SKIP PERIOD
	BIT	#SKIP,.LIFLG	; SEARCHING FOR LABEL?
	BEQ	INDC		; NO
	JMP 	$LABEL		; YES, GO PROCESS THIS LIKE A LABEL
INDC:	MOV	#$CMDTB,R2	; POINT TO VALID COMMANDS
	CALL	$TBSRC		; SEARCH TABLE FOR COMMAND                      ;HJL007
	BCC	50$		;                                               ;HJL007
	MOV	$TIBUF,R2	; GET STARTING ADDRESS OF BUFFER                ;**-9
	INC	R2		; POINT TO SECOND CHARACTER
	CMP	R0,R2		; ARE WE AT THE SECOND CHARACTER?
	BEQ	50$		; YES, IT MUST BE A LABEL
	JMP	$SYNER		; NO, SYNTAX ERROR
50$:	BIT	#DATFIL,.LIFLG	; IS DATA FILE OPEN?                            ;HJL007
	BEQ	60$		; NO                                            ;HJL007
	BIT	#DEFDAT,.LIFLG	; YES, DEFAULT TO DATA FILE?                    ;HJL007
	BEQ	60$		; NO                                            ;HJL007
	CMP	$PROTB(R1),#$DSABL ; YES, IS COMMAND DISABLE?                   ;HJL007
	BEQ	60$		; YES                                           ;HJL007
	CMP	$PROTB(R1),#$CLOSE ; NO, IS IT CLOSE?                           ;HJL007
	BEQ	60$		; YES                                           ;HJL007
	BIS	#FLUSH,.LIFLG	; NO, FLUSH COMMANDS                            ;HJL007
	JMP	$SYNER		; COMMAND ERROR                                 ;HJL007
60$:	JMP	@$PROTB(R1)	; GO TO COMMAND PROCESSOR                       ;HJL007

	.SBTTL	PAUSE AND DELAY PROCESSING
;
; PAUSE COMMAND
;
$PAUSE:: CALL	$GOTST		; TEST IF ALL CONDITIONS GO FOR THIS COMMAND
	BCS	10$		; NO
	CALL	$DSPLY		; DISPLAY COMMAND
	INC	$CMDFL		; SET COMMAND IN PROGRESS FLAG
	MOV	#$SYM13,R0	; GET ADDRESS OF PLACE TOP PUT TASK NAME
	.IF DF R$$11D                                                           ;JMM031
	MOV	.CRTSK,R4	; GET OUR ATL ADDRESS                           ;JMM031
	MOV	A.TD(R4),R4	; GET OUR STD ADDRESS                           ;JMM031
	MOV	S.TN(R4),R1	; GET FIRST HALF OF TASK NAME                   ;JMM031
	CALL	$C5TA		; CONVERT TO ASCII                              ;JMM031
	MOV	S.TN+2(R4),R1	; GET SECOND HALF                               ;JMM031
	.IFF                                                                    ;JMM031
	MOV	$TKTCB,R4	; GET OUR TCB ADDRESS
	MOV	T.NAM(R4),R1	; GET TASK NAME
	CALL	$C5TA		; CONVERT TO ASCII
	MOV	T.NAM+2(R4),R1	;
	.IFTF                                                                   ;JMM031
	CALL	$C5TA		;
	MOV	#-1,$SBFLG	; SET TO SUPPRESS COMMAND LINE                  ;HJL024
	CALL	$ATE13		; SEND PAUSING MESSAGE
	.IFT                                                                    ;JMM031
$$PAUS	==.			; GLOBAL TAG FOR MESSAGE ROUTINE                ;JMM031
	.ENDC                                                                   ;JMM031
	SPND$S			; SUSPEND US
	INC	$CMDFL		; SET COMMAND IN PROGRESS
	MOV	#-1,$SBFLG	; SET TO SUPPRESS COMMAND LINE                  ;HJL024
	CALL	$ATE14		; SEND CONTINUING MESSAGE
10$:	JMP	$INDRD		; READ NEXT COMMAND
;
; DELAY COMMAND  - FORMAT "DELAY NNNU" NNN - COUNT, U - UNIT
;
$DELAY:: CALL	$GOTST		; TEST FOR GO FLAG
	BCS	15$		; CAN'T GO
	CALL	$GNBLK		; GET NEXT NON-BLANK
	BCS	20$		; EOL IS ERROR
	DEC	R0		; BACK UP TO POINT TO FIRST CHARACTER
	CALL	$GTNUM		; GET COUNT OF UNITS
	MOV	#1,R3		; SET UNIT TO TICKS
	CMPB	R2,#'T		; TICKS?
	BEQ	10$		; YES
	INC	R3		;
	CMPB	R2,#'S		; SECONDS?
	BEQ	10$		; YES
	INC	R3		; NO
	CMPB	R2,#'M		; MINUTES?
	BEQ	10$		; YES
	INC	R3		; NO
	CMPB	R2,#'H		; HOURS?
	BNE	20$		; NO ERROR
10$:	MOV	R1,$MKTIM+4	; SET COUNT OF UNITS
	MOV	R3,$MKTIM+6	; SET UNITS CODE
	CALL	$DSPLY		; DISPLAY COMMAND
	BIT	#NOTRAC,.LIFLG	;SEND MSG ONLY IF TRACING			;MPK002
	BNE	11$								;MPK002
	INC	$CMDFL		; SET COMMAND IN PROGRESS
	MOV	#-1,$SBFLG	; SET TO SUPPRESS COMMAND LINE                  ;HJL024
	CALL	$ATE15		; SEND DELAYING MESSAGE
11$:	DIR$	#$MKTIM		; ISSUE MARK TIME
	BCS	15$		; ERROR
	WTSE$S	#EFN1		; WAIT TILL TIME IS UP
	BIT	#NOTRAC,.LIFLG	;SEND MSG ONLY IF TRACING			;MPK002
	BNE	15$								;MPK002
	INC	$CMDFL		; SET COMMAND IN PROGRESS
	MOV	#-1,$SBFLG	; SET TO SUPPRESS COMMAND LINE                  ;HJL024
	CALL	$ATE14		; SEND CONTINUING MESSAGE
15$:	JMP	$INDRD		; READ NEXT COMMAND
20$:	JMP	$ATE12		; COMMAND OR SYNTAX ERROR

	.SBTTL	WAIT AND XQT COMMANDS
	.ENABL	LSB
;
; WAIT COMMAND FORMAT  ".WAIT TTTTTT"    TTTTTT-TASK NAME
;
$WAIT::	CALL	$GOTST		; CAN WE GO
	BCS	60$		; NO
	CALL	$DSPLY		; DISPLAY COMMAND                               ;HJL025
	CALL	$GETTK		; GET TASK NAME
	BCS	100$		; SYNTAX ERROR
	BEQ	NOTINS		; TASK NOT IN SYSTEM
	.IF DF R$$11D                                                           ;JMM031
50$:	MOV	#$TSKNM,R3	; GET ADDRESS OF TASK NAME                      ;JMM031
	CALL	$GTTSK		; LOOK FOR TASK IN ATL AND MRL'S                ;JMM031
	BCS	60$		; NOT FOUND IF CARRY SET                        ;JMM031
	CMP	R0,.CRTSK	; FOUND -- IS IT US?                            ;JMM031
	BEQ	60$		; YES -- JUST CONTINUE                          ;JMM031
	MOV	#2,$MKTIM+4	; SET FLAG IN 2...
	MOV	#2,$MKTIM+6	; ...SECONDS
	DIR$	#$MKTIM		; START COUNTDOWN
	WTSE$S	#EFN1		; WAIT FOR FLAG
	BR	50$		; TRY AGAIN                                     ;JMM031
	.IFF                                                                    ;JMM031
50$:	MOV	$TKTCB,R3	; GET OUR TCB ADDRESS
	MOV	T.UCB(R3),R3	; GET TI UCB ADDRESS
	CMP	$TSKNM,T.NAM(R2) ; TASK NAME SAME AS ASKED FOR?
	BNE	53$		; NO
	CMP	$TSKNM+2,T.NAM+2(R2) ; MAYBE
	BEQ	57$		; YES, DON'T CHECK TCB, SINCE WE FOUND THE TASK
53$:	CMP	R3,T.UCB(R2)	; NO, CHECK THAT TI UCB IS THE SAME
	BNE	60$		; NO, NO NEED TO WAIT
57$:	TST	T.STAT(R2)	; TASK ACTIVE?
	BMI	60$		; NO
	CALL	$NULSB		; YES, WAIT A WHILE
	MOV	#$TSKNM,R3	; POINT TO TASK NAME
	CALL	$GTTSK		; FIND TASK
	BCS	60$		; NOT THERE NOW
	MOV	R0,R2		; COPY TCB ADDRESS
	BR	50$		; AND LOOP
	.ENDC                                                                   ;JMM031
60$:	JMP	$INDRD		; GET NEXT COMMAND
NOTINS:	MOV	#$SYM20,R0	; GET ADDRESS FOR TASK IMAGE
	MOV	$TSKNM,R1	; GET TASK NAME
	CALL	$C5TA		; CONVERT TO ASCII
	MOV	$TSKNM+2,R1	; GET TASK NAME
	CALL	$C5TA		; CINVERT TO ASCII
	CLRB	(R0)		; SET END OF LINE
	JMP	$ATE20		; TASK NOT IN SYSTEM
100$:	JMP	$ATE12		; SYNTAX ERROR

;
; IMMEDIATE EXECUTION, DON'T WAIT FOR COMMAND TO BE DONE
;
$XQT::	CALL	$GOTST		; CAN WE CONTINUE?
	BCS	60$		; NO
	CALL	$DSPLY		; DISPLAY LINE IF NECCESSARY
	BIS	#IMXQT,.LIFLG	; SET IMMEDIATE EXECUTION FLAG
	CALL	$GNBLK		; GET NEXT NON-BLANK
	BCS	100$		; EOL IS SYNTAX ERROR
	TST	R1		; ANY BLANKS?
	BEQ	100$		; NO, SYNTAX ERROR
	MOVB	#'!,@$TIBUF	; SET COMMENT FOR BEGINING
	DEC	R0		; BACK UP CHARACTER POINTER
	JMP	$INTST		; EXECUTE MCR COMMAND
	.DSABL	LSB

	.SBTTL	ASK PROCESSOR
	.ENABL	LSB
$ASK::	MOV	#TF,R1		; SET SYMBOL TYPE TO LOGICAL                    ;HJL024
	BR	ASK		;                                               ;HJL024
$ASKN::	MOV	#NUM,R1		; SET SYMBOL TYPE TO NUMBER                     ;HJL024
	BR	ASK		;                                               ;HJL024
$ASKS::	MOV	#STR,R1		; SET SYMBOL TYPE TO STRING                     ;HJL024
                                                                                ;HJL024
ASK:	MOVB	R1,$SYMTP	; SET SYMBOL TYPE                               ;HJL024
	CALL	$GOTST		; CAN WE GO?                                    ;HJL024
	BCS	70$		; NO                                            ;HJL024
	CALL	$DSPLY		; DISPLAY COMMAND                               ;HJL024
	CALL	$PRSYM		; PARSE SYMBOL AND LOCATE TABLE ENTRY           ;HJL024
	MOV	#$BUF,R1		; SET OUTPUT BUFFER ADDRESS             ;**-1
	MOV	#1,R3		; SET INITIAL CHARACTER COUNT
	MOVB	#'*,(R1)+	; PUT IN QUESTION INDICATOR
25$:	MOVB	(R0)+,R2	; YES, GET NEXT CHARACTER                       ;**-4
	CMPB	R2,#15		; CR?
	BEQ	30$		; YES
	CMPB	R2,#33		; ESC?
	BEQ	30$		; YES
27$:	MOVB	R2,(R1)+	; NO, PUT IN CHARCTER
	INC	R3		; INCREMENT CHARACTER COUNT
	BR	25$		; LOOP
30$:	CMPB	#TF,$SYMTP	; IS THIS LOGICAL SYMBOL?                       ;HJL024
	BNE	32$		; NO                                            ;HJL024
	MOV	#YESNO,R2	; YES, SET QUESTION SUFFIX                      ;HJL024
	CALL	$MOVE		; MOVE IT TO BUFFER                             ;**-1
	ADD	#9.,R3		; INDEX BUFFER COUNT
	BR	40$		;                                               ;HJL024
32$:	CMPB	#NUM,$SYMTP	; IS THIS NUMERIC SYMBOL?                       ;HJL024
	BNE	34$		; NO                                            ;HJL024
	MOV	#NMBR,R2	; YES, SET NUMERIC QUESTION SUFFIX              ;HJL024
	CALL	$MOVE		; MOVE IT INTO BUFFER                           ;HJL024
	ADD	#7.,R3		; UPDATE BUFFER LENGTH                          ;HJL024
	BR	40$		;                                               ;HJL024
34$:	MOV	#STNG,R2	; MUST BE STRING TYPE                           ;HJL024
	CALL	$MOVE		; MOVE IN STRING QUESTION SUFFIX                ;HJL024
	ADD	#7.,R3		; UPDATE BUFFER LENGTH                          ;HJL024
40$:	MOV	R3,$TIBUF+2	; SET BUFFER LENGTH
	MOV	#$BUF,$TIBUF	; SET BUFFER ADDRESS
	CLR	$TIBUF+4		; ZERO CARRIAGE CONTROL
41$:	CALL	$TIIO		; WRITE IT OUT
	BCS	80$		; ERROR
;
; READ ANSWER AND SET TRUE/FALSE FLAG
;
42$:	MOV	#IO.RVB,$TIDPB+2	; SET READ VIRTUAL BLOCK
	MOV	#ANS,R0		; GET INPUT BUFFER ADDRESS                      ;HJL024
	MOV	#STRLEN+1,R1	; GET INPUT BUFFER LENGTH                       ;HJL024
	MOV	R0,$TIBUF	; SET BUFFER ADDRESS                            ;HJL024
	MOV	R1,$TIBUF+2	; SET BUFFER LENGTH                             ;HJL024
421$:	CLRB	(R0)+		; ZERO NEXT BYTE                                ;HJL024
	DEC	R1		; DONE?                                         ;HJL024
	BGT	421$		; NO, LOOP UNTIL IT IS                          ;HJL024
43$:	CALL	$TIIO		; READ IN ANSWER                                ;**-2
	BCS	80$		; ERROR
45$:	MOV	#IO.WVB,$TIDPB+2	; SET WRITE FUNCTION BACK
	MOV	#ANS,R0		; GET ANSWER                                    ;HJL024
	MOV	$TIOST+2,R1	; GET NUMBER OF CHARACTERS READ                 ;HJL024
	CMPB	$SYMTP,#TF	; LOGICAL?                                      ;HJL024
	BNE	100$		; NO                                            ;HJL024
	CLRB	(R5)		; DEFAULT TO FALSE                              ;HJL024
	TST	R1		; ANY CHARACTERS READ?                          ;HJL024
	BEQ	47$		; NO, NO DEFAULT
	BICB	#40,ANS		; CONVERT LOWER CASE RESPONSE TO UPPER CASE
	CMPB	#'Y,ANS		; IS IT YES?
	BEQ	50$		; YES
	CMPB	#'N,ANS		; NO, IS IT NO?
	BEQ	60$		; YES
47$:	INC	$CMDFL		; SET COMMAND IN PROGRESS                       ;HJL024
	MOV	#-1,$SBFLG	; SET NOT TO PRINT COMMAND LINE                 ;HJL024
	CALL	$ATE18		; INVALID ANSWER                                ;**-1
	BR	40$		; LOOP
50$:	MOVB	#1,(R5)		; SET TRUE                                      ;HJL024
60$:	MOV	#$PMPT,$TIBUF	; SET PROMPT ADDRESS                            ;**-1
	.IF DF R$$11D                                                           ;JMM031
	MOV	#6,$TIBUF+2	; SET LENGTH                                    ;JMM031
	.IFF                                                                    ;JMM031
	MOV	#3,$TIBUF+2	; SET LENGTH
	.ENDC                                                                   ;JMM031
	CLR	$TIBUF+4		; SET NO CARRIAGE CONTROL
	CALL	$TIIO		; WRITE IT OUT
	BCS	80$		; ERROR
70$:	JMP	$INDRD		; READ IN NEXT LINE
80$:	CLR	$CMDFL		; I/O ERROR
	JMP	$INXIT
90$:	JMP	$SYNER		; SYNTAX ERROR
100$:	CMPB	$SYMTP,#STR	; IS SYMBOL A STRING?                           ;HJL024
	BNE	130$		; NO                                            ;HJL024
	CMP	R1,#STRLEN	; IS IT OF VALID SIZE?                          ;HJL024
	BGT	47$		; NO, ERROR                                     ;HJL024
	TST	R1
	BLE	47$
	MOV	#STRLEN,R1	; MOVE THE WHOLE STRING                         ;HJL024
120$:	MOVB	(R0)+,(R5)+	; MOVE IN CHARACTER                             ;HJL024
	DEC	R1		; DONE?                                         ;HJL024
	BGT	120$		; NO, LOOP                                      ;HJL024
	BR	60$		; YES                                           ;HJL024
130$:	CMP	R1,#STRLEN	; LESS THAN MAX CHARACTERS?                     ;HJL024
	BGT	47$		; NO                                           ;HJL024
	TST	R1
	BLE	47$
	ADD	R0,R1		; POINT TO LAST CHARACTER+1                     ;HJL024
	CLRB	(R1)		; ZERO IT OUT                                   ;HJL024
	CALL	$GTNUM		; CONVERT TO NUMBER                             ;HJL024
	CMP	R1,#255.	; VALID NUMBER?                                 ;HJL024
	BGT	47$		; NO, ERROR                                     ;HJL024
	MOVB	R1,(R5)		; SET SYMBOL VALUE                              ;HJL024
	BR	60$		;                                               ;HJL024
	.DSABL	LSB		;                                               ;HJL024

	.SBTTL	SETF AND SETF PROCESSOR
;
; SETT - SET SYMBOL TRUE
;
$SETT::	MOV	#1,$COND	; SET VALUE TO TRUE
	BR	SET		;
;
; SETF - SET SYMBOL FALSE
;
$SETF::	CLR	$COND		; SET VALUE FALSE
;
; COMMON SET CODE
;
SET:	MOVB	#TF,$SYMTP	; SET SYMBOL TYPE TO LOGICAL                    ;HJL024
	CALL	$GOTST		; CAN WE GO?                                    ;HJL024
	BCS	10$		; NO                                            ;HJL024
	CALL	$DSPLY		; YES, DISPLAY COMMAND                          ;HJL024
	CALL	$PRSYM		; PARSE SYMBOL                                  ;HJL024
	MOVB	$COND,(R5)	; SET VALUE                                     ;HJL024
10$:	JMP	$INDRD		; GET NEXT LINE FROM FILE                       ;HJL024
                                                                                ;HJL024
	.ENABL	LSB                                                             ;HJL024
$SETS::	MOVB	#STR,$SYMTP	; SET SYMBOL AS STRING                          ;HJL024
	CALL	$GOTST		; CAN WE GO?                                    ;HJL024
	BCS	40$		; NO                                            ;HJL024
	CALL	$DSPLY		; YES, DISPLAY COMMAND                          ;HJL024
	CALL	$PRSYM		; PARSE SYMBOL                                  ;HJL024
	MOV	R5,R4		; GET ADDRESS  OF STRING                        ;HJL024
	CALL	$GNBLK		; GET NEXT CHARACTER                            ;HJL024
	BCS	50$		; SYNTAX ERROR                                  ;HJL024
	CMPB	R2,#'"		; YES, IS FIRST CHARACTER QUOTE?                ;HJL024
	BNE	50$		; NO                                            ;HJL024
	MOV	#STRLEN,R4	; YES, SET MAX LENGTH OF STRING                 ;HJL024
20$:	MOVB	(R0)+,R2	; GET NEXT CHARACTER                            ;HJL024
	CMPB	R2,#15		; EOL?                                          ;HJL024
	BEQ	40$		; YES                                           ;HJL024
	CMPB	R2,#33		; EOL?                                          ;HJL024
	BEQ	40$		; YES                                           ;HJL024
	CMPB	R2,#'"		; END OF STRING?                                ;HJL024
	BEQ	40$		; YES                                           ;HJL024
	DEC	R4		; ROOM FOR MORE?                                ;HJL024
	BMI	50$		; NO, SYNTAX ERROR                              ;HJL024
	MOVB	R2,(R5)+	; YES, STORE NEXT CHARACTER                     ;HJL024
	BR	20$		; LOOP                                          ;HJL024
40$:	JMP	$INDRD		; GET NEXT LINE                                 ;HJL024
50$:	JMP	$SYNER		; SYNTAX ERROR                                  ;HJL024
                                                                                ;HJL024
$SETN:: MOVB	#NUM,$SYMTP	; SET SYMBOL TYPE TO NUMERIC                    ;HJL024
	CALL	$GOTST		; CAN WE GO?                                    ;HJL024
	BCS	40$		; NO                                            ;HJL024
	CALL	$DSPLY		; YES, DISPLAY COMMAND                          ;HJL024
	CALL	$PRSYM		; GET SYMBOL TABLE ENTRY                        ;HJL024
	CALL	$GNBLK		; GET NEXT CHARACTER                            ;HJL024
	BCS	50$		; EOL IS ERROR                                  ;HJL024
	DEC	R0		; BACK UP                                       ;HJL024
	CALL	$GTNUM		; GET NUMBER                                    ;HJL024
	CMP	R1,#255.	; IS IT VALID?                                  ;HJL024
	BGT	50$		; NO, ERROR                                     ;HJL024
	MOVB	R1,(R5)		; STORE VALUE                                   ;HJL024
	BR	40$		;                                               ;HJL024
	.DSABL	LSB                                                             ;HJL024

	.SBTTL	IFXXXX, AND, & OR FUNCTIONS
	.ENABL	LSB
$IFINS:: CALL	$GETTK		; SEARCH FOR TASK
	BCS	IFERR		; SYNTAX ERROR
	BEQ	FALSE		; NOT INSTALLED
	BR	TRUE		; FOUND IT
$IFNIN:: CALL	$GETTK		; SEARCH FOR TASK
	BCS	IFERR		; SYNTAX ERROR
	BEQ	TRUE		; NOT INSTALLED
	BR	FALSE		; FOUND IT
$IFACT:: CALL	$GETTK		; SEARCH FOR TASK
	BCS	IFERR		; SYNTAX ERROR
	BNE	IFA1		; FOUND IT
	JMP	NOTINS		; NOT INSTALLED
IFA1:                                                                           ;JMM031
	.IF DF R$$11D                                                           ;JMM031
	MOV	#$TSKNM,R3	; GET ADDRESS OF TASK NAME                      ;JMM031
	CALL	$CKTSK		; LOOK FOR TASK IN ATL AND MRL'S                ;JMM031
	BCS	FALSE		; NOT FOUND IF CARRY SET                        ;JMM031
	.IFF                                                                    ;JMM031
	TST	T.STAT(R2)	; IS IT ACTIVE?                                 ;JMM031
	BMI	FALSE		; NO                                            ;**-1
	.ENDC                                                                   ;JMM031
	BR	TRUE		; YES
$IFNAC:: CALL	$GETTK		; SEARCH FOR TASK
	BCS	IFERR		; SYNTAX ERROR
	BNE	IFNA1		; FOUND IT
	JMP	NOTINS		; NOT INSTALLED
IFNA1:                                                                          ;JMM031
	.IF DF R$$11D                                                           ;JMM031
	MOV	#$TSKNM,R3	; GET ADDRESS OF TASK NAME                      ;JMM031
	CALL	$CKTSK		; LOOK FOR TASK IN ATL AND MRL'S                ;JMM031
	BCS	TRUE		; NOT FOUND IF CARRY SET                        ;JMM031
	.IFF                                                                    ;JMM031
	TST	T.STAT(R2)	; IS IT ACTIVE?                                 ;JMM031
	BMI	TRUE		; NO                                            ;**-1
	.ENDC                                                                   ;JMM031
	BR	FALSE		; YES
$IFDF:: CALL	$GTSYM		; GET SYMBOL NAME
	BCS	IFERR		; SYNTAX ERROR
	CALL	$SRSYM		; SEARCH FOR SYMBOL
	BCS	FALSE		; NOT DEFINED
	BR	TRUE		; DEFINED
$IFNDF:: CALL	$GTSYM		; GET SYMBOL NAME
	BCS	IFERR		; SYNTAX ERROR
	CALL	$SRSYM		; SEARCH FOR SYMBOL
	BCS	TRUE		; NOT DEFINED
	BR	FALSE		; DEFINED
$IFT:: MOV	#1,$COND	; SET UP TRUE CONDITION
	BR	IF		;
$IFF:: CLR	$COND		; SET UP FALSE CONDITION
IF:	CALL	$GTSYM		; GET SYMBOL
	BCS	IFERR		; SYNTAX ERROR
10$:	CALL	$SRSYM		; LOCATE SYMBOL IN SYMBOL TABLE
	BCC	20$		; FOUND IT
	JMP	UDFSYM		; UNDEFINED SYMBOL
20$:	CMPB	SYMSIZ(R5),#TF	; IS THIS A LOGICAL SYMBOL?                     ;HJL024
	BEQ	21$		; YES                                           ;HJL024
	JMP	$TYPER		; NO, SYMBOL TYPE ERROR                         ;HJL024
21$:	CMPB	$COND,SYMSIZ+1(R5) ; CONDITION TRUE?                            ;HJL024
	BEQ	TRUE		; YES                                           ;**-1
FALSE:	INC	$IFCNT		; INCREMENT NUMBER OF IFS SEEN
	BIT	#IFTST,$LOGFL	; LAST TEST AN IF?
	BEQ	22$		; NO
	JMP	$INDRD		; YES, TREAT AS AN AND, SO FALSE
22$:	BIT	#AND,$LOGFL	; NO, AND WITH PREVIOUS?
	BNE	24$		; YES
	CMP	#1,$IFCNT	; NO, ITS AN OR, IS THIS FIRST IF?
	BNE	29$		; NO
24$:	BIC	#GO,$LOGFL	; YES, FALSE ANDED WITH ANY IS FALSE
	BR	29$		;
TRUE:	INC	$IFCNT		; INCREMENT NUMBER OF IFS SEEN
	BIT	#IFTST,$LOGFL	; LAST AN IFF ALSO?
	BNE	29$		; YES, TREAT AS AN AND
	BIT	#AND,$LOGFL	; IS IT AN AND?
	BNE	29$		; TRUE ANDED WITH ANY IS SAME AS BEFORE
	BIS	#GO,$LOGFL	; NO, TRUE OR'D WITH ANY IS TRUE
29$:	BIS	#IFTST,$LOGFL	; SET LAST FUNCTION IS AND
;
; PROCESS NEXT PART OF COMMAND
;
30$:	BIC	#LGCL,$LOGFL	; SET BINARY FUNCTION SATISFIED
	CALL	$DSPLY		; DISPLAY COMMAND
	CALL	$GNBLK		; GET NEXT NON-BLANK
	BCS	IFERR		; EOL IS AN ERROR
IFEND:	CMPB	R2,#'.		; COMMAND INDICATOR?                            ;**-2
	BNE	40$		; NO
	JMP	INDC		; YES, PARSE NEXT PART OF COMMAND
40$:	MOVB	#'!,@$TIBUF	; SET THIS AS A COMMENT BEGINING
	DEC	R0		; POINT TO LAST CHARACTER
	JMP	$INTST		; GO PROCESS REST OF COMMAND
IFERR:	JMP	$SYNER		; SYNTAX ERROR
;
; AND/OR PROCESSOR
;
$BOLAN:: BIS	#AND,$LOGFL	; SET AND IN PROGRESS
	BR	ANDOR		;
$BOLOR:: BIC	#AND,$LOGFL	; SET OR IN PROGRESS
ANDOR:	BIT	#IFTST,$LOGFL	; PREVIOUS FUNCTION IF?
	BNE	50$		; YES
	JMP	$ATE22		; NO, BINARY OPERATOR ERROR
50$:	BIS	#LGCL,$LOGFL	; YES, SET LOGICAL OPERATION IN PROGRESS
	BIC	#IFTST,$LOGFL	; SET PREVIOUS NOT IF
	BR	30$		;
	.DSABL	LSB

	.SBTTL	IF PROCESSOR                                                    ;HJL024
$IF::	CALL	$DSPLY		; DISPLAY LINE                                  ;HJL024
	CALL	$GTSYM		; PARSE SYMBOL NAME                             ;HJL024
	BCS	IFERR		; SYNTAX ERROR                                  ;HJL024
	CALL	$SRSYM		; LOCATE SYMBOL                                 ;HJL024
	BCC	80$		; FOUND IT                                      ;HJL024
60$:	JMP	UDFSYM		; UNDEFINED SYMBOL                              ;HJL024
70$:	JMP	$TYPER		; TYPE ERROR                                    ;HJL024
80$:	MOV	R5,$LINLN	; SAVE SYMBOL TABLE ADDRESS                     ;HJL024
	CALL	$GNBLK		; GET NEXT NON-BLANK                            ;HJL024
	BCS	IFERR		; EOL IS ERROR                                  ;HJL024
	TST	R1		; ANY BLANKS SEEN?                              ;HJL024
	BEQ	IFERR		; NO, ERROR                                     ;HJL024
	DEC	R0		; YES, BACKUP UP TO LAST NON-BLANK              ;HJL024
	MOV	#CNDNL,R2	; GET ADDRESS OF CONDITIONAL TEXT               ;HJL024
	CALL	$TBSRC		; SEARCH TABLE FOR TEXT                         ;HJL024
	BCS	IFERR		; ERROR, SYNTAX                                 ;HJL024
	BIC	#2,R1		; CLEAR DUPLICATE BIT                           ;HJL024
	MOVB	R1,$COND	; SAVE IT                                       ;HJL024
	CALL	$GTSYM		; YES, GET NEXT SYMBOL                          ;HJL024
	BCS	IFERR		; SYNTAX ERROR                                  ;HJL024
	CALL	$SRSYM		; LOCATE SYMBOL IN TABLE                        ;HJL024
	BCS	60$		; UNDEFINED SYMBOL                              ;HJL024
	MOV	$LINLN,R4	; GET FIRST SYMBOL ADDRESS                      ;HJL024
	CMPB	SYMSIZ(R4),SYMSIZ(R5) ; ARE TYPES THE SAME?                     ;HJL024
	BNE	70$		; NO                                            ;HJL024
	MOVB	$COND,R1	; GET CONDITION CODE INDEX                      ;HJL024
	ADD	#SYMSIZ+1,R4	; POINT TO SYMBOL VALUE                         ;HJL024
	ADD	#SYMSIZ+1,R5	;                                               ;HJL024
	CMPB	-1(R4),#NUM	; NUMERIC SYMBOL?                               ;HJL024
	BEQ	90$		; YES                                           ;HJL024
	CMP	R1,#4.		; NO, EQUALITY OR NON-EQUALITY TEST?            ;HJL024
	BGT	IFERR		; NO, SYNTAX ERROR                              ;HJL024
	CMPB	-1(R4),#TF	; YES, LOGICAL SYMBOL?                          ;HJL024
	BNE	100$		; NO                                            ;HJL024
90$:	CMPB	(R4),(R5)	; YES, VALUES EQUAL?                            ;HJL024
	JMP	SNGTST(R1)	; DO TEST                                       ;HJL024
100$:	MOV	#STRLEN,R2	; SET LENGTH OF STRING SYMBOL                   ;HJL024
110$:	CMPB	(R4)+,(R5)+	; COMPARE                                       ;HJL024
	CALL	MLTTST(R1)	; TEST COMPARISON                               ;HJL024
	DEC	R2		; DONE?                                         ;HJL024
	BGT	110$		; LOOP TIL END                                  ;HJL024
	TST	R1		; STRINGS EQUAL, LOOKING FOR EQUALITY?          ;HJL024
	BEQ	120$		; YES                                           ;HJL024
	JMP	FALSE		; NO                                            ;HJL024
120$:	JMP	TRUE		;                                               ;HJL024
                                                                                ;HJL024
MLTTST:	BNE	20$		; LOOKING FOR EQUALITY, BUT NOT EQUAL           ;HJL024
	RETURN			; EQUALITY                                      ;HJL024
	BNE	10$		; LOOKING FOR INEQUALITY, AND GOT IT            ;HJL024
	RETURN			;                                               ;HJL024
10$:	TST	(SP)+		; POP STACK                                     ;HJL024
	JMP	TRUE		;                                               ;HJL024
20$:	TST	(SP)+		; POP STACK                                     ;HJL024
	JMP	FALSE		; NOT EQUAL                                     ;HJL024

	.SBTTL	INC AND DEC                                                     ;HJL024
$INC::	MOVB	#1,$COND	; SET VALUE TO ADD TO SYMBOL                    ;HJL024
	BR	ARITH		;                                               ;HJL024
$DEC::	MOVB	#377,$COND	; SET VALUE TO ADD TO SYMBOL                    ;HJL024
                                                                                ;HJL024
ARITH:	CALL	$GOTST		; CAN WE GO?                                    ;HJL024
	BCS	7$		; NO                                            ;HJL024
	CALL	$DSPLY		; YES, DISPLAY COMMAND                          ;HJL024
	CALL	$GTSYM		; PARSE SYMBOL NAME                             ;HJL024
	BCC	5$		; OKAY                                          ;HJL024
	CMPB	R2,#15		; EOL?                                          ;HJL024
	BNE	10$		; NO, ERROR                                     ;HJL024
5$:	CALL	$SRSYM		; SEARCH FOR SYMBOL                             ;HJL024
	BCS	20$		; UNDEFINED SYMBOL                              ;HJL024
	CMPB	SYMSIZ(R5),#NUM ; IS THIS NUMERIC SYMBOL?                       ;HJL024
	BNE	30$		; NO, TYPE ERROR                                ;HJL024
	CLRB	R1		; GET CURRENT                                   ;HJL024
	BISB	SYMSIZ+1(R5),R1	; VALUE                                         ;HJL024
	MOVB	$COND,R2	; GET VALUE TO ADD                              ;HJL024
	ADD	R2,R1		; PERFORM FUNCTION                              ;HJL024
	MOVB	R1,SYMSIZ+1(R5)	; STORE IT BACK                                 ;HJL024
7$:	JMP	$INDRD		; GET NEXT COMMAND                              ;HJL024
10$:	JMP	$SYNER		; SYNTAX ERROR                                  ;HJL024
20$:	JMP	UDFSYM		; UNDEFINED SYMBOL                              ;HJL024
30$:	JMP	$TYPER		; TYPE ERROR                                    ;HJL024

	.SBTTL	GOTO AND ONERR PROCESSOR
	.ENABL	LSB
;
; SET UP GOTO HERE
;
$GOTO:: CALL	$GOTST		; CAN WE GO?
	BCS	10$		; NO
	CALL	$DSPLY		; YES, DISPLAY COMMAND                          ;JMM031
	CALL	$GTLBL		; GET LABEL
	BCS	20$		; NOT FOUND
	BIS	#SKIP,.LIFLG	; SET SEARCHING FLAG
$SERCH:: BISB	#GE.RWD,G.MODE+$GCML ; SET TO REWIND ON END OF FILE
	BICB	#GE.IND,G.MODE+$GCML ; DISABLE DEEPER INDIRECT FILES
	BR	10$		;


;
; SET UP ERROR ROUTINE LABEL HERE
;
$ONERR:: CALL	$GOTST		; CAN WE GO?
	BCS	10$		; NO
	CALL	$DSPLY		; YES, DISPLAY COMMAND                          ;JMM031
	CALL	$GTLBL		; GET LABEL                                     ;JMM031
	BCS	20$		; NOT FOUND                                     ;**-1
	MOV	$LABL,$ERLBL	; AND COPY IT
	MOV	$LABL+2,$ERLBL+2	;
	MOV	$LABL+4,$ERLBL+4	;
10$:	JMP	$INDRD		; READ IN NEXT LINE
20$:	JMP	$SYNER		; SYNTAX ERROR
	.DSABL	LSB

	.SBTTL	OPEN, CLOSE AND DATA                                            ;HJL007
	.ENABL	LSB	                                                        ;HJL007
$OPEN:: CALL	$GOTST		; CAN WE GO?                                    ;HJL007
	BCS	10$		; NO                                            ;HJL007
	CALL	$DSPLY		; YES, DISPLAY COMMAND                          ;HJL007
	MOV	R0,R1		; COPY BUFFER ADDRESS                           ;HJL007
	MOV	$TIBUF+2,R2	; GET LENGTH OF BUFFER                          ;HJL007
	DEC	R2		; DISCOUNT TERMINATOR                           ;HJL007
	ADD	$TIBUF,R2	; GET END OF BUFFER                             ;HJL007
	SUB	R1,R2		; COMPUTE LENGTH OF FILENAME                    ;HJL007
	CSI$1	#$DATCS,R1,R2	; PARSE COMMAND LINE SYNTAX                     ;HJL007
	BCS	20$		; ERROR                                         ;HJL007
	BITB	#CS.EQU,C.STAT(R0) ; EQUALS SIGN? (INPUT FILES?)                ;HJL007
	BNE	20$		; YES, SYNTAX ERROR                             ;HJL007
	CSI$2	R0,OUTPUT	; NO, PARSE OUTPUT FILE                         ;HJL007
	BCS	20$		; ERROR                                         ;HJL007
	BITB	#CS.NMF!CS.DVF,C.STAT(R0) ; FILE NAME OR DEVICE NAME?           ;HJL007
	BEQ	20$		; NO, SYNTAX ERROR                              ;HJL007
	BITB	#CS.WLD!CS.MOR,C.STAT(R0) ; WILD CARD OR MORE FILES             ;HJL007
	BNE	20$		; YES, SYNTAX ERROR                             ;HJL007
	MOV	#$DATF,R0	; GET FDB ADDRESS                               ;HJL007
	MOV	R0,R1		; GET ADDRESS OF                                ;HJL007
	ADD	#F.FNB,R1	; FILE NAME BLOCK                               ;HJL007
	MOV	F.DSPT(R0),R2	; GET DATA SET DESCRIPTOR ADDRESS               ;HJL007
	MOV	F.DFNB(R0),R3	; GET DEFAULT NAME BLOCK ADDRESS                ;HJL007
	CALL	.PARSE		; PARSE FILE NAME                               ;HJL007
	BCS	30$		; ERROR                                         ;HJL007
	OFNB$W	R0		; OPEN FILE FOR WRITE                           ;HJL007
	BCS	30$		; ERROR DURING OPEN                             ;HJL007
	BIS	#DATFIL,.LIFLG	; SET DATA FILE OPEN                            ;HJL007
10$:	JMP	$INDRD		; GET NEXT LINE                                 ;HJL007
20$:	BIS	#FLUSH!DATFIL,.LIFLG ; SET TO FLUSH DATA FILE                   ;HJL007
25$:	JMP	$SYNER		; SYNTAX ERROR                                  ;HJL007
30$:	BIS	#FLUSH!DATFIL,.LIFLG ; SET TO FLUSH DATA                        ;HJL007
40$:	JMP	$DATER		; DATA FILE OPEN FAILURE                        ;HJL007
                                                                                ;HJL007
                                                                                ;HJL007
$CLOSE:: CALL	$GOTST		; CAN WE GO?                                    ;HJL007
	BCS	10$		; NO                                            ;HJL007
	CALL	$DSPLY		; YES, DISPLAY COMMAND                          ;HJL007
	BIT	#DATFIL,.LIFLG	; DATA FILE OPEN?                               ;HJL007
	BEQ	25$		; NO, ERROR                                     ;HJL007
	CLOSE$	#$DATF		; YES, CLOSE THE DATA FILE                      ;HJL007
	BIC	#DATFIL!FLUSH,.LIFLG ; CLEAR DATA FILE FLAGS                    ;HJL007
	BR	10$		; GET NEXT COMMAND                              ;HJL007
                                                                                ;HJL007
                                                                                ;HJL007
$DATA:: CALL	$GOTST		; CAN WE GO?                                    ;HJL007
	BCS	10$		; NO                                            ;HJL007
	CALL	$DSPLY		; YES, DISPLAY COMMAND                          ;HJL007
	BIT	#FLUSH,.LIFLG	; FLUSHING DATA FILE?                           ;HJL007
	BNE	10$		; YES, SKIP WRITING IT OUT                      ;HJL007
	CMPB	(R0)+,#40	; NO, NEXT CHARACTER A SPACE?                   ;HJL007
	BNE	25$		; NO, SYNTAX ERROR                              ;HJL007
	MOV	R0,R1		; YES, COPY BUFFER ADDRESS                      ;HJL007
	SUB	$TIBUF,R1	; COMPUTE BYTES SKIPPED OVER                    ;HJL007
	INC	R1		; DISCOUNT TERMINATOR                           ;HJL007
	SUB	R1,$TIBUF+2	; COMPUTE BYTES TO WRITE                        ;HJL007
	MOV	R0,$TIBUF	; SET ADDRESS OF DATA                           ;HJL007
	PUT$	#$DATF,$TIBUF,$TIBUF+2 ; WRITE OUT LINE                         ;HJL007
	BCC	10$		; GOOD                                          ;HJL007
	BR	40$		; DATA FILE ERROR                               ;HJL007
	.DSABL	LSB                                                             ;HJL007

	.SBTTL	ENABLE AND DISABLE                                              ;HJL007
	.ENABL	LSB                                                             ;HJL007
$ENABL:: MOV	#20$,-(SP)	; SET ADDRESS OF ENABLE INSTRUCTION             ;HJL007
	BR	10$		;                                               ;HJL007
                                                                                ;HJL007
$DSABL:: MOV	#30$,-(SP)	; SET ADDRESS OF DISABLE INSTRUCTION            ;HJL007
10$:	CALL	$GOTST		; CAN WE GO?                                    ;HJL007
	BCS	60$		; NO                                            ;HJL007
	CALL	$DSPLY		; YES, DISPLAY COMMAND                          ;HJL007
	CALL	$GNBLK		; GET NEXT NON-BLANK                            ;HJL007
	BCS	50$		; ERROR                                         ;HJL007
	TST	R1		; ANY BLANKS SEEN?                              ;HJL007
	BEQ	50$		; NO                                            ;HJL007
	MOV	#ENATXT,R2	; YES, GET ADDRESS OF VALID STRINGS             ;HJL007
	DEC	R0		; BACK UP TO FIRST CHARACTER                    ;HJL007
	CALL	$TBSRC		; SEARCH TABLE FOR STRING                       ;HJL007
	BCS	50$		; INVALID OPTION                                ;HJL007
	MOV	ENAADD(R1),R1	; GET BIT TO SET/CLEAR                          ;HJL007
	BIT	#DEFDAT,.LIFLG	; DEFAULT TO DATA FILE?                         ;HJL007
	BEQ	15$		; NO                                            ;HJL007
	BIT	#DEFDAT,R1	; YES, DISABLE DATA?                            ;HJL007
	BEQ	50$		; NO, ERROR                                     ;HJL007
15$:	JMP	@(SP)+		; GO DO THE THING                               ;HJL007
20$:	BIS	R1,.LIFLG	; ENABLE THE OPTION                             ;HJL007
	BR	40$		;                                               ;HJL007
30$:	BIC	R1,.LIFLG	; DISABLE THE OPTION                            ;HJL007
40$:	JMP	$INDRD		; GO GET NEXT COMMAND                           ;HJL007
                                                                                ;HJL007
50$:	TST	(SP)+		; CLEAN STACK                                   ;HJL007
	JMP	$SYNER		; SYNTAX ERROR                                  ;HJL007
                                                                                ;HJL007
60$:	TST	(SP)+		; CLEAN STACK                                   ;HJL007
	BR	40$		;                                               ;HJL007
	.DSABL	LSB                                                             ;HJL007

	.SBTTL	LABEL PROCESSOR
;
; LABEL PROCESSING
;
$LABEL:: BIT	#SKIP,.LIFLG	; SEARCHING FOR LABEL?
	BNE	30$		; YES
5$:	MOV	$TIBUF+2,R3	; NO, GET BUFFER LENGTH
	DEC	R3		; GO UP TO EOL
10$:	CMPB	(R0)+,#':	; END OF LABEL?
	BEQ	20$		; YES
	DEC	R3		; NO, END OF LINE?
	BNE	10$		; NO, LOOP
	JMP	$ATE12		;
20$:	CALL	$GNBLK		; GET NEXT NON-BLANK
	JMP	IFEND		; CONTINUE PROCESSING LINE
;
; COMPARE LABEL FOR SEARCH ARGUMENT
;
30$:	MOV	R0,R3		; COPY POINTER
	MOV	#$LABL,R2	; SET ADDRESS OF ARGUMENT
	CALL	$CMPAR		; COMPARE THEM
	BCS	40$		; NOT THE SAME
	CMPB	(R3)+,#':	; LABEL TERMINATOR?
	BNE	40$		; NO, NOT RIGHT LABEL
	BIC	#SKIP!ERPROC,.LIFLG	; SET SEARCH MODE OFF
	TST	$SBERR		; DID A SUBSTITUTION ERROR OCCUR?               ;HJL024
	BEQ	35$		; NO                                            ;HJL024
	JMP	$ATE27		; YES, ISSUE ERROR MESSAGE NOW                  ;HJL024
35$:	CALL	$DSPLY		; DISPLAY LINE IF TRACE MODE ON                 ;HJL024
	BICB	#GE.RWD,G.MODE+$GCML ; CLEAR REWIND BIT                         ;**-1
	BISB	#GE.IND,G.MODE+$GCML ; ENABLE DEEPER INDIRECT FILES
	MOV	R3,R0		; COPY BUFFER POINTER
	BR	20$		; AND EXECUTE THE COMMAND
40$:	JMP	$INDRD		; READ IN NEXT COMMAND

	.SBTTL	COMMAND INTERPRETOR ERROR PROCESSOR
$SYNER:: INC	$CMDFL		; SET COMMAND IN PROGRESS
	CALL	$ATER2		; SYNTAX ERROR
	BR	COMERR		;
$SMOFL:: MOV	#$SYM17,R1	; POINT TO MESSAGE AREA
	MOV	#$ATE17,-(SP)	; SET ERROR ROUTINE ADDRESS                     ;HJL024
	BR	SYMPRT		;                                               ;HJL024
$TYPER:: MOV	#$SYM26,R1	; GET ADDRESS OF MESSAGE AREA                   ;HJL024
	MOV	#$ATE26,-(SP)	; SET ERROR ROUTINE ADDRESS                     ;HJL024
	BR	SYMPRT		;                                               ;HJL024
$REDEF:: MOV	#$SYM25,R1	; GET NMESSAGE AREA ADRRESS                     ;HJL024
	MOV	#$ATE25,-(SP)	; SET ERROR ROUTINE ADDRESS                     ;HJL024
	BR	SYMPRT		;                                               ;HJL024
$DATER:: MOVB	$DATF+F.ERR,R1	; GET ERROR CODE                                ;HJL024
	MOV	#$SYM24,R0	; GET BUFFER ADDRESS                            ;HJL024
	CLR	R2		; SUPPRESS LEADING ZEROES                       ;HJL024
	CALL	$CBDSG		; CONVERT TO DECIMAL                            ;HJL024
	CLRB	(R0)+		; MARK END OF LINE                              ;HJL024
	JMP	$ATE24		; ISSUE IT                                      ;HJL024
UDFSYM:	MOV	#$SYM19,R1	; GET MESSAGE AREA ADDRESS                      ;**-6
	MOV	#$ATE19,-(SP)	; SET ERROR ROUTINE ADDRESS                     ;HJL024
SYMPRT:	MOV	#$CRNTS,R2	; GET ADDRESS OF SYMBOL                         ;HJL024
	BIT	#SPCSYM,.LIFLG	; SPECIAL SYMBOL?                               ;**-1
	BEQ	10$		; NO
	MOVB	#'<,(R1)+	; YES, PUT IN STARTING BRACKET
10$:	CALL	$MOVE		; MOVE SYMBOL INTO MESSAGE
	BIT	#SPCSYM,.LIFLG	; SPECIAL SYMBOL?
	BEQ	20$		; NO
	MOVB	#'>,(R1)+	; YES, PUT IN TRAILING BRACKET
20$:	CLRB	(R1)		; SET END OF MESSAGE
	INC	$CMDFL		;
	CALL	@(SP)+		; GO TO ROUTINE                                 ;HJL024
COMERR:	JMP	$INXIT		;                                               ;**-1
	.END