.TITLE	LOADCM	LOAD MBD CONTROL MEMORY
	.IDENT	/03MAY7/	;15:20:00  LV
;	.ENTRY	LOADCM	LOAD MBD CONTROL MEMORY
;+
; L O A D C M
;
; PURPOSE:	LOAD MBD CONTROL MEMORY - VERSION FOR RSX-11D
;
; INTERFACE:	CALLING SEQUENCE
;			CALL LOADCM
;
;		INPUT:	R0 -- BYTE COUNT
;			R1 -- FWA CONTROL MEMORY
;			R2 -- FBA PDP-11 MEMORY
;
; LANGUAGE:	MACRO-11
;
; RESTRICTIONS:	NOT FORTRAN-CALLABLE
;		THIS ROUTINE CAN BE USED ONLY BY A PRIVILEGED TASK.
;-
;
; REVISIONS:
; 03-MAY-77	LV	UPDATED TO CONFORM TO STANDARDS
;
.GLOBL LOADCM
;
;	MACRO CALLS
	.MCALL RETURN,PUSH,POP
;
;	MBD SYMBOL DEFINITIONS
;
CSR=164000	;COMMAND AND STATUS REGISTER
PDX=164002	;PROGRAM DATA REGISTER
MBDIR=164006	;MBD INSTRUCTION REGISTER
RESET=2
STOP=130000	;STORE PDR (MODEL 2), STORE ATR (MODEL 1)
LOADCM:
	PUSH	R3
	MOV #RESET,@#CSR
	CLR @#164004	;CLEAR GL MASK
	MOV #STOP,R3	;MOVE STORE PDR TO R3
	ADD R1,R3	;ADD FWA CM
S5:	MOV (R2)+,@#PDX	;PUT WORD TO BE STORED IN PDR
	MOV #340,@#MBDIR	;MOVE PDR TO ATR
	MOV R3,@#MBDIR	;PUT CURRENT STORE INSTRUCTION IN MBDIR AND EXECUTE IT
	INC R3		;INCREMENT STORE ADDRESS
	DEC R0		;COUNT OUT
	DEC R0
	BNE S5
	MOV #RESET,@#CSR	;RESET
	POP	R3
	RETURN
.END